/*
 * Exercice 2.2 Examens physiques
 */

/*
 * Recupere les lignes ou la taille n'est pas vide et garde uniquement le usubjid et la taille
 */
Data donnees.peRes;
    set donnees.physical_exam;
    where hgt is not null;
    keep usubjid hgt;
run;

/*
 * Recupere les lignes ou le poids n'est pas vide et garde uniquement le usubjid et le poids
 */
Data donnees.peRes2;
    set donnees.physical_exam;
    where wgt is not null;
    keep usubjid wgt;
run;

/*
 * Recupere toutes les lignes mais ne conserve que le usubjid, la date de visite et l'id de cette derniere
 */
Data donnees.date;
    set donnees.date_of_visit;
    keep usubjid visid visdt;
run;

/*
 * Proc sort necessaire pour la merge des trois tables
 */
proc sort data=donnees.peRes2;
    by usubjid;
run;

proc sort data=donnees.peRes;
    by usubjid;
run;

proc sort data=donnees.date;
    by usubjid;
run;


/*
 * Fusionne les trois tables crées précedemment
 */
Data donnees.mPeRes;
    Merge donnees.peRes
          donnees.peRes2
          donnees.date;
    by usubjid;
run;

/*
 * Tri la table créée précédemment par usubjid et date de visite
 */
Proc sort data= donnees.mPeRes;
by usubjid descending visdt;
run;

/*
 * Supprime tous les doublons ne gardant que la premiere occurence de chaque patient qui correspoind a la derniere visite
 */
proc sort data=donnees.mPeRes nodupkey;
   by usubjid;
run;

/*
 *Calcul l'IMC et la save dans la nouvelle colonne IMC dans la nouvelle table resIMC
 */
Data donnees.resIMC;
    set donnees.mPeRes;
    ATTRIB IMC
            LABEL="Indice de masse corporelle"
            LENGTH=5;
    IMC=FLOOR(wgt/((hgt/100)*(hgt/100)));
RUN;

Proc sort data=donnees.fusion_dm_treatment;
    by usubjid;
run;

/*
 *Fusion des tables dm et resIMC
 */
Data donnees.peTemp;
    merge donnees.fusion_dm_treatment
          donnees.resimc;
    by usubjid;
run;

data donnees.pe;
    set donnees.peTemp;
    keep trtcd imc sex age hgt wgt;
    where imc is not null;
Run;

proc sort data=donnees.pe;
    by trtcd;
run;

/*
 * Calcul le coefficient de correlation de la variable IMC en les triants par numero de
 * traitement
 */
TITLE "IMC moyen par groupe";
proc corr data = donnees.PE plots;
    var imc;
    by trtcd;
run;

/*
 * Affiche le graphique des moyennes d'IMC par groupe
 */
proc sgplot data= donnees.PE;
  VBAR TRTCD/ STAT=MEAN RESPONSE=IMC;
run;

/*
 *class:variable de tri
 */
/*Hypothese : Les resultats d'IMC dépendent du groupe de traitement.

Conclusion : dans 55% des cas les valeurs sont hors de la moyenne ont peu donc en conclure que
l'hypothese est fausse et que l'IMC ne dépend pas du groupe de traitemment*/

proc anova data=donnees.PE;
    class TRTCD;
    model IMC=TRTCD;
run;

/*
 *Proc sort necessaire pour le proc means qui suit
 */
proc sort data=donnees.PE;
    by trtcd sex;
run;

/*
 *Proc means affichant le min, max, la moyenne et l'ecart type de l'age, du poids, de la taille et de
 *l'IMC en fonction du sexe pour chaque groupe
 */
Title "On remarque grâce a ces resultats qu'en moyenne, quelque soit le groupe, le poids et la taille sont des hommes est superieur a celle des femmes.
        Pour ce qui est des autres variables on voit que la moyenne des hommes et des femmes est toujours plus ou la meme";
proc means data=donnees.PE maxdec=2;
     var age wgt hgt imc;
     class trtcd sex;
     OUTPUT out=donnees.stat_PE max=max min=min mean=moyenne std=ecart_type;
run;