cd /d %~dp0

rem Построчное чтение файла log.txt и запись в память
for /f "tokens=1,* delims=[]" %%i in ('find /v /n "" "log.txt"') do (
rem Присвоение значения строке
set string_%%i=%%j
rem Максимальный номер
set max=%%i
)



:begin
rem Построчное чтение из памяти
set /a num=%num%+1
if %num% geq %max% goto :eof

set errorstring=0

call set this=%%string_%num%%%

rem Если строка пустая, значит, следующая строка - первая в блоке
if /i "%this%"=="" set /a block=%num%+1

rem Проверка, начинается ли текущая строка "HTTP request sent,", и если да, то оканчивается ли "200 OK". Если нет, номер строки ошибочный
rem HTTP request sent, awaiting response... 200 OK
for /f "tokens=1-5,* delims= " %%a in ("%this%") do (
if /i "%%a %%b %%c"=="HTTP request sent," (
if /i not "%%f"=="200 OK" (
rem На две строки выше сообщения об ошибке находится URL
set /a errorstring=%block%
set error=%%f
)
)
)

if /i not "%errorstring%"=="0" call set this=%%string_%errorstring%%%
if /i not "%errorstring%"=="0" for /f "tokens=1-10 delims= " %%a in ("%this%") do set this=%%c
if /i not "%errorstring%"=="0" echo %this%  %error%>>test.txt

goto begin