Video Encoding

@echo off
::
:: Script for Encoding from:
::   AVI: Any Video codec, WAV 6 channels
:: To:
::   M4V: AVC H.264 AC3 5.1
::
:: ----------------------------------------------------------------------------
:: WARNING!
:: DONT TOUCH OR CHANGE NOTHING BELOW THIS LINE!
:: ----------------------------------------------------------------------------


IF %1.==. GOTO empty

:: Batch path
SET THIS_PATH=%~d0%~p0
SET B=%THIS_PATH%bin\
for %%a in (%*) do "%B%HandBrakeCLI.exe" -i "%%~a" -t 1 --angle 1 -c 1 -o "%%~da%%~pa%%~na.v.m4v" -f mp4 -4 --loose-anamorphic --modulus 2 -e x264 -q 20 -r 30 --pfr -a none --audio-fallback ffac3 --x264-profile=high --x264-tune="animation" --h264-level="4.0" --verbose=1 && ^
"%B%ffmpeg" -i "%%~a" -vn -acodec copy "%%~da%%~pa%%~na.wav" && ^
"%B%aften.exe" "%%~da%%~pa%%~na.wav" "%%~da%%~pa%%~na.ac3" && ^
"%B%MP4Box.exe" -ipod -brand M4VH -hint -keep-sys -add "%%~da%%~pa%%~na.v.m4v#1:fps=30.000" -add "%%~da%%~pa%%~na.ac3:lang=en" -new "%%~da%%~pa%%~na.m4v" && ^
del "%%~da%%~pa%%~na.wav" && ^
del "%%~da%%~pa%%~na.ac3" && ^
del "%%~da%%~pa%%~na.v.m4v"

echo All done!

GOTO end
:empty
echo.
echo  ERROR!
echo  No input file specified.
echo  You can set an input by draggin a video file to this script or by calling
echo  the script on the command prompt and setting the full file path as
echo  the first param.
echo.
pause
:end