Railblaster

Actor Railblaster : Doomweapon replaces CERailgun {
  SpawnID 164
  Radius 20
  Height 16
  Weapon.Selectionorder 100
  Weapon.AmmoType "Cell"
  Weapon.AmmoGive 40
  Weapon.AmmoUse 10
  Weapon.SlotNumber 6
  Weapon.SlotPriority 0.9
  Inventory.Pickupmessage "You got the cryo-railblaster!"
  Obituary "$OB_RAILGUN" // "%o was railed by %k."
  Decal "RailScorch"
  +WEAPON.NOAUTOAIM
  States {
    Ready:
      RLGG A 1 A_WeaponReady
      Loop
    Deselect:
      RLGG A 1 A_Lower
      Loop
    Select:
      RLGG A 1 A_Raise
      Loop
    Fire:
      RLGG E 0 A_GunFlash
      RLGG E 0 A_FireBullets(0, 0, 1, 0, "BlastPuff", 0)
      RLGG E 16 A_RailAttack(random(31, 76), 0, 1, none, SteelBlue)
      RLGG F 6
      RLGG G 6 A_PlayWeaponSound("weapons/RailGunOut")
      RLGG HIJ 6
      RLGG K 6 A_PlayWeaponSound("weapons/RailGunIn")
      RLGG LA 6
      RLGG A 0 A_ReFire
      goto Ready
    Flash:
      TNT1 A 2 bright A_Light1
      TNT1 A 4 bright A_Light2
      TNT1 A 4 bright A_Light1
      TNT1 A 0 bright A_Light0
      Goto LightDone
    Spawn:
      RAIL A -1
      Stop
  }
}

ACTOR BlastPuff : BulletPuff {
  +NOBLOCKMAP
  +NOGRAVITY
  +ALLOWPARTICLES
  +RANDOMIZE
  +PUFFONACTORS
  +ALWAYSPUFF
  +PUFFGETSOWNER
  RenderStyle Translucent
  Alpha 0.8
  Translation Ice
  VSpeed 0
  Mass 5
  DamageType "Ice"
  Obituary "%o was frosted by %k's railblaster."
  States {
    Spawn:
      MISL B 0
      MISL B 0 A_PlaySound("weapons/rocklx")
      MISL B 8 bright A_Explode(64, 128)
      MISL C 6 bright
      MISL D 4 bright
      stop
  }
}