'nj
'2.0
'&NAME JOGGER:Spasm (AKA spasm_attack)
'&startnj:stopnj
'&38277
'&Jogs through accounts to keep them active.:If an account has less than 2 hours logged, it will wait for the remainder of the two hours so the account doesn't get automatically deleted.:Usernames and passwords should go in names.txt, located in the plugins folder.:One username and password per line, seperated by a space.:Can also write profile data.:Settings can be found at the top of the script.



'****************************************************************************************
'****************************************************************************************
'***********************************   SETTINGS   ***************************************
'****************************************************************************************
'****************************************************************************************


'CHANGE NEXT LINE TO MINIMUM TIME TO STAY LOGGED IN IN SECONDS
Const minWaitTime = 180


'WRITE PROFILE UPON CONNECT?
Const writeProfile = False

'PROFILE LOCATION
Const profileLocation = "Outer Space"

'PROFILE SEX
Const profileSex = "Sexy"

'PROFILE DESCRIPTION
Const profileDescription = "I am me."








'****************************************************************************************
'****************************************************************************************
'***********************************   VARIABLES  ***************************************
'****************************************************************************************
'****************************************************************************************


Dim usernames()
Dim passwords()
Dim active






'****************************************************************************************
'****************************************************************************************
'***********************************   FUNCTIONS  ***************************************
'****************************************************************************************
'****************************************************************************************

Sub startJogger()


    'load usernames and passes from usernames.txt

    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set File = FSO.OpenTextFile(BotPath & "plugins\names.txt", 1, True)


    i = 0

    Do Until File.AtEndOfStream


        line = Split(File.ReadLine, " ")

        If UBound(Line) = 1 Then

            ReDim Preserve usernames(i + 1)
            ReDim Preserve passwords(i + 1)

            usernames(i) = line(0)
            passwords(i) = line(1)

            i = i + 1

        End If

    Loop


    File.Close


    If i > 0 Then
        active = true
        jogNext
    Else
        AddChat VBRed, "NAME JOGGER: names.txt was empty!"
    End If

End Sub

Sub jogNext()

    i = CInt(GetSetting("nj", "i"))



    If (Not IsNumeric(i)) Or (i > UBound(usernames)) Then i = 0


    BotVars.Username = usernames(i)
    BotVars.Password = passwords(i)

    AddChat VBYellow, "NAME JOGGER: New username and password set: " & usernames(i)


    i = i + 1
    SetSetting "nj", "i", i, "Last position in the name array.", True


    Connect


    'set the interval to 30 seconds, it will depend on the nj_Event_ServerInfo
    '   to be set for longer, if that event doesn't happen, the login failed
    '   and we don't want to be waiting around for a long time
    TimerInterval "nj", "jogger", 30
    TimerEnabled "nj", "jogger", true

End Sub






'****************************************************************************************
'****************************************************************************************
'************************************   EVENTS  *****************************************
'****************************************************************************************
'****************************************************************************************



Sub nj_Event_PressedEnter(Text)

    If Text = "/startnj" Then

        startJogger
        VetoThisMessage

    ElseIf Text = "/stopnj" Then

        Addchat VBYellow, "NAME JOGGER: Name jogging stopped"
        TimerEnabled "nj", "jogger", False

        active = false

        VetoThisMessage

    End If


End Sub


Sub nj_jogger_timer()

    jogNext

End Sub

Sub nj_Event_ServerInfo(Message)

    If Not active Then Exit Sub

    If Left(Message, 13) = "Time Logged: " Then

        temp = Split(Message, " ")


        days = CInt(temp(2))
        hours = CInt(temp(4))
        mins = CInt(temp(6))
        secs = CInt(temp(9))



        Dim waitTime

        If (days = 0) And (hours < 2) Then

            waitTime = (2 * 60 * 60) + 30 '2 hours 30 seconds

            waitTime = waitTime - (hours * 60 * 60)
            waitTime = waitTime - (mins * 60)
            waitTime = waitTime - (secs)

            If waitTime < minWaitTime Then waitTime = minWaitTime

        Else

            waitTime = minWaitTime

        End If


        AddChat VBYellow, "NAME JOGGER: Waiting " & waitTime & " seconds..."


        TimerInterval "nj", "jogger", waitTime
        TimerEnabled "nj", "jogger", True


        If writeProfile Then
            AddChat VBYellow, "NAME JOGGER: Writing profile data..."
            SetBotProfile profileLocation, profileSex, profileDescription
        End If

    End If

End Sub