API tools faq
paste
Advertisement
Guest User

QTGMC 3.33s for avs 2.60

a guest
Aug 3rd, 2015
455
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 83.97 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #                    QTGMC 3.33, by Vit, 2012                       #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.33s (mod) 2015 8 4
  16. # - fix bug in YUY2 with SourceMatch
  17. # - add slice=false to ditherpost to avoid artefacts
  18. #
  19. # v3.33s (mod)
  20. # - fix bob chroma
  21. # - work with new masktool2 for avs 2.60
  22. #
  23. # v3.33d (mod)
  24. # - Added 32 bit precision option through the lsbd (for dfttest) and lsb (mdegrain) options.
  25. # - optimized some mask handling a bit as originally suggested by Vit
  26. # - others
  27. #
  28. # v3.33
  29. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  30. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  31. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  32. # - Minor change to denoising
  33. #
  34. # v3.32
  35. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  36. # - Tweaked vector recalculation for shutter motion blur
  37. # - Changed defaults for TR2 when using source-match
  38. # - Minor bugfix with SLMode/SLRad on pass-through settings
  39. #
  40. # --- REQUIREMENTS ---
  41. #
  42. # Input colorspaces: YV12, YUY2
  43. #
  44. # Core plugins:
  45. #   MVTools2 (2.5.11.3 or above)
  46. #   MaskTools v2 (recommend 2.0a48 or above. Must use the 2.5 version with YUY2)
  47. #   NNEDI3 (recommend 0.9.4 or above for speed)
  48. #   RemoveGrain + Repair (several versions of this plugin, use the SSE2 dlls from the file called "RemoveGrain-1.0.rar". Don't use the SSE3 versions )
  49. #   SSE2Tools for YUY2 support (from the earlier 0.9 version of RemoveGrain, use only SSE2Tools.dll from this version. Don't use the SSE3 version)
  50. #
  51. # Additional plugins:
  52. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  53. #   Yadif - for Preset="Ultra Fast" or if selected directly (cannot be autoloaded, must be loaded in the calling script)
  54. #   VerticalCleaner - for SVThin or Lossless modes
  55. #   FFT3DFilter - if selected for noise processing
  56. #   dfttest - if selected for noise processing
  57. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  58. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  59. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  60.  
  61.  
  62. # --- GETTING STARTED ---
  63. #
  64. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  65. # To use QTGMC write a script like this:
  66. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  67. #   QTGMC( Preset="Slow" )
  68. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  69. #
  70. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  71. #
  72. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  73. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  74. # The default preset is "Slower"
  75. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  76. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  77. #
  78. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  79. #   QTGMC( Preset="Slow", ShowSettings=true )
  80.  
  81.  
  82. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  83.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  84.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  85.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  86.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  87.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  88.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  89.                     int "DftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  90.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  91.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  92.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  93.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", bool "lsbd", bool "lsb" )
  94. {
  95.     # The preset "Ultra Fast" & EdiMode="RepYadif"/"Yadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  96.     # To have this script load Yadif put it's full path in string below (e.g. "C:\Plugins\Yadif.dll"). Use empty string ("") if calling script will load Yadif
  97.     YadifPath = "" # Or just enter "yadif.dll" if Yadif is placed in the system path (e.g. windows\system32)
  98.  
  99.     # Temporary Warnings
  100.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  101.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  102.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  103.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  104.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  105.  
  106.     #---------------------------------------
  107.     # Presets
  108. lsbd=default(lsbd, false)
  109. lsb=default(lsb, false)
  110.     # Select presets / tuning
  111.     Preset = default( Preset, "Slower" )
  112.     pNum = (Preset == "Placebo"   ) ? 0 : \
  113.            (Preset == "Very Slow" ) ? 1 : \
  114.            (Preset == "Slower"    ) ? 2 : \
  115.            (Preset == "Slow"      ) ? 3 : \
  116.            (Preset == "Medium"    ) ? 4 : \
  117.            (Preset == "Fast"      ) ? 5 : \
  118.            (Preset == "Faster"    ) ? 6 : \
  119.            (Preset == "Very Fast" ) ? 7 : \
  120.            (Preset == "Super Fast") ? 8 : \
  121.            (Preset == "Ultra Fast") ? 9 : \
  122.            (Preset == "Draft"     ) ? 10 : 11
  123.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  124.  
  125.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  126.              (MatchPreset == "Placebo"   ) ? 0 : \
  127.              (MatchPreset == "Very Slow" ) ? 1 : \
  128.              (MatchPreset == "Slower"    ) ? 2 : \
  129.              (MatchPreset == "Slow"      ) ? 3 : \
  130.              (MatchPreset == "Medium"    ) ? 4 : \
  131.              (MatchPreset == "Fast"      ) ? 5 : \
  132.              (MatchPreset == "Faster"    ) ? 6 : \
  133.              (MatchPreset == "Very Fast" ) ? 7 : \
  134.              (MatchPreset == "Super Fast") ? 8 : \
  135.              (MatchPreset == "Ultra Fast") ? 9 : \
  136.              (MatchPreset == "Draft"     ) ? 10 : 11
  137.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  138.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  139.  
  140.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  141.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  142.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  143.              (MatchPreset2 == "Slower"    ) ? 2 : \
  144.              (MatchPreset2 == "Slow"      ) ? 3 : \
  145.              (MatchPreset2 == "Medium"    ) ? 4 : \
  146.              (MatchPreset2 == "Fast"      ) ? 5 : \
  147.              (MatchPreset2 == "Faster"    ) ? 6 : \
  148.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  149.              (MatchPreset2 == "Super Fast") ? 8 : \
  150.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  151.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  152.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  153.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  154.  
  155.     NoisePreset = default( NoisePreset, "Fast" )
  156.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  157.             (NoisePreset == "Slow"   ) ? 1 : \
  158.             (NoisePreset == "Medium" ) ? 2 : \
  159.             (NoisePreset == "Fast"   ) ? 3 : \
  160.             (NoisePreset == "Faster" ) ? 4 : 5
  161.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  162.  
  163.     Tuning = default( Tuning, "None" )
  164.     tNum = (Tuning == "None"  ) ? 0 : \
  165.            (Tuning == "DV-SD" ) ? 1 : \
  166.            (Tuning == "DV-HD" ) ? 2 : 3
  167.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  168.  
  169.     # Tunings only affect blocksize in this version
  170.     bs = Select( tNum,  16, 16, 32 )
  171.     bs2 = (bs >= 16) ? 32 : bs * 2
  172.  
  173.     #                                                               Very                                                        Very      Super      Ultra
  174.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  175.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         1      ) )
  176.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  177.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  178.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  179.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  180.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  181.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  182.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  183.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  184.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  185.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  186.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  187.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  188.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  189.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  190.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  191.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  192.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  193.     bs = Blocksize
  194.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  195.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  196.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  197.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  198.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  199.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  200.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  201.  
  202.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  203.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  204.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  205.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  206.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  207.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  208.  
  209.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  210.     SourceMatch   = default( SourceMatch, 0 )
  211.     MatchNNSize   = NNSize
  212.     MatchNNeurons = NNeurons
  213.     MatchEdiMaxD  = EdiMaxD
  214.     MatchEdiQual  = EdiQual
  215.  
  216.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  217.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  218.     #                                                                    Very                                                        Very      Super     Ultra
  219.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  220.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  221.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  222.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  223.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  224.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  225.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  226.     MatchEdi = TempEdi
  227.  
  228.     #                                                          Very                                                        Very      Super     Ultra
  229.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  230.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  231.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  232.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  233.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  234.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  235.  
  236.  
  237.     #---------------------------------------
  238.     # Settings
  239.  
  240.     # Core and Interpolation defaults
  241.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  242.     RepChroma  = default( RepChroma,  true )
  243.     EdiThreads = default( EdiThreads, 0    )
  244.     ChromaEdi  = default( ChromaEdi,  ""   )
  245.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  246.     EdiQual    = (EdiMode == "NNEDI3" && EdiQual > 2 ) ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  247.     ((FindStr( EdiMode, "Yadif" ) != 0 || FindStr( MatchEdi, "Yadif" ) != 0 || FindStr( MatchEdi2, "Yadif" ) != 0  ) && YadifPath != "") ? \
  248.         Load_Stdcall_Plugin( YadifPath ) : NOP() # Load Yadif as required
  249.  
  250.     # Source-match / lossless defaults
  251.     MatchTR1     = TR1
  252.     MatchTR2     = default( MatchTR2,     1   )
  253.     MatchEnhance = default( MatchEnhance, 0.5 )
  254.     Lossless     = default( Lossless,     0   )
  255.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  256.  
  257.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  258.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  259.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  260.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  261.     spatialSL  = (SLMode == 1 || SLMode == 3)
  262.     temporalSL = (SLMode == 2 || SLMode == 4)
  263.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  264.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  265.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  266.     Sbb        = (SMode == 0) ? 0 : Sbb
  267.     SOvs       = default( SOvs,   0   )
  268.     SVThin     = default( SVThin, 0.0 )
  269.  
  270.     # Noise processing settings
  271.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  272.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  273.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  274.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  275.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  276.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  277.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  278.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  279.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  280.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  281.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  282.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  283.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  284.     Sigma        = defined(Sigma)       ? Sigma : \
  285.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  286.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  287.     DftThreads   = default( DftThreads, EdiThreads )
  288.     ChromaNoise  = default( ChromaNoise, false )
  289.     ShowNoise    = default( ShowNoise, 0.0 )
  290.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  291.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  292.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  293.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  294.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  295.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  296.     totalRestore = GrainRestore + NoiseRestore
  297.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  298.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  299.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  300.  
  301.     # MVTools settings
  302.     SubPelInterp = default( SubPelInterp, 2     )
  303.     TrueMotion   = default( TrueMotion,   false )
  304.     GlobalMotion = default( GlobalMotion, true  )
  305.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  306.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  307.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  308.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  309.     DCT          = default( DCT,     0          )
  310.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  311.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  312.     ThSCD1       = default( ThSCD1,  180        )
  313.     ThSCD2       = default( ThSCD2,  98         )
  314.  
  315.     # Motion blur settings
  316.     FPSDivisor  = default( FPSDivisor, 1 )
  317.     ShutterBlur = default( ShutterBlur, 0 )
  318.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  319.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  320.     SBlurLimit  = default( SBlurLimit, 4 )
  321.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  322.  
  323.     # Miscellaneous
  324.     InputType      = default( InputType,     0        )
  325.     Border         = default( Border,        false    )
  326.     ShowSettings   = default( ShowSettings,  false    )
  327.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  328.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  329.     ForceTR        = default( ForceTR,       0        )
  330.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  331.     ReuseGlobals   = (PrevGlobals == "Reuse")
  332.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  333.     rgBlur         = (Precise) ? 11 : 12
  334.  
  335.     # Get maximum temporal radius needed
  336.     maxTR = (temporalSL)       ? SLRad : 0
  337.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  338.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  339.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  340.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  341.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  342.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  343.  
  344.  
  345.     #---------------------------------------
  346.     # Pre-Processing
  347.  
  348.     w = Input.Width()
  349.     h = Input.Height()
  350.     yuy2 = Input.IsYUY2()
  351.     epsilon = 0.0001
  352.  
  353.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  354.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  355.  
  356.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  357.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  358.     h = (Border) ? h+8 : h
  359.  
  360.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  361.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  362.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  363.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  364.     vpad = (vpad > 8) ? vpad : 8
  365.  
  366.  
  367.     #---------------------------------------
  368.     # Motion Analysis
  369.  
  370.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  371.     planarClip = yuy2 ? clip.Interleaved2Planar() : clip
  372.  
  373.     # Bob the input as a starting point for motion search clip
  374.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  375.              (InputType == 1) ? planarClip : \
  376.                                 planarClip.Blur( 0,1 )
  377.  
  378.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  379.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  380.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  381.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  382.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  383.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  384.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  385.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  386.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  387.  
  388.     CMmt = ChromaMotion ? 3   :  1
  389.     CMts = ChromaMotion ? 255 :  0
  390.     CMrg = ChromaMotion ? 12  : -1
  391.  
  392.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  393.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  394.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  395.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  396.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  397.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  398.  
  399.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  400.     binomial0 = IsClip(srchClip) ? NOP() : \
  401.                 (TR0 == 0)       ? bobbed : \
  402.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )): \
  403.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  404.  
  405.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  406.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  407.  
  408.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  409.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  410.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  411.                   (!yuy2 && SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg, planar=true ).BilinearResize( w, h ) : \
  412.                   (!yuy2)                    ? repair0.RemoveGrain( 12,CMrg, planar=true ).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ) : \
  413.                                                repair0.RemoveGrain( 12,CMrg, planar=true ).Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ).Interleaved2Planar()
  414.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  415.     tweluin26 = isyuy2(repair0) ? mt_lutxy( repair0.planar2interleaved.ConvertToYV16, bobbed.planar2interleaved.ConvertToYV16, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ).ConvertToYuy2.interleaved2planar : \
  416.     mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt )
  417.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? tweluin26 : NOP()
  418.     srchClip    = IsClip(srchClip)  ? srchClip : \
  419.                   (SrchClipPP == 0) ? repair0 : \
  420.                   (SrchClipPP < 3)  ? spatialBlur : \
  421.                                       isclip(spatialBlur) && isyuy2(spatialBlur) ? spatialBlur.planar2interleaved.ConvertToYV16.mt_lutxy( isclip(tweaked) ? tweaked.planar2interleaved.ConvertToYV16 : tweaked, \
  422.     "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt ).ConvertToYuy2.interleaved2planar : \
  423.     spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  424.     # Calculate forward and backward motion vectors from motion search clip
  425.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  426.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion, planar=true ) : NOP()
  427.     bVec3 = IsClip(bVec3) ? bVec3 : \
  428.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  429.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  430.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  431.     bVec2 = IsClip(bVec2) ? bVec2 : \
  432.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  433.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  434.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  435.     bVec1 = IsClip(bVec1) ? bVec1 : \
  436.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  437.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  438.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  439.     fVec1 = IsClip(fVec1) ? fVec1 : \
  440.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  441.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  442.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  443.     fVec2 = IsClip(fVec2) ? fVec2 : \
  444.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  445.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  446.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  447.     fVec3 = IsClip(fVec3) ? fVec3 : \
  448.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  449.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  450.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  451.  
  452.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  453.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  454.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  455.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  456.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  457.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  458.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  459.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  460.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  461.  
  462.  
  463.     #---------------------------------------
  464.     # Noise Processing
  465.  
  466.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  467.  
  468.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  469.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  470.                 (InputType > 0)     ? clip : \
  471.                                       clip.QTGMC_Bob( 0,1.0 )
  472.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.Interleaved2Planar() : fullClip
  473.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP() #TEST chroma OK?
  474.  
  475.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  476.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  477.                   (!DenoiseMC)        ? fullClip : \
  478.                   (NoiseTR == 0)      ? fullClip : \
  479.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  480.                                                     fullClip, \
  481.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) ) : \
  482.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  483.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  484.                                                     fullClip, \
  485.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  486.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) )
  487.     noiseWindow = (yuy2 && NoiseTR > 0) ? noiseWindow.Planar2Interleaved() : noiseWindow
  488.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  489.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=DftThreads, lsb=lsbd ) : \
  490.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD )
  491.     dnwindow = (Denoiser == "dfttest") && lsbd ? isyuy2(Input) ? dnWindow.ConvertToYv16.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false).ConvertToYUY2 : dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  492.  
  493.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  494.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  495.     denoised = (NoiseProcess == 0) ? NOP() : \
  496.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  497.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  498.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  499.  
  500.     # >>>> Switch to planar YUY2 for noise bypass
  501.  
  502.     CNmt1   = ChromaNoise ? 3 : 1
  503.     CNmt2   = ChromaNoise ? 3 : 2
  504.     CNmt128 = ChromaNoise ? 3 : -128
  505.  
  506.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  507.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.Interleaved2Planar() : denoised
  508.     noise = (totalRestore > 0.0)  ? Isyuy2(planarClip) ? mt_makediff( planarClip.planar2interleaved.ConvertToYV16, isclip(planarDenoised) ? planarDenoised.planar2interleaved.ConvertToYV16 : planarDenoised, U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : \
  509.     mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  510.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  511.                  (InputType != 0)                           ? noise : \
  512.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  513.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  514.                                                               noise.DoubleWeave()
  515.     # Motion-compensated stabilization of generated noise
  516.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP()
  517.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  518.     finalNoise = (StabilizeNoise) ? isclip(deintNoise) && isyuy2(deintNoise) ? mt_lutxy( deintNoise.planar2interleaved.ConvertToYV16, mcNoise.planar2interleaved.ConvertToYV16, \
  519.     "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : isclip(mcNoise) && isyuy2(mcNoise) ? mt_lutxy( deintNoise, mcNoise.planar2interleaved.ConvertToYV16, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ).ConvertToYuy2.interleaved2planar : \
  520.     mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  521.  
  522.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  523.     innerClip = (NoiseProcess == 1) ? denoised : clip
  524.  
  525.  
  526.     #---------------------------------------
  527.     # Interpolation
  528.  
  529.     # >>>> Interleaved YUY2 for interpolation
  530.  
  531.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  532.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  533.  
  534.     # Create interpolated image as starting point for output
  535.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  536.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, \
  537.                                                 yuy2 ? clip.QTGMC_Bob( 0,0.5 ) : bobbed, ChromaEdi )
  538.  
  539.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  540.  
  541.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  542.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask, planar=true ) : NOP()
  543.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.Interleaved2Planar()) :\
  544.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).Interleaved2Planar()) : \
  545.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  546.                                                         mt_merge( innerClip.ConvertToYV16, edi1.ConvertToYV16, inputTypeBlend, U=2,V=2 ).ConvertToYuy2.interleaved2planar)
  547.  
  548.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  549.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  550.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  551.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  552.     tMax     = (temporalSL)              ? isyuy2(edi) ? edi.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp1) ? fComp1.planar2interleaved.ConvertToYV16 : fComp1, "max", \
  553.     U=3,V=3 ).mt_logic( isclip(bComp1) ? bComp1.planar2interleaved.ConvertToYV16 : bComp1, "max", U=3,V=3 ).ConvertToYuy2.interleaved2planar : edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  554.     tMin     = (temporalSL)              ? isyuy2(edi) ? edi.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp1) ? fComp1.planar2interleaved.ConvertToYV16 : fComp1, "min", \
  555.     U=3,V=3 ).mt_logic( isclip(bComp1) ? bComp1.planar2interleaved.ConvertToYV16 : bComp1, "min", U=3,V=3 ).ConvertToYuy2.interleaved2planar : edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  556.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  557.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  558.     tMax     = (SLRad > 1 && temporalSL) ? isyuy2(tMax) ? tMax.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp3) ? fComp3.planar2interleaved.ConvertToYV16 : fComp3, "max", \
  559.     U=3,V=3 ).mt_logic( isclip(bComp3) ? bComp3.planar2interleaved.ConvertToYV16 : bComp3, "max", U=3,V=3 ).ConvertToYuy2.interleaved2planar : tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  560.     tMin     = (SLRad > 1 && temporalSL) ? isyuy2(tMin) ? tMin.planar2interleaved.ConvertToYV16.mt_logic( isclip(fComp3) ? fComp3.planar2interleaved.ConvertToYV16 : fComp3, "min", \
  561.     U=3,V=3 ).mt_logic( isclip(bComp3) ? bComp3.planar2interleaved.ConvertToYV16 : bComp3, "min", U=3,V=3 ).ConvertToYuy2.interleaved2planar : tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  562.  
  563.  
  564.     #---------------------------------------
  565.     # Create basic output
  566.  
  567.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  568.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  569.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  570.     # Create linear weightings of neighbors first                                                                                             -2    -1     0    1     2
  571.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  572.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  573.     degrain1 = (TR1 > 0) && lsb ? isyuy2(Input) ? degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : degrain1.ditherpost(mode=6, slice=false) : degrain1
  574.     degrain2 = (TR1 > 1) && lsb ? isyuy2(Input) ? degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : degrain2.ditherpost(mode=6, slice=false) : degrain2
  575.  
  576.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  577.     binomial1 = (TR1 == 0) ? edi : \
  578.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  579.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  580.  
  581.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  582.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  583.  
  584.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  585.     match = (SourceMatch == 0) ? repair1 : \
  586.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  587.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  588.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  589.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  590.  
  591.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  592.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  593.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  594.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  595.  
  596.  
  597.     #---------------------------------------
  598.     # Resharpen / retouch output
  599.  
  600.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  601.     vresharp1 = (SMode == 2) ? isyuy2(lossed1) ? Merge( lossed1.planar2interleaved.ConvertToYV16.mt_expand( mode="vertical", U=3,V=3 ), \
  602.     lossed1.planar2interleaved.ConvertToYV16.mt_inpand( mode="vertical", U=3,V=3 ) ).ConvertToYuy2.interleaved2planar : \
  603.     Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  604.     vresharp  = (Precise && SMode == 2) ? isclip(vresharp1) && isyuy2(vresharp1) ? vresharp1.planar2interleaved.ConvertToYV16.mt_lutxy( lossed1.planar2interleaved.ConvertToYV16, \
  605.     "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ).ConvertToYuy2.interleaved2planar : vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  606.     resharp   = (SMode == 0) ? lossed1 : \
  607.                 (SMode == 1) ? isyuy2(lossed1) ? lossed1.planar2interleaved.ConvertToYV16.mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ).planar2interleaved.ConvertToYV16,  \
  608.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  609.                                isyuy2(lossed1) ? lossed1.planar2interleaved.ConvertToYV16.mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ).planar2interleaved.ConvertToYV16, \
  610.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  611.  
  612.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  613.     SVThinSc = SVThin * 6.0
  614.     vertMedD = (SVthin > 0.0) ? isyuy2(lossed1) ? mt_lutxy( lossed1.planar2interleaved.ConvertToYV16, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ).planar2interleaved.ConvertToYV16, \
  615.     "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ).ConvertToYuy2.interleaved2planar : mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  616.     vertMedD = (SVthin > 0.0) ? (!yuy2 ? vertMedD.Blur( 1,0 ) : vertMedD.Planar2Interleaved().Blur( 1,0 ).Interleaved2Planar()) : NOP()
  617.     neighborD = (SVthin > 0.0) ? isclip(vertMedD) && isyuy2(vertMedD) ? mt_lutxy( vertMedD.planar2interleaved.ConvertToYV16, vertMedD.RemoveGrain( rgBlur,-1, planar=true ).planar2interleaved.ConvertToYV16, \
  618.     "y 128 - abs x 128 - abs > y 128 ?" ).ConvertToYuy2.interleaved2planar : mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1, planar=true ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  619.     thin      = (SVthin > 0.0) ? isclip(resharp) && isyuy2(resharp) ? resharp.planar2interleaved.ConvertToYV16.mt_adddiff( isclip(neighborD) ? neighborD.planar2interleaved.ConvertToYV16 : neighborD, U=2,V=2 ).ConvertToYuy2.interleaved2planar : resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  620.  
  621.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  622.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  623.                  !yuy2 ? thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  624.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  625.                          thin.planar2interleaved.ConvertToYV16.mt_makediff( mt_makediff( thin.planar2interleaved.ConvertToYV16, lossed1.planar2interleaved.ConvertToYV16, U=1,V=1 ).ConvertToYuy2.interleaved2planar.RemoveGrain( 12, -1, planar=true ) \
  626.                              .Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16, U=2,V=2 ).ConvertToYuy2.Interleaved2Planar()
  627.  
  628.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  629.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  630.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  631.                   (SLMode == 2) ? isyuy2(backBlend1) ? backBlend1.planar2interleaved.ConvertToYV16.mt_clamp( tMax.planar2interleaved.ConvertToYV16,tMin.planar2interleaved.ConvertToYV16, Sovs,Sovs, U=3,V=3 ).ConvertToYuy2.interleaved2planar : backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  632.                                   backBlend1
  633.  
  634.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  635.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  636.                  !yuy2     ? sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  637.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  638.                              sharpLimit1.planar2interleaved.ConvertToYV16.mt_makediff( mt_makediff( sharpLimit1.planar2interleaved.ConvertToYV16, lossed1.planar2interleaved.ConvertToYV16, U=1,V=1 ).ConvertToYuy2.interleaved2planar.RemoveGrain( 12, -1, planar=true ) \
  639.                                         .Planar2Interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16, U=2,V=2 ).ConvertToYuy2.Interleaved2Planar()
  640.  
  641.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  642.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  643.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  644.         isyuy2(backBlend2) ? backBlend2.planar2interleaved.ConvertToYV16.mt_adddiff( finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYuy2.interleaved2planar : \
  645.         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  646.  
  647.     # Final light linear temporal smooth for denoising
  648.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  649.     stable  = (TR2 == 0) ? addNoise1 : \
  650.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  651.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  652.                            addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb )
  653.     stable  = (TR2 > 0) && lsb ? isyuy2(Input) ? stable.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.Interleaved2Planar() : stable.ditherpost(mode=6, slice=false) : stable
  654.  
  655.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  656.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  657.  
  658.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  659.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  660.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  661.                   (SLMode == 4) ? isyuy2(repair2) ? repair2.planar2interleaved.ConvertToYV16.mt_clamp( tMax.planar2interleaved.ConvertToYV16,tMin.planar2interleaved.ConvertToYV16, Sovs,Sovs, U=3,V=3 ).ConvertToYuy2.interleaved2planar : repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  662.                                   repair2
  663.  
  664.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  665.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  666.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  667.  
  668.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  669.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  670.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  671.         isyuy2(lossed2) ? lossed2.planar2interleaved.ConvertToYV16.mt_adddiff( finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYuy2.interleaved2planar : \
  672.         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  673.  
  674.  
  675.     #---------------------------------------
  676.     # Post-Processing
  677.  
  678.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  679.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  680.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  681.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  682.  
  683.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  684.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  685.     rBlockSize = BlockSize / rBlockDivide
  686.     rOverlap   = Overlap   / rBlockDivide
  687.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  688.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  689.     rBlockDivide = BlockSize / rBlockSize
  690.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  691.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  692.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  693.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  694.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  695.  
  696.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  697.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  698.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  699.  
  700.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  701.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit, planar=true ) : NOP()
  702.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  703.                    (SBlurLimit == 0)  ? sblur : \
  704.                                         isyuy2(addNoise2) ? mt_merge( addNoise2.planar2interleaved.ConvertToYV16, isclip(sblur) ? sblur.planar2interleaved.ConvertToYV16 : sblur, sbMotionMask.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  705.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  706.     # Reduce frame rate
  707.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  708.  
  709.     # Crop off temporary vertical padding
  710.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  711.     h = Border ? h-8 : h
  712.  
  713.     # Show output of choice + settings
  714.     # >>>> Restore YUY2 to interleaved
  715.     output = (ShowNoise == 0.0) ? cropped : isyuy2(finalNoise) ? finalNoise.planar2interleaved.ConvertToYV16.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 ).ConvertToYuy2.interleaved2planar : \
  716.     finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  717.     output = yuy2 ? output.Planar2Interleaved() : output
  718.     return (ShowSettings == false) ? output : \
  719.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  720.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  721.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  722.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  723.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  724.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  725.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  726.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  727.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  728.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  729.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  730.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  731.         Denoiser + "' | DftThreads=" + string(DftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  732.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  733.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  734.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  735.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  736.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  737.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  738.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  739. }
  740.  
  741.  
  742. #---------------------------------------
  743. # Helpers
  744.  
  745. # Same as Bob, but keeps the field order the same.
  746. function QTGMC_Bob(clip clip, float "b", float "c", float "height" )
  747. {
  748.   h = Default(Height, Height(clip))
  749.   w = clip.Width
  750.  
  751.   oiFields=clip.AssumeTFF().SeparateFields()
  752.   Ec = oiFields.SelectEven().BicubicResize(w, h, b, c,  src_top=0.5).AssumeFrameBased()
  753.   Oc = oiFields.SelectOdd( ).BicubicResize(w, h, b, c, src_top=-0.5).AssumeFrameBased()
  754.   crchroma=GetParity(clip) ? Interleave(Ec, Oc).AssumeTFF() : Interleave(Oc, Ec).AssumeBFF()
  755.     (clip.GetParity()) ? clip.Bob( b,c, height ).AssumeTFF() : \
  756.                          clip.Bob( b,c, height ).AssumeBFF()
  757.         IsYV12(clip) ? MergeChroma(crchroma) : last
  758. }
  759.  
  760.  
  761. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  762. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  763. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  764.                             string "ChromaEdi" )
  765. {
  766.     # >>>> YUY2 is interleaved here
  767.  
  768.     ChromaEdi = default( ChromaEdi, "" )
  769.     CEed = (ChromaEdi == "")
  770.  
  771.     interp = (InputType == 1)            ? Input : \
  772.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  773.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  774.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  775.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  776.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  777.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  778.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  779.              (EdiMode == "Yadif")        ? Input.Yadif( mode=3 ) : \
  780.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  781.              (EdiMode == "RepYadif")     ? Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  782.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  783.  
  784.     interpuv = (InputType == 1)        ? NOP() : \
  785.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  786.                (ChromaEdi == "Yadif")  ? Input.Yadif( mode=3 ) : \
  787.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  788.                                          NOP()
  789.  
  790.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  791. }
  792.  
  793. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  794. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  795. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  796. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  797. {
  798.     # >>>> YUY2 is planar here
  799.  
  800.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 5 = maximum
  801.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  802.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  803.     Rep    = default( Rep,    1    )
  804.     Chroma = default( Chroma, true )
  805.     ed = (Rep < 10) ? Rep : Rep / 10
  806.     od = (Rep < 10) ? 0   : Rep % 10
  807.     RCrg  = Chroma ? 3 : 1
  808.     RCrgo = Chroma ? 3 : 2
  809.  
  810.     diff = mt_makediff(Isyuy2(Ref) ? Ref.planar2interleaved.ConvertToYV16 : Ref, Isyuy2(Input) ? Input.planar2interleaved.ConvertToYV16 : Input, U=3,V=3 )
  811.  
  812.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  813.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  814.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  815.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  816.     choke1 = (ed % 3 != 0)        ? choke1.mt_deflate( U=RCrg,V=RCrg )                 : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  817.     choke1 = Isyv16(choke1) ? choke1.ConvertToYuy2.interleaved2planar : choke1
  818.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4, planar=true )               : choke1   #      . . x . . x . .    Local median
  819.                                                                                                                      
  820.     choke1 = Isyuy2(choke1) ? choke1.planar2interleaved.ConvertToYV16 : choke1
  821.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  822.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  823.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  824.  
  825.     # Over-dilation - extra reflation up to about 1 pixel
  826.     choke1 = (od == 0)            ? choke1 : \
  827.              (od == 1)            ? choke1.mt_inflate( U=RCrg,V=RCrg ) : \
  828.              (od == 2)            ? choke1.mt_inflate( U=RCrg,V=RCrg ).mt_inflate( U=RCrg,V=RCrg ) : \
  829.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  830.  
  831.     # Areas of negative difference (similar to above)
  832.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  833.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  834.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  835.     choke2 = (ed % 3 != 0)        ? choke2.mt_inflate( U=RCrg,V=RCrg )                 : choke2
  836.     choke2 = Isyv16(choke2) ? choke2.ConvertToYuy2.interleaved2planar : choke2
  837.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4, planar=true )               : choke2
  838.     choke2 = Isyuy2(choke2) ? choke2.planar2interleaved.ConvertToYV16 : choke2
  839.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  840.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  841.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  842.     choke2 = (od == 0)            ? choke2 : \
  843.              (od == 1)            ? choke2.mt_deflate( U=RCrg,V=RCrg )  : \
  844.              (od == 2)            ? choke2.mt_deflate( U=RCrg,V=RCrg ).mt_deflate( U=RCrg,V=RCrg ) : \
  845.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  846.  
  847.     # Combine above areas to find those areas of difference to restore
  848.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  849.     fin4ret = Isyuy2(Input) ? Input.planar2interleaved.ConvertToYV16.mt_adddiff( restore, U=RCrgo,V=RCrgo ) : Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  850.     return Isyuy2(Ref) ? fin4ret.ConvertToYuy2.interleaved2planar : fin4ret
  851. }
  852.  
  853.  
  854. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  855. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  856. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  857. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  858. {
  859.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  860.     ChromaNoise = default( ChromaNoise, false )
  861.     CNmt1 = ChromaNoise ? 3 : 1
  862.     origNoise = Input.SeparateFields()
  863.     origNoise = Isyuy2(origNoise) ? origNoise.planar2interleaved.ConvertToYV16 : origNoise
  864.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  865.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  866.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  867.     random    = InterleavedClip.IsYUY2() ? random.ConvertToYV16 : random
  868.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  869.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  870.     return Isyuy2(origNoise) ? Interleave( origNoise, newNoise ).Weave().ConvertToYuy2.interleaved2planar : Interleave( origNoise, newNoise ).Weave()
  871. }
  872.  
  873.  
  874. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  875. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  876. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  877. {
  878.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  879.  
  880.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  881.  
  882.     # Weave the source fields and the "new" fields that have generated in the input
  883.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  884.     srcFields  = Source.IsYUY2() ? srcFields1.Interleaved2Planar() : srcFields1
  885.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  886.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  887.  
  888.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  889.     vertMedian  = processed.VerticalCleaner( mode=1, planar=true )
  890.     vertMedDiff = mt_makediff( Isyuy2(processed) ? processed.planar2interleaved.ConvertToYV16 : \
  891.     processed, Isyuy2(vertMedian) ? vertMedian.planar2interleaved.ConvertToYV16 : vertMedian, U=3,V=3 )
  892.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  893.     vmNewDiff1  = Isyv16(vmNewDiff1) ? vmNewDiff1.ConvertToYuy2.interleaved2planar : vmNewDiff1
  894.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1, planar=true )
  895.     vmNewDiff2  = Isyuy2(vmNewDiff2) ? vmNewDiff2.planar2interleaved.ConvertToYV16.mt_lutxy( vmNewDiff1.planar2interleaved.ConvertToYV16, \
  896.     "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 ) : \
  897.     vmNewDiff2.mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  898.     vmNewDiff2  = Isyv16(vmNewDiff2) ? vmNewDiff2.ConvertToYuy2.interleaved2planar : vmNewDiff2
  899.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2, planar=true ), 1, planar=true )
  900.  
  901.     # Reweave final result
  902.     newfd = Isyuy2(newFields) ? newFields.planar2interleaved.ConvertToYV16.mt_makediff( vmNewDiff3.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  903.     newFields.mt_makediff( vmNewDiff3, U=3,V=3 )
  904.     return Interleave( srcFields, newfd).SelectEvery( 4, 0,1,3,2 ).Weave()
  905. }
  906.  
  907.  
  908. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  909. # the source without introducing shimmer. All other arguments defined in main script
  910. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  911.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  912.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  913.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  914.                                  float MatchEnhance, int EdiThreads, bool lsb )
  915. {
  916.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  917.     yuy2 = Source.IsYUY2()
  918.     Source = yuy2 ? Source.Interleaved2Planar() : Source
  919.  
  920.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  921.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  922.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  923.     # this new source. Result will still be shimmer-free and closer to the original source.
  924.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  925.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  926.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  927.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  928.     errorTemporalSimilarity = 0.5  # S in formula described above
  929.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  930.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  931.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  932.                         ? Source : Isyuy2(Source) ? mt_lutxy( Source.planar2interleaved.ConvertToYV16, match1Clip.planar2interleaved.ConvertToYV16, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  933.                         mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  934.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  935.                      !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  936.                              match1Update.Planar2Interleaved() \
  937.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  938.                                          .Interleaved2Planar()
  939.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  940.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  941.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  942.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? Isyuy2(Deinterlace) ? match1Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  943.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? Isyuy2(Deinterlace) ? match1Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  944.     match1         = (SourceMatch < 1) ? Deinterlace : \
  945.                      (MatchTR1 == 0)   ? match1Edi : \
  946.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  947.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  948.  
  949.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  950.     malu = Isyuy2(match1) ? match1.planar2interleaved.ConvertToYV16.mt_lutxy( match1.RemoveGrain( 12, planar=true ).planar2interleaved.ConvertToYV16, \
  951.     "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  952.     match1.mt_lutxy( match1.RemoveGrain( 12, planar=true ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 )
  953.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? malu : match1
  954.  
  955.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  956.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  957.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  958.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  959.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  960.     matchdifyuyin26= Isclip(Source) ? Isyuy2(Source) ? mt_makediff( Source.planar2interleaved.ConvertToYV16, match2Clip.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : nop() : nop()
  961.     match2Diff     = (SourceMatch > 1) ? !Isyuy2(Deinterlace) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : matchdifyuyin26 : NOP()
  962.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  963.                      !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  964.                              match2Diff.Planar2Interleaved() \
  965.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  966.                                        .Interleaved2Planar()
  967.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  968.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  969.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  970.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? isyuy2(match2Degrain1) ? match2Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  971.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? isyuy2(match2Degrain2) ? match2Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  972.     match2         = (SourceMatch < 2) ? match1 : \
  973.                      (MatchTR2 == 0)   ? match2Edi : \
  974.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  975.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  976.  
  977.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  978.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  979.     matlutin26 = Isyuy2(Deinterlace) && isclip(match2Edi) ? mt_lutxy( match2Edi.planar2interleaved.ConvertToYV16, match2.planar2interleaved.ConvertToYV16, \
  980.     "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ).ConvertToYuy2.interleaved2planar : nop()
  981.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  982.                          ? match2Edi : !Isyuy2(Deinterlace) ? mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ) : matlutin26
  983.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  984.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  985.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  986.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? isyuy2(match3Degrain1) ? match3Degrain1.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  987.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? isyuy2(match3Degrain2) ? match3Degrain2.planar2interleaved.ConvertToYV16.ditherpost(mode=6, slice=false).ConvertToYuy2.interleaved2planar : match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  988.     match3         = (SourceMatch < 3) ? match2 : \
  989.                      (MatchTR2 == 0)   ? match3Update : \
  990.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  991.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  992.  
  993.     # Apply difference calculated in source-match refinement
  994.     return (SourceMatch < 2) ? match1 : Isyuy2(match1Shp) ? match1Shp.planar2interleaved.ConvertToYV16.mt_adddiff( match3.planar2interleaved.ConvertToYV16, U=3,V=3 ).ConvertToYuy2.interleaved2planar : \
  995.     match1Shp.mt_adddiff( match3, U=3,V=3 )
  996. }
  997.  
  998.  
  999. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1000. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1001. {
  1002.     Replace = default( Replace, false )
  1003.     globalName = Prefix + "_" + Name
  1004.  
  1005.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1006.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1007.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1008.     catch (e)
  1009.     {
  1010.         Eval( "global " + globalName + " = Value" )
  1011.         Replace = true
  1012.     }
  1013.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1014. }
  1015.  
  1016. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1017. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1018. {
  1019.     Reuse = default( Reuse, false )
  1020.     globalName = Prefix + "_" + Name
  1021.  
  1022.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1023.     catch (e) { ret = NOP() }
  1024.     return ret
  1025. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!