Date Math in Batch

@ECHO OFF
SET rundate=%date%
REM SET rundate=04/27/2018
SET datecode=%rundate:~-4,4%%rundate:~-10,2%%rundate:~-7,2%
echo Starting Passport reports for %rundate%
REM echo Date: %date%
echo Run Date: %rundate%
REM get the date parts
FOR /F "TOKENS=1-3 DELIMS=/" %%A IN ("%rundate%") DO SET MM=%%A& SET DD=%%B& SET YYYY=%%C
REM eliminate left zeroes
SET /A DD=10%DD% %% 100, MM=10%MM% %% 100
REM calculate julian date
IF %MM% LSS 3 SET /A MM+=12, YYYY-=1
SET /A A=YYYY/100, B=A/4, C=2-A+B, E=36525*(YYYY+4716)/100, F=306*(MM+1)/10, JDN=C+DD+E+F-1524
REM echo Julian Date: %JDN%

REM end date is JDN-1 days
SET /A endJDN=JDN-1
REM convert julian to date
SET /A W=(%endJDN%*100-186721625)/3652425, X=W/4, A=%endJDN%+1+W-X, B=A+1524, C=(B*100-12210)/36525, D=36525*C/100, E=(B-D)*10000/306001, F=306001*E/10000, DD=B-D-F, MM=E-1, YYYY=C-4716
IF %MM% GTR 12 SET /A MM-=12, YYYY+=1
REM pad with left zeroes
IF %DD% LSS 10 SET DD=0%DD%
IF %MM% LSS 10 SET MM=0%MM%
SET enddate=%YYYY%%MM%%DD%

REM start date is endJDN-120 days
SET /a startJDN=endJDN-120
REM convert julian to date
SET /A W=(%startJDN%*100-186721625)/3652425, X=W/4, A=%startJDN%+1+W-X, B=A+1524, C=(B*100-12210)/36525, D=36525*C/100, E=(B-D)*10000/306001, F=306001*E/10000, DD=B-D-F, MM=E-1, YYYY=C-4716
IF %MM% GTR 12 SET /A MM-=12, YYYY+=1
REM pad with left zeroes
IF %DD% LSS 10 SET DD=0%DD%
IF %MM% LSS 10 SET MM=0%MM%
SET startdate=%YYYY%%MM%%DD%

echo Run Date: %datecode%
echo Start Date: %startdate%
echo End Date: %enddate%
timeout /t 5

wscript "C:\Reports\Passport\Passport_Lackey-2018082301JRB.vbs" %startdate% %enddate% %datecode%