CSCO Server Starter Script

@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################

@ECHO off
title CSCO Server Starter

@REM This is a small script that allows creation of a server with each available gamemode

set SERVER_NAME="My CSCO Server"
set SERVER_PORT=27015
set MAX_PLAYERS=64
set SERVER_DEFAULT_MAP="de_dust2_csco"
set TICK_RATE=128
@REM 64 or 128

@REM  Available maps:
@REM    as_retreat_csco
@REM    awp_india_csco
@REM    cs_backalley_csco
@REM    cs_militia_csco
@REM    de_dust2_csco
@REM    de_inferno_csco
@REM    de_mirage_csco
@REM    de_nuke_csco
@REM    de_train_csco
@REM    de_vertigo_csco
@REM    fy_iceworld_csco
@REM    fy_pool_day_csco_11
@REM    tr_firingrange_csco
@REM    ar_baggage
@REM    de_shortdust
@REM    dz_blacksite

@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################
@REM #######################################################################################

echo.
echo.     Choose gamemode number:
echo.
echo.  1) The classic Counter-Strike experience
echo.  2) The classic Condition Zero experience
echo.  3) 5v5 Tournament mode
echo.  4) Shorter Competitive
echo.  5) 2v2 Competitive (Wingman)
echo.  6) Arms Race (GunGame)
echo.  7) Round based GunGame (Demolition)
echo.  8) FFA Deathmatch
echo.  9) Survive waves of bots (Guardian)
echo. 10) Coop - Only works on maps meant for it (CoopStrike)
echo. 11) Battle Royale - Only works on maps meant for it (Danger Zone)
echo. 12) Scouts and knives, low gravity (Flying Scoutsman)
echo. 13) Official retakes gamemode
echo. 14) One in the Chamber
echo. 15) Zombie Mod
echo. 16) Custom (No gamemode)
echo. 17) Retreat (VIP protect) - Normal
echo. 18) Retreat (VIP protect) - Condition Zero
echo.

:INPUT_LOOP
set /p USER_INPUT="Enter value: "
IF %USER_INPUT% LEQ 18 (
  IF %USER_INPUT% GEQ 1 (
    goto:SERVER_ARGS
  )
)
echo Invalid value
goto:INPUT_LOOP

:SERVER_ARGS
set "ARGS="

IF %USER_INPUT% EQU 1 (
  set "ARGS=+game_type 0 +game_mode 0"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 2 (
  set "ARGS=+game_type 0 +game_mode 0 +sv_skirmish_id 22 +sv_game_mode_flags 4"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 3 (
  set MAX_PLAYERS=10
  set "ARGS=+game_type 0 +game_mode 1"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 4 (
  set MAX_PLAYERS=10
  set "ARGS=+game_type 0 +game_mode 1 +sv_game_mode_flags 32"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 5 (
  set MAX_PLAYERS=4
  set "ARGS=+game_type 0 +game_mode 2"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 6 (
  set "ARGS=+game_type 1 +game_mode 0"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 7 (
  set "ARGS=+game_type 1 +game_mode 1"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 8 (
  set "ARGS=+game_type 1 +game_mode 2"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 9 (
  set "ARGS=+game_type 4 +game_mode 0"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 10 (
  set "ARGS=+game_type 4 +game_mode 1"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 11 (
  @REM Here it's hardcoded to be 'dz_blacksite' remove the line below if you want to change the map
  set SERVER_DEFAULT_MAP="dz_blacksite"
  set "ARGS=+game_type 6 +game_mode 0"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 12 (
  set "ARGS=+game_type 0 +game_mode 0 +sv_skirmish_id 3"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 13 (
  set "ARGS=+game_type 0 +game_mode 0 +sv_skirmish_id 12"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 14 (
  set "ARGS=+game_type 1 +game_mode 2 +sv_skirmish_id 21"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 15 (
  set "ARGS=+game_type 0 +game_mode 0 +sv_skirmish_id 23"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 16 (
  set "ARGS=+game_type 3 +game_mode 0"
  goto:START_SERVER
)
@REM I guess it checks based on map data if it's Retreat or not, hardcoded to "as_retreat_csco" for now
IF %USER_INPUT% EQU 17 (
  set SERVER_DEFAULT_MAP="as_retreat_csco"
  set "ARGS=+game_type 0 +game_mode 0"
  goto:START_SERVER
)
IF %USER_INPUT% EQU 18 (
  set SERVER_DEFAULT_MAP="as_retreat_csco"
  set "ARGS=+game_type 0 +game_mode 0 +sv_skirmish_id 22 +sv_game_mode_flags 4"
  goto:START_SERVER
)

:START_SERVER
start srcds.exe -game csco/csgo -console -usercon %ARGS% +sv_max_players %MAX_PLAYERS% -maxplayers %MAX_PLAYERS% -maxplayers_override %MAX_PLAYERS% +hostname %SERVER_NAME% +map %SERVER_DEFAULT_MAP% -tickrate %TICK_RATE% -port %SERVER_PORT%