Open-Ryzen-Master-Maximized+Create-Profile.bat

:: CREATED BY SlyFox1186
:: https://pastebin.com/u/slyfox1186
:: https://stackoverflow.com/users/10572786/slyfox11867

:: THIS SCRIPT WILL LAUNCH AMD RYZEN MASTER MAXIMIZED >>
:: >> AND CREATE A RYZEN PROFILE+TEMPORARY AHK SCRIPT
:: [YOU MUST] HAVE AUTOHOTKEY.EXE INSTALLED
:: MAKE SURE AUTOHOTKEY.EXE IS SET TO RUNS AS AN ADMINISTRATOR
:: RIGHT CLICK AUTOHOTKEY.EXE, COMPATIBILITY TAB, CHECK "RUN AS AN ADMINISTRATOR"
:: MODIFY OR REMOVE SECTIONS IF/AS NECESSARY

:: BEGIN SCRIPT

@ECHO OFF
:: RUN THE SCRIPT AS AN ADMINISTRATOR IF NOT ALREADY DOING SO
IF NOT "%1"=="am_admin" (POWERSHELL -WindowStyle Hidden -Command START -verb RunAs '%0' am_admin & EXIT /B)
SETLOCAL
COLOR 0A
TITLE OPEN RYZEN MASTER MAXIMIZED

PUSHD "%~dp0"

:: CREATE AND OPEN RYZEN MASTER PROFILE
:: UNCOMMENT THE NEXT SECTION [TO ENABLE]
:: YOU CAN EXPORT YOUR OWN CUSTOM PROFILE AND REPLACE >>
:: >> THE INFORMATION BELOW WITH IT'S CONTENTS
:-------------------------------------
:: (
:: ECHO NOTE: This file is AMD Profile File. Modifying content of this file may lead to failure in Importing the profile.
:: ECHO Profile Info:
:: ECHO 3c566:41635g575:5d562b22/b3421232b262b242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621211d242621212c3421222b272b221d221d221d221d221d221d221d221d221d221d221d221d221d221d221d222c4721222b242b221f2423262c4721232b242b221f24262c4721242b242b211f2728262c4721252b242b221f222c3421242b222b222c3421262b222b212c3421272b232b212c3421292b232b232c3422232b232b2229212c3422242b232b2229212c3422252b232b2325212c3e21222b232b222721212c3e21232b232b22252c3e21242b232b22252c3e21252b232b24252c3e21262b232b22252c3e21272b232b22252c3e21282b232b25292c3e21292b232b23252c3e212:2b232b22252c
:: ECHO 38611
:: )> ryzen.rpmf
:: START "" NOTEPAD "ryzen.rpmf"
:-------------------------------------

:: CREATE THE TEMPORARY AHK SCRIPT
:: IF YOU HAVE ISSUES WITH THE SCRIPT SUCCESSFULLY >>
:: >> CLOSING THE POP UP WINDOW WHEN RYZEN MASTER LAUNCHES >>
:: >> INCREASE THE SLEEP TIME VALUE BY EDITING THE [pauseAHK] VARIABLE BELOW
:: YOU SHOULD INCREASE THE SLEEP TIME IN INCREMENTS OF 100 UNTIL WORKING [1000 = 1 SECOND]

SET pauseAHK=1200
(
ECHO #NoEnv
ECHO #SingleInstance, Force
ECHO #MaxThreadsPerHotkey 2
ECHO #MaxHotkeysPerInterval, 99000000
ECHO #HotkeyInterval, 99000000
ECHO #WinActivateForce
ECHO #KeyHistory 0
ECHO ListLines Off
ECHO SetBatchLines, -1
ECHO SetControlDelay, -1
ECHO SetDefaultMouseSpeed, 0
ECHO SetKeyDelay, -1, -1
ECHO SetMouseDelay, -1
ECHO SetWinDelay, -1
ECHO DetectHiddenWindows, On
ECHO DetectHiddenText, On
ECHO DllCall^("Sleep,",UInt,16.67^)
ECHO.
ECHO winTitle := "ahk_class Qt5QWindowOwnDCIcon"
ECHO.
ECHO WinWaitActive, %% winTitle
ECHO Send, {Enter}
ECHO Sleep, %pauseAHK%
ECHO WinMaximize, %% winTitle
ECHO Return
)> "%TEMP%\RyzenMax.ahk"

:: START RYZEN MASTER
START "" "%ProgramFiles%\AMD\RyzenMaster\bin\AMD Ryzen Master.exe"

:: START AND THEN DELETE THE TEMPORARY AHK SCRIPT
START "" /WAIT /HIGH "%TEMP%\RyzenMax.ahk"
DEL /Q "%TEMP%\RyzenMax.ahk"

EXIT