SISTEMA: Trocar de armas no passageiro ~Nyft

#include a_samp
#include pawn.cmd

main(){}

public OnPlayerStateChange(playerid, newstate, oldstate)
{
    if(newstate == PLAYER_STATE_PASSENGER)
        SetPVarInt(playerid, "curWeaponID", GetPlayerWeapon(playerid));

    return 1;
}

public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
    if(GetPlayerState(playerid) == PLAYER_STATE_PASSENGER && IsBulletWeapon(GetPVarInt(playerid, "curWeaponID")))
    {
        if(newkeys & KEY_LOOK_RIGHT)
        {
            new curWeap = GetPVarInt(playerid, "curWeaponID"), weapSlot = GetWeaponSlot(curWeap), weapID, weapAmmo;

            for(new i = weapSlot + 1; i <= 7; i++)
            {
                GetPlayerWeaponData(playerid, i, weapID, weapAmmo);
                if(IsBulletWeapon(weapID) && weapID != curWeap)
                {
                    GameTextForPlayer(playerid, "~y~~h~Arma Seguinte ~>~", 1000, 3);
                    SetPVarInt(playerid, "curWeaponID", weapID);
                    SetPlayerArmedWeapon(playerid, weapID);
                    break;
                }
            }
        }
        if(newkeys & KEY_LOOK_LEFT)
        {
            new curWeap = GetPVarInt(playerid, "curWeaponID"), weapSlot = GetWeaponSlot(curWeap), weapID, weapAmmo;

            for(new i = weapSlot - 1; i >= 2; i--)
            {
                GetPlayerWeaponData(playerid, i, weapID, weapAmmo);
                if(IsBulletWeapon(weapID) && weapID != curWeap)
                {
                    GameTextForPlayer(playerid, "~y~~h~~<~ Arma Anterior", 1000, 3);
                    SetPVarInt(playerid, "curWeaponID", weapID);
                    SetPlayerArmedWeapon(playerid, weapID);
                    break;
                }
            }
        }
    }
    return 1;
}

// -----------------------------------------------------------------------------

IsBulletWeapon(weaponid)
    return (WEAPON_COLT45 <= weaponid <= WEAPON_SNIPER) || weaponid == WEAPON_MINIGUN;

GetWeaponSlot(weaponid)
{
    switch(weaponid)
    {
        case 0, 1:       return 0;
        case 2..9:       return 1;
        case 22..24:     return 2;
        case 25..27:     return 3;
        case 28, 29, 32: return 4;
        case 30, 31:     return 5;
        case 33, 34:     return 6;
        case 35..38:     return 7;
        case 16..18, 39: return 8;
        case 41..43:     return 9;
        case 10..15:     return 10;
        case 44..46:     return 11;
        case 40:         return 12;
    }
    return -1;
}

// -----------------------------------------------------------------------------

CMD:nrg(playerid)
{
    new vehicleid, Float:x, Float:y, Float:z, Float:a;
    GetPlayerPos(playerid, x, y, z);
    GetPlayerFacingAngle(playerid, a);

    vehicleid = CreateVehicle(522, x, y, z, a, -1, -1, -1);
    PutPlayerInVehicle(playerid, vehicleid, 1);
    return 1;
}
CMD:sul(playerid)
{
    new vehicleid, Float:x, Float:y, Float:z, Float:a;
    GetPlayerPos(playerid, x, y, z);
    GetPlayerFacingAngle(playerid, a);

    vehicleid = CreateVehicle(560, x, y, z, a, -1, -1, -1);
    PutPlayerInVehicle(playerid, vehicleid, 1);
    return 1;
}
CMD:armas(playerid)
{
    GivePlayerWeapon(playerid, 38, 9999);
    GivePlayerWeapon(playerid, 24, 9999);
    GivePlayerWeapon(playerid, 26, 9999);
    GivePlayerWeapon(playerid, 31, 9999);
    GivePlayerWeapon(playerid, 34, 9999);
    return 1;
}