Russian Elimination Roulette WIP1

_rr_reset = [
    _rr_players  = []
    _rr_deceased = []
    _rr_chamber = 0
    _rr_sel     = 0
    _rr_game    = 1
    _rr_last    = -1
]

_rr_reset

newgui roulette [
    guistayopen [
        guilist [
            guilist [
                guiimage "data/cube.png" [_rr_reset] 3 0
                guistrut 2
                case $_rr_game 0 [
                    guibutton "Roulette" [
                        if (= (rnd 6 $_rr_chamber) 5) [
                            _rr_deceased = (concat $_rr_deceased $_rr_sel)
                            _rr_chamber = 0
                            say "^f3BANG!^f2" (getclientname $_rr_sel) "^f7experienced a sudden brain surgery and had to take a nap!"
                            if (!= (listlen $_rr_deceased) (- (listlen $_rr_players) 1)) [
                                say "^f7A ^f2new round ^f7begins!^f2" (getname) "^f7reloads the gun and spins the chamber.^n"
                            ]
                        ] [
                            _rr_chamber = (+ 1 $_rr_chamber)
                            say "^f0CLICK!^f2" (getclientname $_rr_sel) "^f7survived. Who's next?^n"
                        ]
                        _rr_last = $_rr_sel
                        _rr_sel = (listdel (listdel $_rr_players $_rr_last) $_rr_deceased)
                        _rr_sel = (at $_rr_sel (rnd (listlen $_rr_sel)))
                        if (= (listlen $_rr_deceased) (- (listlen $_rr_players) 1)) [
                            say (format "^f3Game Over! ^f7The winner is ^f2%1^f7!^n" (getclientname $_rr_sel))
                            _rr_game = 2
                        ]
                    ]
                ] 1 [
                    guibutton "Start Game" [
                        if (> (listlen $_rr_players) 1) [
                            _rr_game = 0
                            say "^f7Let's play some ^f2Russian Roulette^f7!"
                        ] [ echo "^f7More players are required for this game!" ]
                    ]
                ] 2 [ guibutton "New Game" _rr_reset ]
            ]
            guistrut 2
            guilist [
                if (= $_rr_game 1) [
                    looplist i (listclients 1) [
                        n = (getclientname $i)
                        guibutton (concatword (? (> (indexof $_rr_players $i) -1) "^f6") $n) [
                            if (< (indexof $_rr_players @i) 0) [
                                _rr_players = (concat $_rr_players @@i)
                            ] [
                                _rr_players = (listdel $_rr_players @@i)
                            ]
                        ] (? (> (indexof $_rr_players $i) -1) "radio_on" "radio_off")
                    ]
                ] [
                    looplist i $_rr_players [
                        n = (getclientname $i)
                        guibutton (concatword (? (< (indexof $_rr_deceased $i) 0) (? (= $i $_rr_last) "^f4" "") "^f3") $n) [
                            cond (> (indexof $_rr_deceased @i) -1) [
                                echo (format "^f2%1 ^f7is already dead, he cannot play again until the game has ended!" @@n)
                            ] (= @i $_rr_last) [
                                echo (format "^f2%1 ^f7already played before, you must choose another person!" @@n)
                            ] [_rr_sel = @@i]
                        ] (? (|| [> (indexof $_rr_deceased $i) -1] [= $i $_rr_last]) "radio_off" (? (= $_rr_sel $i) "radio_on" "radio_off"))
                    ]
                ]
            ]
        ]
    ]
]