*
* CASE FOR ATOMIC FIRST LIST OF DOUBLET
*
 EVQAT PDX     0,4
       TXL     EVQNF,4,0          EXIT IF END OF ATOM
       CLA     0,4                NEXT WORD
       PAX     0,4                CAR OF ATOM
       STL     EVQST              SET SWITCH FOR SUBR OF EXPR
       TXL     *+2,4,$SUBR-1      LOOK FOR $SUBR
       TXL     EVQFS,4,$SUBR      TREAT AS FSUBR (ALMOST)
       TXL     *+2,4,$EXPR-1      LOOK FOR $EXPR
       TXL     EVQFX,4,$EXPR      TREAT AS FEXPR (ALMOST)
       STZ     EVQST              SET SWITCH FOR FSUBR OR FEXPR
       TXL     *+2,4,$FSUBR-1     LOOK FOR FSUBR
       TXL     EVQFS,4,$FSUBR
       TXL     EVQAT,4,$FEXPR-1   LOOK FOR FEXPR
       TXH     EVQAT,4,$FEXPR
 EVQFX PDX     0,4                FOUND AN FEXPR
       CLA     0,4
       PAX     0,4                THE EXPRESSION FOR THE FEXPR
       PXD     0,4                EXPRESSION TO AC
       ZET     EVQST              SKIP IF FEXPR
       TRA     EVQZ               GO TO APPLY CALL FOR EXPR
       STO     EVQAN              SAVE THE EXPRESSION
       STQ     EVQMQ              SAVE MQ
       PXD     0,0                CLEAR
       XCA                        MQ AND
       PXD     0,0                AC
       TSX     $CONS,4            NULL A LIST
       XCA                        INTO MQ
       CLA     EVQMQ              PUT SECOND LIST IN AC
       TSX     $CONS,4            CONS(L,A)
       XCA                        ANSWER TO ARG 2
       CLA     EVQAN              FEXPR
       TRA     EVQZ               GO TO APPLY FOR FEXPR