//  lower shield
//2   power relais 1 (power lower shield)
//(2) power relais 2 (power upper shield)
//4   SZ  down
//16  SZ  up (+4)
//17  Z3L down
//21  Z3L up (+17)
//18  Z3R down
//19  Z3R up (+18)
//  upper shield
//13  Z2L down
//27  Z2L up (+13)
//26  Z2R down
//25  Z2R up (+26)
//33  Z1L down
//32  Z1L up (+33)
//22  Z1R down
//23  Z1R up (+23)

on System#Boot do
 if [Boot#Watcher] = 0
  TaskValueSet,1,1,-1
  TaskValueSet,2,1,-1
  TaskValueSet,3,1,-1
  TaskValueSet,4,1,-1
  TaskValueSet,5,1,-1
 endif
endon

on Clock#Time=All,%sunset% do
 event,ControlZ1=100
 event,ControlZ2=100
 event,ControlZ3=100
 event,ControlSZ=100
endon

on Clock#Time=All,**:** do
 //minutely
endon

on Openall do
 //control?cmd=event,Openall
 event,ControlZ1=0
 event,ControlZ2=0
 event,ControlZ3=0
 event,ControlSZ=0
endon

on Closeall do
 //control?cmd=event,Closeall
 event,ControlZ1=100
 event,ControlZ2=100
 event,ControlZ3=100
 event,ControlSZ=100
endon

on Rules#Timer=8 do
 logentry,"shutter movement states: Z1#M=[Z1#M] Z2#M=[Z2#M] Z3#M=[Z3#M] SZ#M=[SZ#M]"
 if [Z1#M] = 0 and [Z2#M] = 0 and [Z3#M] = 0 and [SZ#M] = 0
  logentry,"No Movement, Power off"
  TaskValueSet,5,1,-1
  gpio,2,1
 else
  TimerSet,8,5
  logentry,"Power still needed."
 endif
endon

on Rules#Timer=7 do
 TaskValueSet,1,2,0
endon

on ControlSZ do
 //control?cmd=event,ControlSZ=0
 Let,13,%eventvalue%
 if [VAR#13] > 0 and [VAR#13] < 100
  //open/close percent
  Let,10,(30/100)*[VAR#13]
  Let,11,(30/100)*[SZ#S]
  if [VAR#11] > [VAR#10]
   // open a bit
   Let,12,[VAR#11]-[VAR#10]
   logentry,SZ_o_secs=[VAR#12]
   gpio,2,0
   TimerSet,8,[VAR#12]+2
   delay,250
   LongPulse,4,0,[VAR#12]
   LongPulse,16,0,[VAR#12]
   TimerSet,7,[VAR#12]
   TaskValueSet,1,2,1
  endif
  if [VAR#11] < [VAR#10]
   //close a bit
   Let,12,[VAR#10]-[VAR#11]
   logentry,SZ_c_secs=[VAR#12]
   gpio,2,0
   TimerSet,8,[VAR#12]+2
   delay,250
   LongPulse,4,0,[VAR#12]
   gpio,16,1
   TimerSet,7,[VAR#12]
   TaskValueSet,1,2,1
  endif
 else
  if [VAR#13] = 0
   logentry,SZ_o_comp
   gpio,2,0
   TimerSet,8,30+2
   delay,250
   LongPulse,4,0,30
   LongPulse,16,0,30
   TimerSet,7,30
   TaskValueSet,1,2,1
  endif
  if [VAR#13] = 100
   logentry,SZ_c_comp
   gpio,2,0
   TimerSet,8,30+2
   delay,250
   LongPulse,4,0,30
   gpio,16,1
   TimerSet,7,30
   TaskValueSet,1,2,1
  endif
  if [VAR#13] = 101
   logentry,SZ_stop
   LongPulse,4,0,0
   LongPulse,16,0,0
   TimerSet,7,1
  endif
  if [VAR#13] = 102
   //special state
  endif
  if [VAR#13] = 103
   //special state
  endif
 endif
 TaskValueSet,1,1,[VAR#13]
endon