<cfcomponent>
    <cffunction name="init" access="public" output="false">
        <cfargument name="transferFactory" type="transfer.TransferFactory" required="true" />
        <cfset variables.transfer = arguments.transferFactory.getTransfer() />
        <cfset variables.datasourceObj = arguments.transferFactory.getDatasource() />
        <cfreturn this />
    </cffunction>

    <!--- Query using plain SQL --->
    <cffunction name="getMySQLQuery">
        <cfargument name="id" />
        <cfset var qResultQuery = "" />

        <!--- Direct SQL query --->
        <cfquery name="qResultQuery" datasource="#datasourceObj.getName()#" username="#datasourceObj.getUsername()#" password="#datasourceObj.getPassword()#">
            SELECT myTable.myColumn
            FROM myTable
            WHERE myTable.myID = <cfqueryparam cfsqltype="cf_sql_integer" value="#arguments.id#" />
        </cfquery>

        <cfreturn qResultQuery>
    </cffunction>

    <!--- Query using TQL --->
    <cffunction name="getMyTQLQuery">
        <cfargument name="id" />
        <cfargument name="idList" />
        <cfset var transferTQL = "" />
        <cfset var transferQuery = "" />
        <cfset var qResultQuery = "" />

        <!--- Define TQL --->
        <cfsavecontent variable="transferTQL">
            <cfoutput>
                SELECT myObject.myField
                FROM myObject
                WHERE myObject.ID = :tql_ID
                    OR myObject.ID IN (:tql_ID_list)
            </cfoutput>
        </cfsavecontent>

        <cfscript>
            transferQuery = transfer.createQuery(transferTQL);
            transferQuery.setParam(
                name = "tql_ID",
                value = arguments.id,
                type = "numeric");
            transferQuery.setParam(
                name = "tql_ID_list",
                value = arguments.idList,
                type = "numeric",
                list = True);
            qResultQuery = transfer.listByQuery(transferQuery);
            return qResultQuery;
        </cfscript>
    </cffunction>

</cfcomponent>