SHARE
TWEET

QTGMC for avs 2.60

a guest Jul 19th, 2019 363 Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.363, by Vit, 2012, 2018 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that may comes with this script, or even better see avisynth wiki
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.363s
  16. # - some changes in LUT things
  17. #
  18. # v3.362s
  19. # - some changes for avs+ and avs neo, need IsAvsNeo(), IsAvsPlus() and AvsPlusVersionNumber(), they are in SMDegrain v3.1.2.101s or up
  20. #
  21. # v3.361s
  22. # - update to masktools 2.2.17, use expr in avs+ (for speed up and less RAM usage)
  23. #
  24. # v3.358s
  25. # - new n16 bool (avs+ faster replacement for lsb), and tr2=6
  26. #
  27. # v3.357s
  28. # - high bit depth now basically work in avs+
  29. #
  30. # v3.354s
  31. # - added optional chikuzen PlanarTools for YUY2 using nonyuy2clipin/nonyuy2clipout in AnimeIVTC() v2.20
  32. #
  33. # v3.353s
  34. # - added ndjamena suggestion for maximum temporal radius
  35. # - added DftDither to controle dfttest dither Parameter
  36. #
  37. # v3.352s
  38. # - added useEdiExt
  39. # - added tr0=-1 to use the EdiExt clip (if there is no EdiExt clip then it will not work)
  40. # - rep0 now will be 0 if tr0 < 1
  41. #
  42. # v3.347s
  43. # - fix SourceMatch (bug after new YUY2 method, thanks to ndjamena for report it)
  44. #
  45. # v3.346s
  46. # - EEDI3+NNEDI3 bug fix by ndjamena
  47. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  48. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  49. #
  50. # v3.345s
  51. # - work with SMDegrain_KNLMeansCL now to process chroma too
  52. #
  53. # v3.343s
  54. # - edit in ChromaEdi
  55. # - others
  56. #
  57. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  58. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  59. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  60. #
  61. # v3.33s (mod) 2016 12 06
  62. # - Add TR2=4 and TR2=5
  63. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  64. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  65. #
  66. # v3.33s (mod) 2016 04 11
  67. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  68. # - others
  69. #
  70. # v3.33s (mod) 2016 01 19
  71. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  72. #
  73. # v3.33s (mod) 2015 10 23
  74. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  75. #
  76. # v3.33s (mod) 2015 9 10
  77. # - fix Multiple QTGMC Calls
  78. # - others fix
  79. #
  80. # v3.33s (mod) 2015 8 6
  81. # - some changes in bob to speed up
  82. #
  83. # v3.33s (mod) 2015 8 4
  84. # - fix bug in YUY2 with SourceMatch
  85. # - add slice=false to ditherpost to avoid artefacts
  86. #
  87. # v3.33s (mod)
  88. # - fix bob chroma
  89. # - work with new masktool2 for avs 2.60 in YUY2
  90. #
  91. # v3.33d (mod)
  92. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  93. # - optimized some mask handling a bit as originally suggested by Vit
  94. # - others
  95. #
  96. # v3.33
  97. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  98. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  99. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  100. # - Minor change to denoising
  101. #
  102. # v3.32
  103. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  104. # - Tweaked vector recalculation for shutter motion blur
  105. # - Changed defaults for TR2 when using source-match
  106. # - Minor bugfix with SLMode/SLRad on pass-through settings
  107. #
  108. # --- REQUIREMENTS ---
  109. #
  110. # Input colorspaces: YV12, YUY2, others as plugins supports
  111. #
  112. # Core plugins:
  113. #   MVTools2 (2.7.26 or above)
  114. #   MaskTools2 (v2.2.17 or above)
  115. #   NNEDI3 (0.9.4.6 or above)
  116. #   RgTools
  117. #
  118. # Core scripts:
  119. #   SMDegrain (3.1.2.100s or above) unless you set tv_range=false
  120. #   AnimeIVTC (2.20 or above) if you work with YUY2 source
  121. #
  122. # Additional plugins:
  123. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  124. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  125. #   FFT3DFilter - if selected for noise processing
  126. #   dfttest (1.9.4 or above) - if selected for noise processing
  127. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  128. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  129. #   KNLMeansCL - if selected for noise processing
  130. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  131. #   chikuzen PlanarTools - if you work with YUY2 source (not necessarily required but may improve speed)
  132.  
  133.  
  134. # --- GETTING STARTED ---
  135. #
  136. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  137. # To use QTGMC write a script like this:
  138. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  139. #   QTGMC( Preset="Slow" )
  140. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  141. #
  142. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  143. #
  144. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  145. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  146. # The default preset is "Slower"
  147. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  148. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  149. #
  150. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  151. #   QTGMC( Preset="Slow", ShowSettings=true )
  152.  
  153.  
  154. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  155.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  156.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  157.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  158.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  159.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  160.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  161.                     int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  162.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  163.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  164.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  165.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "useEdiExt", int "DftDither", bool "lsbd", bool "lsb", bool "n16" )
  166. {
  167.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  168.  
  169.     # Temporary Warnings
  170.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  171.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  172.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  173.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  174.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  175.  
  176.     #---------------------------------------
  177.     # Presets
  178.     lsbd         = default( lsbd,      false)
  179.     lsb          = default( lsb,       false)
  180.     n16          = default( n16,       false)
  181.     useEdiExt    = default( useEdiExt, false)
  182.     Str          = default( Str,        1.0 )
  183.     Amp          = default( Amp,     0.0625 )
  184.     TV_range     = default( TV_range,   !(Isrgb(input)))
  185.  
  186.         sisphbd = AvsPlusVersionNumber > 2294
  187.     sisphbd  ? Assert( !(Input.BitsPerComponent() > 8 && (lsb || lsbd)), "QTGMC: lsb hack is not Compatible with native high bit depth" ) : nop()
  188.  
  189.     # Select presets / tuning
  190.     Preset = default( Preset, "Slower" )
  191.     pNum = (Preset == "Placebo"   ) ? 0 : \
  192.            (Preset == "Very Slow" ) ? 1 : \
  193.            (Preset == "Slower"    ) ? 2 : \
  194.            (Preset == "Slow"      ) ? 3 : \
  195.            (Preset == "Medium"    ) ? 4 : \
  196.            (Preset == "Fast"      ) ? 5 : \
  197.            (Preset == "Faster"    ) ? 6 : \
  198.            (Preset == "Very Fast" ) ? 7 : \
  199.            (Preset == "Super Fast") ? 8 : \
  200.            (Preset == "Ultra Fast") ? 9 : \
  201.            (Preset == "Draft"     ) ? 10 : 11
  202.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  203.  
  204.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  205.              (MatchPreset == "Placebo"   ) ? 0 : \
  206.              (MatchPreset == "Very Slow" ) ? 1 : \
  207.              (MatchPreset == "Slower"    ) ? 2 : \
  208.              (MatchPreset == "Slow"      ) ? 3 : \
  209.              (MatchPreset == "Medium"    ) ? 4 : \
  210.              (MatchPreset == "Fast"      ) ? 5 : \
  211.              (MatchPreset == "Faster"    ) ? 6 : \
  212.              (MatchPreset == "Very Fast" ) ? 7 : \
  213.              (MatchPreset == "Super Fast") ? 8 : \
  214.              (MatchPreset == "Ultra Fast") ? 9 : \
  215.              (MatchPreset == "Draft"     ) ? 10 : 11
  216.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  217.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  218.  
  219.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  220.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  221.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  222.              (MatchPreset2 == "Slower"    ) ? 2 : \
  223.              (MatchPreset2 == "Slow"      ) ? 3 : \
  224.              (MatchPreset2 == "Medium"    ) ? 4 : \
  225.              (MatchPreset2 == "Fast"      ) ? 5 : \
  226.              (MatchPreset2 == "Faster"    ) ? 6 : \
  227.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  228.              (MatchPreset2 == "Super Fast") ? 8 : \
  229.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  230.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  231.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  232.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  233.  
  234.     NoisePreset = default( NoisePreset, "Fast" )
  235.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  236.             (NoisePreset == "Slow"   ) ? 1 : \
  237.             (NoisePreset == "Medium" ) ? 2 : \
  238.             (NoisePreset == "Fast"   ) ? 3 : \
  239.             (NoisePreset == "Faster" ) ? 4 : 5
  240.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  241.  
  242.     Tuning = default( Tuning, "None" )
  243.     tNum = (Tuning == "None"  ) ? 0 : \
  244.            (Tuning == "DV-SD" ) ? 1 : \
  245.            (Tuning == "DV-HD" ) ? 2 : 3
  246.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  247.  
  248.     # Tunings only affect blocksize in this version
  249.     bs = Select( tNum,  16, 16, 32 )
  250.     bs2 = (bs >= 16) ? 32 : bs * 2
  251.  
  252.     #                                                               Very                                                        Very      Super      Ultra
  253.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  254.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  255.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  256.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  257.     Rep0         = defined(Rep0) ? Rep0 : TR0 < 1 ? 0 : undefined()
  258.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  259.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  260.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  261.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  262.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  263.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  264.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  265.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  266.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  267.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  268.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  269.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  270.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  271.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  272.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  273.     bs = Blocksize
  274.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  275.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  276.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  277.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  278.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  279.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  280.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  281.  
  282.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  283.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  284.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  285.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  286.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  287.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  288.  
  289.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  290.     SourceMatch   = default( SourceMatch, 0 )
  291.     MatchNNSize   = NNSize
  292.     MatchNNeurons = NNeurons
  293.     MatchEdiMaxD  = EdiMaxD
  294.     MatchEdiQual  = EdiQual
  295.  
  296.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  297.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  298.     #                                                                    Very                                                        Very      Super     Ultra
  299.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  300.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  301.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  302.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  303.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  304.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  305.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  306.     MatchEdi = TempEdi
  307.  
  308.     #                                                          Very                                                        Very      Super     Ultra
  309.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  310.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  311.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  312.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  313.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  314.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  315.  
  316.  
  317.     #---------------------------------------
  318.     # Settings
  319.  
  320.     # Core and Interpolation defaults
  321.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  322.     RepChroma  = default( RepChroma,  true )
  323.     EdiThreads = default( EdiThreads, 0    )
  324.     ChromaEdi  = default( ChromaEdi,  ""   )
  325.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  326.     EdiQual    = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  327.  
  328.     # Source-match / lossless defaults
  329.     MatchTR1     = TR1
  330.     MatchTR2     = default( MatchTR2,     1   )
  331.     MatchEnhance = default( MatchEnhance, 0.5 )
  332.     Lossless     = default( Lossless,     0   )
  333.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  334.  
  335.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  336.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  337.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  338.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  339.     spatialSL  = (SLMode == 1 || SLMode == 3)
  340.     temporalSL = (SLMode == 2 || SLMode == 4)
  341.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  342.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  343.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  344.     Sbb        = (SMode == 0) ? 0 : Sbb
  345.     SOvs       = default( SOvs,   0   )
  346.     SVThin     = default( SVThin, 0.0 )
  347.  
  348.     # Noise processing settings
  349.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  350.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  351.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  352.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  353.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  354.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  355.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  356.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  357.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  358.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  359.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  360.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  361.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  362.     Sigma        = defined(Sigma)       ? Sigma : \
  363.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  364.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  365.     FftThreads   = default( FftThreads, EdiThreads )
  366.     ChromaNoise  = default( ChromaNoise, false )
  367.     ShowNoise    = default( ShowNoise, 0.0 )
  368.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  369.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  370.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  371.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  372.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  373.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  374.     totalRestore = GrainRestore + NoiseRestore
  375.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  376.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  377.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  378.  
  379.     # MVTools settings
  380.     SubPelInterp = default( SubPelInterp, 2     )
  381.     TrueMotion   = default( TrueMotion,   false )
  382.     GlobalMotion = default( GlobalMotion, true  )
  383.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  384.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  385.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  386.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  387.     DCT          = default( DCT,     0          )
  388.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  389.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  390.     ThSCD1       = default( ThSCD1,  180        )
  391.     ThSCD2       = default( ThSCD2,  98         )
  392.  
  393.     # Motion blur settings
  394.     FPSDivisor  = default( FPSDivisor, 1 )
  395.     ShutterBlur = default( ShutterBlur, 0 )
  396.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  397.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  398.     SBlurLimit  = default( SBlurLimit, 4 )
  399.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  400.  
  401.     # Miscellaneous
  402.     InputType      = default( InputType,     0        )
  403.     Border         = default( Border,        false    )
  404.     ShowSettings   = default( ShowSettings,  false    )
  405.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  406.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  407.     ForceTR        = default( ForceTR,       0        )
  408.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  409.     ReuseGlobals   = (PrevGlobals == "Reuse")
  410.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  411.     rgBlur         = (Precise) ? 11 : 12
  412.  
  413.     # Get maximum temporal radius needed
  414.     maxTR = (temporalSL)       ? SLRad : 0
  415.     maxTR = max(MatchTR2, TR1, TR2, NoiseTR, maxTR)
  416.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  417.     maxTR = max(ForceTR, MaxTR)
  418.  
  419.  
  420.     #---------------------------------------
  421.     # Pre-Processing
  422.  
  423.     w = Input.Width()
  424.     h = Input.Height()
  425.     yuy2 = Input.IsYUY2()
  426.     epsilon = 0.0001
  427.  
  428.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  429.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  430.  
  431.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  432.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  433.     h = (Border) ? h+8 : h
  434.  
  435.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  436.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  437.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  438.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  439.     vpad = (vpad > 8) ? vpad : 8
  440.  
  441.  
  442.     #---------------------------------------
  443.     # Motion Analysis
  444.  
  445.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  446.     planarClip = yuy2 ? clip.nonyuy2clipin(true) : clip
  447.  
  448.     # Bob the input as a starting point for motion search clip
  449.     bobbed = (InputType == 0) ? useEdiExt ? isyuy2(EdiExt) ? EdiExt.nonyuy2clipin(true) : EdiExt : planarClip.QTGMC_Bob( 0,0.5 ) : \
  450.              (InputType == 1) ? planarClip : \
  451.                                 planarClip.Blur( 0,1 )
  452.  
  453.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  454.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  455.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  456.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  457.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  458.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  459.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  460.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  461.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  462.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  463.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  464.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  465.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  466.     bVec6     = QTGMC_GetUserGlobal( GlobalNames, "bVec6",     ReuseGlobals )
  467.     fVec6     = QTGMC_GetUserGlobal( GlobalNames, "fVec6",     ReuseGlobals )
  468.  
  469.     CMmt = ChromaMotion ? 3   :  1
  470.     CMts = ChromaMotion ? 255 :  0
  471.     CMrg = ChromaMotion ? 12  : -1
  472.  
  473.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  474.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  475.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  476.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  477.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  478.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  479.  
  480.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  481.     binomial0 = IsClip(srchClip) ? NOP() : \
  482.     TR0 == -1 && defined(EdiExt) ? isyuy2(EdiExt) ? EdiExt.nonyuy2clipin(true) : EdiExt : \
  483.                 (TR0 == 0)       ? bobbed : \
  484.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  485.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  486.  
  487.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  488.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  489.  
  490.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  491.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  492.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  493.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  494.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  495.  
  496.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  497.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 scalef + y < x 3 scalef + x 3 scalef - y > x 3 scalef - y ? ?", use_expr=2, U=CMmt,V=CMmt ) : NOP()
  498.     srchcheck   = IsClip(srchClip)
  499.     srchClip    = srchcheck         ? srchClip : \
  500.                   (SrchClipPP == 0) ? repair0 : \
  501.                   (SrchClipPP < 3)  ? spatialBlur : \
  502.                                       spatialBlur.mt_lutxy( tweaked, "x 7 scalef + y < x 2 scalef + x 7 scalef - y > x 2 scalef - x 51 * y 49 * + 100 / ? ?", use_expr=2, U=CMmt,V=CMmt )
  503.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  504.     # Calculate forward and backward motion vectors from motion search clip
  505.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  506.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  507.     bVec6 = IsClip(bVec6) ? bVec6 : \
  508.             (maxTR > 5)   ? srchSuper.MAnalyse( isb=true,  delta=6, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  509.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  510.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  511.     bVec5 = IsClip(bVec5) ? bVec5 : \
  512.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  513.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  514.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  515.     bVec4 = IsClip(bVec4) ? bVec4 : \
  516.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  517.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  518.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  519.     bVec3 = IsClip(bVec3) ? bVec3 : \
  520.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  521.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  522.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  523.     bVec2 = IsClip(bVec2) ? bVec2 : \
  524.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  525.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  526.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  527.     bVec1 = IsClip(bVec1) ? bVec1 : \
  528.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  529.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  530.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  531.     fVec1 = IsClip(fVec1) ? fVec1 : \
  532.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  533.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  534.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  535.     fVec2 = IsClip(fVec2) ? fVec2 : \
  536.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  537.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  538.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  539.     fVec3 = IsClip(fVec3) ? fVec3 : \
  540.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  541.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  542.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  543.     fVec4 = IsClip(fVec4) ? fVec4 : \
  544.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  545.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  546.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  547.     fVec5 = IsClip(fVec5) ? fVec5 : \
  548.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  549.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  550.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  551.     fVec6 = IsClip(fVec6) ? fVec6 : \
  552.             (maxTR > 5)   ? srchSuper.MAnalyse( isb=false, delta=6, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  553.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  554.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  555.  
  556.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  557.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  558.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  559.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  560.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  561.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  562.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  563.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  564.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  565.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  566.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  567.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  568.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  569.     QTGMC_SetUserGlobal( GlobalNames, "bVec6",     bVec6,     ReplaceGlobals )
  570.     QTGMC_SetUserGlobal( GlobalNames, "fVec6",     fVec6,     ReplaceGlobals )
  571.  
  572.  
  573.     #---------------------------------------
  574.     # Noise Processing
  575.  
  576.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  577.  
  578.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  579.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  580.                 (InputType > 0)     ? clip : \
  581.                                       clip.QTGMC_Bob( 0,1.0 )
  582.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.nonyuy2clipin(true) : fullClip
  583.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  584.  
  585.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  586.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  587.                   (!DenoiseMC)        ? fullClip : \
  588.                   (NoiseTR == 0)      ? fullClip : \
  589.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  590.                                                     fullClip, \
  591.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  592.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  593.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  594.                                                     fullClip, \
  595.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  596.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  597.     noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.nonyuy2clipout(true) : noiseWindow
  598.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  599.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, Dither=DftDither, lsb=lsbd ) : \
  600.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  601.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  602.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  603.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.nonyuy2clipout(true) : dnWindow
  604.  
  605.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  606.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  607.     denoised = (NoiseProcess == 0) ? NOP() : \
  608.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  609.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  610.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  611.  
  612.     # >>>> Switch to planar YUY2 for noise bypass
  613.  
  614.     CNmt1   = ChromaNoise ? 3 : 1
  615.     CNmt2   = ChromaNoise ? 3 : 2
  616.     CNmt128 = ChromaNoise ? 3 : -128
  617.  
  618.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  619.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.nonyuy2clipin(true) : denoised
  620.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  621.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  622.                  (InputType != 0)                           ? noise : \
  623.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  624.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  625.                                                               noise.DoubleWeave()
  626.     # Motion-compensated stabilization of generated noise
  627.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  628.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  629.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x range_half - abs y range_half - abs > x y ? 0.6 * x y + 0.2 * +", use_expr=2, U=CNmt1,V=CNmt1 ) : deintNoise
  630.  
  631.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  632.     innerClip = (NoiseProcess == 1) ? denoised : clip
  633.  
  634.  
  635.     #---------------------------------------
  636.     # Interpolation
  637.  
  638.     # >>>> Interleaved YUY2 for interpolation
  639.  
  640.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  641.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  642.  
  643.     # Create interpolated image as starting point for output
  644.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  645.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  646.  
  647.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  648.  
  649.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  650.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  651.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.nonyuy2clipin(true)) :\
  652.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).nonyuy2clipin(true)) : \
  653.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  654.                                                         mt_merge( innerClip.nonyuy2clipin(true), edi1.nonyuy2clipin(true), inputTypeBlend, U=2,V=2 ))
  655.  
  656.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  657.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  658.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  659.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  660.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  661.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  662.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  663.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  664.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  665.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  666.  
  667.  
  668.     #---------------------------------------
  669.     # Create basic output
  670.  
  671.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  672.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  673.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  674.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  675.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  676.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  677.     degrain1 = (TR1 > 0) ? lsb ? degrain1.ditherpost(mode=6, slice=false) : n16 ? degrain1.ConvertTo8bit(dither=1) : degrain1 : degrain1
  678.     degrain2 = (TR1 > 1) ? lsb ? degrain2.ditherpost(mode=6, slice=false) : n16 ? degrain2.ConvertTo8bit(dither=1) : degrain2 : degrain2
  679.  
  680.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  681.     binomial1 = (TR1 == 0) ? edi : \
  682.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  683.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  684.  
  685.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  686.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  687.  
  688.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  689.     match = (SourceMatch == 0) ? repair1 : \
  690.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  691.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  692.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  693.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb, n16 )
  694.  
  695.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  696.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  697.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  698.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  699.  
  700.  
  701.     #---------------------------------------
  702.     # Resharpen / retouch output
  703.  
  704.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  705.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  706.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 scalef + x y > x 1 scalef - x ? ?", use_expr=2, U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  707.     resharp   = (SMode == 0) ? lossed1 : \
  708.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", clamp_float=true, use_expr=1, U=3,V=3 ) : \
  709.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", clamp_float=true, use_expr=1, U=3,V=3 )
  710.  
  711.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  712.     SVThinSc = SVThin * 6.0
  713.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * range_half +", clamp_float=true, use_expr=3, U=1,V=1 ) : NOP()
  714.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  715.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y range_half - abs x range_half - abs > y range_half ?", use_expr=3, U=1,V=1 ) : NOP()
  716.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  717.  
  718.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  719.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  720.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  721.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  722.  
  723.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  724.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  725.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  726.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  727.                                   backBlend1
  728.  
  729.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  730.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  731.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  732.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  733.  
  734.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  735.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  736.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  737.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " scalef - " + string(GrainRestore) + " * range_half +", use_expr=2, U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  738.  
  739.     # Final light linear temporal smooth for denoising
  740.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  741.     stable  = (TR2 == 0) ? addNoise1 : \
  742.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                                  thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  743.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  744.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  745.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  746.               (TR2 == 5) ? addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  747.                            addNoise1.MDegrain6( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, bVec6,fVec6, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 )
  748.     stable  = (TR2 > 0) ? lsb ? stable.ditherpost(mode=6, slice=false) : n16 ? stable.ConvertTo8bit(dither=1) : stable : stable
  749.  
  750.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  751.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  752.  
  753.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  754.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  755.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  756.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  757.                                   repair2
  758.  
  759.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  760.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  761.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  762.  
  763.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  764.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  765.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  766.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " scalef - " + string(NoiseRestore) + " * range_half +", clamp_float=true, use_expr=3, U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  767.  
  768.  
  769.     #---------------------------------------
  770.     # Post-Processing
  771.  
  772.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  773.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  774.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  775.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  776.  
  777.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  778.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  779.     rBlockSize = BlockSize / rBlockDivide
  780.     rOverlap   = Overlap   / rBlockDivide
  781.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  782.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  783.     rBlockDivide = BlockSize / rBlockSize
  784.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  785.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  786.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  787.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  788.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  789.  
  790.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  791.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  792.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  793.  
  794.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  795.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  796.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  797.                    (SBlurLimit == 0)  ? sblur : \
  798.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  799.     # Reduce frame rate
  800.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  801.  
  802.     # Crop off temporary vertical padding
  803.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  804.     h = Border ? h-8 : h
  805.  
  806.     # Show output of choice + settings
  807.     # >>>> Restore YUY2 to interleaved
  808.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x range_half - " + string(ShowNoise) + " * range_half +", clamp_float=true, use_expr=2, U=CNmt128,V=CNmt128 )
  809.     output = yuy2 ? output.nonyuy2clipout(true) : output
  810.     return (ShowSettings == false) ? output : \
  811.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  812.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  813.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  814.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  815.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  816.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  817.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  818.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  819.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  820.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  821.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  822.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  823.         Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  824.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  825.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  826.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  827.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  828.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  829.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  830.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  831. }
  832.  
  833.  
  834. #---------------------------------------
  835. # Helpers
  836.  
  837. # Same as Bob, but keeps the field order the same.
  838. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  839. {
  840.   sisphbd = AvsPlusVersionNumber > 2294
  841.   h = Default(height, cp.Height)
  842.   w = cp.Width
  843.   shift = GetParity(cp) ? 0.25 : -0.25
  844.  
  845.   c420 = sisphbd  ? Is420(cp) : IsYV12(cp)
  846.  
  847.   c420 ? cp.SeparateFields() : nop()
  848.  
  849.   oeven=c420 ? SelectEven() : nop()
  850.   oodd=c420 ? SelectOdd() : nop()
  851.  
  852.   even=c420 ? sisphbd  ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  853.   odd=c420 ? sisphbd  ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  854.  
  855.   evenChr=c420 ? Interleave(sisphbd  ? oeven.ExtractU() : oeven.UToY8(), sisphbd  ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  856.   oddChr=c420 ? Interleave(sisphbd  ? oodd.ExtractU() : oodd.UToY8(), sisphbd  ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  857.  
  858.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  859.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  860. }
  861.  
  862.  
  863. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  864. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  865. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  866.                             string "ChromaEdi" )
  867. {
  868.     # >>>> YUY2 is interleaved here
  869.  
  870.     ChromaEdi = default( ChromaEdi, "" )
  871.     CEed = (ChromaEdi == "")
  872.  
  873.     interp = (InputType == 1)            ? Input : \
  874.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  875.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  876.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  877.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  878.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  879.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  880.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  881.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.nonyuy2clipin(true).Yadifmod2( mode=3 ).nonyuy2clipout(true) : Input.Yadifmod2( mode=3 ) : \
  882.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  883.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  884.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.nonyuy2clipin(true).Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).nonyuy2clipin(true), 2, 0 ).nonyuy2clipout(true) : \
  885.                                                            Input.Yadifmod2( mode=3 ) : \   
  886.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).nonyuy2clipin(true), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).nonyuy2clipin(true), 2, 0 ).nonyuy2clipout(true) : \
  887.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  888.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  889.  
  890.     interpuv = (InputType == 1)        ? NOP() : \
  891.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  892.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.nonyuy2clipin(true).Yadifmod2( mode=3 ).nonyuy2clipout(true) : Input.Yadifmod2( mode=3 ) : \
  893.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  894.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  895.                                          NOP()
  896.  
  897.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  898. }
  899.  
  900.  
  901. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  902. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  903. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  904. {
  905.     # >>>> YUY2 is planar here
  906.     mtY =default( Y, 3 )
  907.     mtU =default( U, 1 )
  908.     mtV =default( V, 1 )
  909.     rgY = (mtY == 3) ? 20 : -1
  910.     rgU = (mtU == 3) ? 20 : -1
  911.     rgV = (mtV == 3) ? 20 : -1
  912.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  913. }
  914.  
  915. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  916. {
  917.     # >>>> YUY2 is planar here
  918.     mtY =default( Y, 3 )
  919.     mtU =default( U, 1 )
  920.     mtV =default( V, 1 )
  921.     rgY = (mtY == 3) ? 20 : -1
  922.     rgU = (mtU == 3) ? 20 : -1
  923.     rgV = (mtV == 3) ? 20 : -1
  924.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  925. }
  926.  
  927. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  928. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  929. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  930. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  931. {
  932.     # >>>> YUY2 is planar here
  933.  
  934.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  935.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  936.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  937.     Rep    = default( Rep,    1    )
  938.     Chroma = default( Chroma, true )
  939.     ed = (Rep < 10) ? Rep : Rep / 10
  940.     od = (Rep < 10) ? 0   : Rep % 10
  941.     RCrg  = Chroma ? 3 : 1
  942.     RCrgo = Chroma ? 3 : 2
  943.  
  944.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  945.  
  946.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  947.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  948.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  949.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  950.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  951.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  952.                                                                                                                      
  953.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  954.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  955.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  956.  
  957.     # Over-dilation - extra reflation up to about 1 pixel
  958.     choke1 = (od == 0)            ? choke1 : \
  959.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  960.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  961.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  962.  
  963.     # Areas of negative difference (similar to above)
  964.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  965.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  966.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  967.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  968.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  969.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  970.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  971.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  972.     choke2 = (od == 0)            ? choke2 : \
  973.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  974.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  975.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  976.  
  977.     # Combine above areas to find those areas of difference to restore
  978.     restore = diff.mt_lutxy( choke1, "x 129 scalef < x y range_half < range_half y ? ?", use_expr=2, U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 scalef > x y range_half > range_half y ? ?", use_expr=1, U=RCrg,V=RCrg )
  979.  
  980.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  981. }
  982.  
  983.  
  984. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  985. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  986. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  987. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  988. {
  989.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  990.     ChromaNoise = default( ChromaNoise, false )
  991.     CNmt1 = ChromaNoise ? 3 : 1
  992.     origNoise = Input.SeparateFields()
  993.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  994.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  995.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  996.     random    = InterleavedClip.IsYUY2() ? random.nonyuy2clipin(true) : random
  997.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x range_half - y * range_size / range_half +", scale_inputs="floatf", use_expr=3, U=CNmt1,V=CNmt1)
  998.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  999.     return Interleave( origNoise, newNoise ).Weave()
  1000. }
  1001.  
  1002.  
  1003. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  1004. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  1005. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  1006. {
  1007.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  1008.  
  1009.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  1010.  
  1011.     # Weave the source fields and the "new" fields that have generated in the input
  1012.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  1013.     srcFields  = Source.IsYUY2() ? srcFields1.nonyuy2clipin(true) : srcFields1
  1014.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  1015.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  1016.  
  1017.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  1018.     vertMedian  = processed.VerticalCleaner( mode=1 )
  1019.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  1020.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  1021.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x range_half - y range_half - * 0 < range_half x range_half - abs y range_half - abs < x y ? ?", use_expr=2, U=3,V=3 )
  1022.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  1023.  
  1024.     # Reweave final result
  1025.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  1026. }
  1027.  
  1028.  
  1029. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  1030. # the source without introducing shimmer. All other arguments defined in main script
  1031. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  1032.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  1033.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  1034.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  1035.                                  float MatchEnhance, int EdiThreads, bool lsb, bool n16 )
  1036. {
  1037.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  1038.     yuy2 = Source.IsYUY2()
  1039.     Source = yuy2 ? Source.nonyuy2clipin(true) : Source
  1040.  
  1041.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  1042.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  1043.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  1044.     # this new source. Result will still be shimmer-free and closer to the original source.
  1045.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  1046.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  1047.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  1048.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  1049.     errorTemporalSimilarity = 0.5  # S in formula described above
  1050.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1051.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1052.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  1053.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", clamp_float=true, use_expr=2, U=3,V=3 )
  1054.     noyv16ma1Edi   = MatchEdi =="NNEDI2" || MatchEdi =="NNEDI" || MatchEdi =="EEDI3+NNEDI3" || MatchEdi =="EEDI3" || MatchEdi =="EEDI2" || MatchEdi =="TDeint" || MatchEdi =="cYadif" || MatchEdi =="RepcYadif"
  1055.     noyv16ma2Edi   = MatchEdi2=="NNEDI2" || MatchEdi2=="NNEDI" || MatchEdi2=="EEDI3+NNEDI3" || MatchEdi2=="EEDI3" || MatchEdi2=="EEDI2" || MatchEdi2=="TDeint" || MatchEdi2=="cYadif" || MatchEdi2=="RepcYadif"
  1056.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  1057.     !noyv16ma1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1058.                              match1Update.nonyuy2clipout(true) \
  1059.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1060.                                          .nonyuy2clipin(true)
  1061.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1062.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1063.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1064.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : n16 ? match1Degrain1.ConvertTo8bit(dither=1) : match1Degrain1 : match1Degrain1
  1065.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : n16 ? match1Degrain2.ConvertTo8bit(dither=1) : match1Degrain2 : match1Degrain2
  1066.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1067.                      (MatchTR1 == 0)   ? match1Edi : \
  1068.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1069.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1070.  
  1071.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1072.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", clamp_float=true, use_expr=2, U=3,V=3 ) : match1
  1073.  
  1074.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1075.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1076.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1077.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1078.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1079.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1080.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1081.     !noyv16ma2Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1082.                              match2Diff.nonyuy2clipout(true) \
  1083.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1084.                                        .nonyuy2clipin(true)
  1085.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1086.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1087.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1088.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : n16 ? match2Degrain1.ConvertTo8bit(dither=1) : match2Degrain1 : match2Degrain1
  1089.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : n16 ? match2Degrain2.ConvertTo8bit(dither=1) : match2Degrain2 : match2Degrain2
  1090.     match2         = (SourceMatch < 2) ? match1 : \
  1091.                      (MatchTR2 == 0)   ? match2Edi : \
  1092.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1093.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1094.  
  1095.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1096.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1097.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1098.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", clamp_float=true, use_expr=2, U=3,V=3 )
  1099.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1100.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1101.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1102.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : n16 ? match3Degrain1.ConvertTo8bit(dither=1) : match3Degrain1 : match3Degrain1
  1103.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : n16 ? match3Degrain2.ConvertTo8bit(dither=1) : match3Degrain2 : match3Degrain2
  1104.     match3         = (SourceMatch < 3) ? match2 : \
  1105.                      (MatchTR2 == 0)   ? match3Update : \
  1106.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1107.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1108.  
  1109.     # Apply difference calculated in source-match refinement
  1110.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1111. }
  1112.  
  1113.  
  1114. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1115. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1116. {
  1117.     Replace = default( Replace, false )
  1118.     globalName = Prefix + "_" + Name
  1119.  
  1120.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1121.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1122.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1123.     catch (e)
  1124.     {
  1125.         Eval( "global " + globalName + " = Value" )
  1126.         Replace = true
  1127.     }
  1128.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1129. }
  1130.  
  1131. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1132. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1133. {
  1134.     Reuse = default( Reuse, false )
  1135.     globalName = Prefix + "_" + Name
  1136.  
  1137.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1138.     catch (e) { ret = NOP() }
  1139.     return ret
  1140. }
RAW Paste Data
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy. OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!
 
Top