Stavox - Fartskilt m. bødemulighed

@name NewSpeed
@inputs [EGP1]:wirelink [Speed1]:entity
@outputs
@persist [Speed1N, Cooldown1, SpaceLimit, IndexMul, SpeedGift, SpeedChance, SpeedState, Active]:number [Table]:table
@trigger

if(first() | dupefinished()) {

    runOnChat(1)

    #Skal der uddeles boeder?
    Active = 0
    #Fartgraensen
    Speed1N = 30
    #Hvor meget skal farten vaere over foer en boede bliver givet?
    SpaceLimit = 2.5


    ##VIRKER IKKE
    #Skal gaver vaere taendte? (0 = Nej, 1 = Ja)
    #SpeedState = 0
    #Hvor mange penge modtager bilisten der overholder fartgraensen?
    #SpeedGift = 10
    #Hvad er chancen for, at man modtager en taknemmeligheds gave? (0% = ingen, 1 = 100%)
    #SpeedChance = 80
    ##VIRKER IKKE


    ###
    NrSign = 0

    function void wirelink:drawSign() {
        if(NrSign){ IndexMul = 30 } else { IndexMul = 1 }
        This:egpClear()
        #base
        This:egpBox(IndexMul, vec2(256,100), vec2(250,280)) This:egpColor(IndexMul,vec4(165,165,165,255))
        This:egpBox(IndexMul+1, vec2(256,100), vec2(235,265)) This:egpColor(IndexMul+1,vec4(115,115,115,255))
        This:egpBox(IndexMul+2, vec2(256,100), vec2(220,250))
        #base foot
        This:egpBox(IndexMul+3, vec2(320,390), vec2(20,300)) This:egpColor(IndexMul+3, vec4(100,100,100,255))
        This:egpBox(IndexMul+4, vec2(192,390), vec2(20,300)) This:egpColor(IndexMul+4, vec4(100,100,100,255))
        #lights
        This:egpCircle(IndexMul+5, vec2(325,15), vec2(32,32)) This:egpColor(IndexMul+5, vec4(0,0,0,255))
        This:egpCircle(IndexMul+6, vec2(187,15), vec2(32,32)) This:egpColor(IndexMul+6, vec4(0,0,0,255))
        #lightsFront
        This:egpCircle(IndexMul+12, vec2(325,15), vec2(30,30)) This:egpColor(IndexMul+12, vec4(135,92,0,255))
        This:egpCircle(IndexMul+13, vec2(187,15), vec2(30,30)) This:egpColor(IndexMul+13, vec4(135,92,0,255))
        #txt
        This:egpText(IndexMul+7,"Din", vec2(256,40)) This:egpColor(IndexMul+7, vec4(256,0,0,255)) This:egpSize(IndexMul+7, 55) This:egpAlign(IndexMul+7,1)
        This:egpText(IndexMul+8,"fart", vec2(256,80)) This:egpColor(IndexMul+8, vec4(256,0,0,255)) This:egpSize(IndexMul+8, 55) This:egpAlign(IndexMul+8,1)
        #baseKmt
        This:egpBox(IndexMul+9, vec2(236,180), vec2(156,70)) This:egpColor(IndexMul+9, vec4(80,80,80,255))
        This:egpText(IndexMul+10,"", vec2(291,141)) This:egpColor(IndexMul+10, vec4(255,174,0,255)) This:egpSize(IndexMul+10, 75) This:egpAlign(IndexMul+10,2)
        This:egpText(IndexMul+11,"km/t", vec2(363,171)) This:egpColor(IndexMul+11, vec4(0,0,0,255)) This:egpSize(IndexMul+11, 22) This:egpAlign(IndexMul+11,2)
    }

    function void wirelink:speed(Col:array, Speed:string) {
        This:egpColor(IndexMul+12, vec(Col[1,number],Col[2,number],Col[3,number]))
        This:egpColor(IndexMul+13, vec(Col[1,number],Col[2,number],Col[3,number]))
        This:egpSetText(IndexMul+10,Speed)
    }

    function void entity:giveTicket(Fine:number,Measured:number) {
        if(!Table:exists(This:steamID())) {
            concmd("say /wanted " + This:steamID() + " [Fartm"+aa()+"ler] Fartgr"+ae()+"nsen i omr"+aa()+"de: " + Speed1N + "Km/t. M"+aa()+"lt hastighed: " + Measured + "Km/t [+"+(Measured-Speed1N)+"] Udregnet b"+oe()+"de: " + Fine:toString() +"kr.")
            timer("makePM",3000)
            Table[This:steamID(),array] = array(This,Fine,0)
        }
    }


    EGP1:drawSign()
    timer("checkList",60000)
}


#Ranger

if(Speed1:isVehicle() & Cooldown1 == 0 & Speed1:kmh() >= 1) {
    EGP1:speed(array(255,174,0),Speed1:kmh():toString())
    Cooldown1 = 1
    timer("reset1",4000)
    if(Speed1:kmh() <= Speed1N & SpeedState == 1) {
        Test = floor(randint(SpeedChance,101)/100,1)
        if(Test == 1 & SpeedChance != 0) {
            concmd("say /pm "+Speed1:driver():steamID()+" [Fartm"+aa()+"ler] Tak fordi du overholder f"+ae()+"rdselsloven. En lille gave er blevet sendt afsted til dig.")
            moneyGive(Speed1:driver(),SpeedGift)
        }
    }elseif(!Table:exists(Speed1:driver():steamID()) & Active == 1) {
            if(!Speed1:elsOn()) {
                if(Speed1:kmh()-SpaceLimit > Speed1N) {
                    Speed1:driver():giveTicket(calculateFine(Speed1N,Speed1:kmh()), Speed1:kmh())
                    Speed1:driver():setFine(calculateFine(Speed1N,Speed1:kmh()))
                }
            }
    }
}

#Timers

if(chatClk()) {
    if(Table:exists(lastSpoke():steamID())){
        A = lastSpoke():lastSaid():lower():explode(" ")
        if(A[1,string]=="!betal") {
            hideChat(1)
            moneyRequest(lastSpoke(),Table[lastSpoke():steamID(),array][2,number],"Fartb"+oe()+"de")
        }
    }
}elseif(clk("makePM")) {
    foreach(K, Ply:entity = players()) {
        if(Table:exists(Ply:steamID()) & Table[Ply:steamID(),array][3,number] == 0) {
            concmd("say /pm " + Table[Ply:steamID(),array][1,entity]:steamID() + " [Auto] Du har f"+aa()+"et en fartb"+oe()+"de. Fjern efters"+oe()+"gelsen ved at skrive !betal")
            Table[Ply:steamID(),array][3,number] = 1
        }
    }
}elseif(clk("checkList")) {
    foreach(K, Ply:entity = players()) {
        if(Table:exists(Ply:steamID()) & !Ply:isWanted()) {
            printColor(vec(255,215,0),"[Fartm"+aa()+"ler] ",vec(255,255,255),"Fjernede ", vec(255,150,0), Ply:name(), vec(255,255,255), "s b"+oe()+"de, idet spilleren ikke l"+ae()+"ngere er efters"+oe()+"gt.")
            Table:remove(Ply:steamID())
        }
    }
timer("checkList",10000)
}


if(moneyClk("Fartb"+oe()+"de")) {
    if(Table:exists(moneyClkPlayer():steamID())){
        printColor(vec(255,215,0),"[Fartm"+aa()+"ler] ",vec(255,150,0),moneyClkPlayer():name(), vec(255,255,255), " betalte sin fartb"+oe()+"de!")
        concmd("say /unwanted "+moneyClkPlayer():steamID())
        Table:remove(moneyClkPlayer():steamID())
    }
}

if(clk("reset1")) {
    Cooldown1 = 0
    EGP1:speed(array(153,104,0),"")
}