isPolygon ver.3

{
Чтобы ABCD являлся многоугольником, отрезки AB и CD, а также BC и AD
не должны пересекаться. Возьмем, например отрезки AB и CD. Если косое произведение
вектора AB с AC и AD одного знака, или же косое произведение CD с CA и CB
одного знака, то отрезки не пересекаются. Аналогично с BC и AD.
}

// Тип точка-вектор
type Point = record
  x,y: real;
  class function operator-(p1, p2: Point): Point;
  begin
    Result.x := p1.x - p2.x;
    Result.y := p1.y - p2.y;
  end;
end;

// Создание точки
function Pnt(x, y: real): Point;
begin
  Result.x := x;
  Result.y := y
end;

// Косое произведение векторов (cross-product)
function cP(p1, p2: Point): real;
begin
  Result := p1.x * p2.y - p1.y * p2.x;
end;

function isPolygon(a, b, c, d: Point): boolean;
begin
  var ab := b - a;
  var bc := c - b;
  var cd := d - c;
  var ad := d - a;
  var ac := c - a;
  var bd := d - b;

  if not ((sign(cP(ab, ac)) = sign(cP(ab, ad))) or (sign(cP(cd, Pnt(0, 0)-ac)) = sign(cP(cd, Pnt(0, 0)-bc)))) then
  begin
    Result := False;
    exit;
  end;

  if not ((sign(cP(bc, Pnt(0, 0)-ab)) = sign(cP(bc, bd))) or (sign(cP(ad, ab)) = sign(cP(ad, ac)))) then
  begin
    Result := False;
    exit;
  end;

  Result := True;
end;

begin
  var (x1, y1) := ReadInteger2('Координаты точки A:');
  var a := pnt(x1, y1);

  var (x2, y2) := ReadInteger2('Координаты точки B:');
  var b := pnt(x2, y2);

  var (x3, y3) := ReadInteger2('Координаты точки C:');
  var c := pnt(x3, y3);

  var (x4, y4) := ReadInteger2('Координаты точки D:');
  var d := pnt(x4, y4);

  println(isPolygon(a, b, c, d));

end.