import crafttweaker.item.IItemStack;
import crafttweaker.liquid.ILiquidStack;
import crafttweaker.item.IIngredient;
import crafttweaker.oredict.IOreDict;
import crafttweaker.oredict.IOreDictEntry;
import mods.artisanworktables.builder.RecipeBuilder;


	#Slabs
var slabsChanged as IItemStack[IItemStack] = {
	<minecraft:wooden_slab:2> : <minecraft:planks:2>,
	<minecraft:wooden_slab:3> : <minecraft:planks:3>,
	<minecraft:wooden_slab:4> : <minecraft:planks:4>,
	<minecraft:wooden_slab:5> : <minecraft:planks:5>,
	<minecraft:stone_slab:1> : <minecraft:sandstone>,
	<minecraft:stone_slab:3> : <minecraft:cobblestone>,
	<minecraft:stone_slab:4> : <minecraft:brick_block>,
	<minecraft:stone_slab:5> : <minecraft:stonebrick>,
	<minecraft:stone_slab:6> : <minecraft:nether_brick>,
	<minecraft:stone_slab:7> : <minecraft:quartz_block>,
	<minecraft:wooden_slab> : <minecraft:planks>,
	<minecraft:wooden_slab:1> : <minecraft:planks:1>
};

for slab, block in slabsChanged {
	recipes.remove(slab);

	recipes.addShaped(block, [
		[slab],
		[slab]]);

	RecipeBuilder.get("basic")
		.setShapeless([block])
		.addTool(<ore:artisansHandsaw>, 5)
		.addOutput(slab*2)
		.create();
}

RecipeBuilder.get("basic")
	.setShaped([
		[<ore:plankWood>, <ore:plankWood>, <ore:plankWood>],
		[<minecraft:book>, <minecraft:book>, <minecraft:book>],
		[<ore:plankWood>, <ore:plankWood>, <ore:plankWood>]])
	.addTool(<ore:artisansHandsaw>, 10)
	.addOutput(<minecraft:bookshelf>)
	.create();