{ compiler ? "ghc843" }: let pkgs = import ./pkgs.nix; in with pkgs; with lib;
let

  jsaddle-src = fetchFromGitHub
    { owner = "ghcjs";
      repo = "jsaddle";
      rev = "68208be806c49a2a0c9f037dfac85feae10a8c80";
      sha256 = "0acj0x716ikfb08ndib36jmwxkwq399lvkip46sfkh1ynn0pvc1c";
    };


  gitignore = (callPackage (fetchFromGitHub
    { owner = "Fresheyeball";
      repo = "nix-gitignore";
      rev = "d27bfb07dc63e36d5ea53f375f023f9ae49aea1d";
      sha256 = "19j47sjxj2fm36y50gfx3kvyxwbiscja45gmbkb01vnqck80rlq6";
    }) {}).gitignoreSource
      [ ".git"
        ".ghc.environment.x86_64-linux-8.4.3"
      ];

  # shpa-src = ../Shpadoinkle;
  shpa-src = fetchFromGitLab
    { owner = "fresheyeball";
      repo = "Shpadoinkle";
      rev = "4919ef476b78e484490d443f4db1ae74fd15b5ae";
      sha256 = "1ay1gb09lsv5yhzji9s9bii86gcym7jgmx8sikincmv4242cns34";
    };

  src = gitignore ./.;

  haskellPackages = with pkgs.haskell.lib; haskell.packages.${compiler}.override {
    overrides = self: super: {
      Shpadoinkle                 = self.callCabal2nix "Shpadoinkle"                 "${shpa-src}/core"             {};
      Shpadoinkle-backend-pardiff = self.callCabal2nix "Shpadoinkle-backend-pardiff" "${shpa-src}/backends/pardiff" {};
      Shpadoinkle-html            = self.callCabal2nix "Shpadoinkle"                 "${shpa-src}/html"             {};

      jsaddle-warp  = dontCheck (self.callCabal2nix  "jsaddle-warp"
                                                   "${jsaddle-src}/jsaddle-warp" {});
      jsaddle       = self.callCabal2nix "jsaddle" "${jsaddle-src}/jsaddle"      {};

      comonad       = dontCheck super.comonad;
      extra         = dontCheck super.extra;
      SHA           = dontCheck super.SHA;
      pureMD5       = dontCheck super.pureMD5;
      unliftio      = dontCheck super.unliftio;
      semigroupoids = dontCheck super.semigroupoids;
      megaparsec    = dontCheck super.megaparsec;
      lens          = dontCheck super.lens;
      http-types    = dontCheck super.http-types;
      silently      = dontCheck super.silently;
      hpack         = haskell.packages.ghc843.hpack;
    };
  };

  site =  haskell.lib.overrideCabal (haskellPackages.callCabal2nix "platonic-marketing" src {}) (old: {
    enableLibraryProfiling    = false;
    enableExecutableProfiling = false;
  });

  dev = site.overrideAttrs (old: {
    buildInputs = with pkgs.haskell.packages.ghc843;
      old.buildInputs ++ [ stylish-haskell ghcid cabal-install ];
  });


in if lib.inNixShell then dev else site