mIRC - Kick and Ban aliases

; assumes global %eccol which is a number from 1 to 15
; (which I use as standard /echo colour; i.e. 5)

; /multimode [#<channel>] +- <mode> <nick1> ... <nickn>
; set multiple params with same mode in instances of %limit
/multimode {
  var %i = 0, %limit = 6, %chan = #, %plumin = $$1, %mode = $$2, %inc = 2
  if ($$1 ischan) {
    %chan = $$1
    %plumin = $$2
    %mode = $$3
    inc %inc
  }
  while ($calc(%i * %limit + %inc) <= $0) {
    /mode %chan $+(%plumin,$str(%mode,%limit)) [ [ $+($,[ $calc(%i * %limit + %inc + 1) ],-,[ $calc((%i + 1) * %limit + %inc) ]) ] ]
    inc %i
  }
}

/bban /multimode $$1 + b $$2- | set %lastban $$2-
/ban /bban # $$1-
/banmask {
  ;/banmask [<#channel>] <nick> [<host-param = 1>]
  if ($$1 ischan) {
    var %chan $$1
    var %nick $$2
    var %mask $3
  }
  else {
    var %chan #
    var %nick $$1
    var %mask $2
  }
  if (%mask == $null) {
    %mask = 1
  }
  /bban %chan $address(%nick, %mask)
}
/unban /multimode # - b $$1-
/unbanlast /unban %lastban | unset %lastban

/k {
  if ($2 != $null) {
    /kick # $$1 $2-
  }
  else {
    /kick # $$1 $$1
  }
}
/kickban {
  ;/bankick <channel> <nick> <host-param> <reason>
  /banmask $$1 $$2 $$3
  /kick $$1 $$2 $$4-
}
/kb {
  ;/bk <nick> [<host-param = 2> [<reason = nick>]]
  if ($2 == $null) {
    /kickban # $$1 2 $$1
  }
  else if ($3 == $null) {
    /kickban # $$1 $$2 $$1
  }
  else {
    /kickban # $$1 $$2 $$3-
  }
}
/kbhelp {
  echo -
  echo %eccol *** Syntax ***
  echo %eccol *-* /bankick <channel> <nick> <host-param> <reason> *-*
  echo %eccol *-* /bk <nick> [<host-param = 2> [<reason = nick>]] *-*
  echo %eccol -
  echo %eccol -+ Host-param           +-
  echo %eccol -| 0:    *! user@  host |-
  echo %eccol -| 1:    *!*user@  host |-
  echo %eccol -| 2:    *!    *@  host |-
  echo %eccol -| 3:    *!*user@*.host |-
  echo %eccol -| 4:    *!    *@*.host |-
  echo %eccol -| 5: nick! user@  host |-
  echo %eccol -| 6: nick!*user@  host |-
  echo %eccol -| 7: nick!    *@  host |-
  echo %eccol -| 8: nick!*user@*.host |-
  echo %eccol -| 9: nick!    *@*.host |-
  echo %eccol -+----------------------+-
  echo %eccol *-* End Help *-*
  echo -
}