/*
(fn_sabotGendarmerie)

    AUTEUR : ADECYA FRANCE (ACF - https://adecya.fr)
    TOUTE REPRODUCTION COMPLETE OU PARTIELLE DE NOS SCRIPTS EST INTERDITE !
    -- NOTE: (Memory): Sabot_den
*/

_ACFSabotGDVeh = cursorTarget;
_ACFSabotGDItem = "ToolKit";

if (playerSide isEqualTo blufor) then {
    if (player distance _ACFSabotGDVeh < 3) then {
        if (_ACFSabotGDVeh getVariable ["ACFSabotVehicle", 0] isEqualTo 0) then {
            if (_ACFSabotGDItem in items player) then {
                _ACFSabotGDVeh setVariable ["ACFSabotVehicle", 1];
                _ACFSabotGDVeh setfuel 0; // -- Voir sauvegarde fuel.
                player action ["repairVehicle", player];
                sleep 5;
                player removeItem _ACFSabotGDItem;
                _sabot = "G9545_sabot" createVehicle position player;
                _sabot attachTo [_ACFSabotGDVeh,[-1.769,-0.2,-0.1],"Sabot_den"];
                ["Sabot Gendarmerie","Vous venez de mettre le sabot sur le véhicule."] call ACF_fnc_showNotification;
            } else {["Sabot Gendarmerie","Vous n'avez pas de sabot sur vous."] call ACF_fnc_showNotification};
        } else {
            if (player canAdd _ACFSabotGDItem) then {
                _ACFSabotGDVeh setVariable ["ACFSabotVehicle", 0];
                _ACFSabotGDVeh setfuel 1; // -- Voir sauvegarde fuel.
                player action ["repairVehicle", player];
                sleep 5;
                player addItem _ACFSabotGDItem;
                {
                    if (typeOf(_x) == "G9545_sabot") then {
                        detach _x;
                        deleteVehicle _x;
                    };
                } forEach attachedObjects _ACFSabotGDVeh;
                ["Sabot Gendarmerie","Vous venez de retirer le sabot du véhicule."] call ACF_fnc_showNotification;
            } else {["Sabot Gendarmerie","Vous n'avez pas de place sur vous pour prendre le sabot."] call ACF_fnc_showNotification};
        };
    } else {["Sabot Gendarmerie","Vous êtes trop loin du véhicule pour poser un sabot."] call ACF_fnc_showNotification};
} else {["Sabot Gendarmerie","Vous n'êtes pas gendarme pour poser un sabot."] call ACF_fnc_showNotification};