limpiador.cmd

@echo off

:: limpiador.cmd
:: Autor: angeldp
:: script que, con cada arranque del sistema o ejecución manual del mismo,
:: se encarga de vaciar los archivos temporales de Internet y vaciar la
:: papelera de reciclaje, almacenando en un fichero, \TEMP\log.txt,
:: las acciones realizadas.
:: Además, el script borrará los ficheros con extensión tmp que se encuentren
:: en el directorio del usuario

cls
color 1b
title Exterminador de temporales y demás basura
::Defino la variable de entorno para guardar el archivo de registro:
set log=C:\TEMP\log.txt
::Creo el directorio y el archivo de log, dándole formato e incluyendo fecha, hora y usuario
mkdir C:\TEMP 2> nul
echo. >> %log%
echo. >> %log%
echo. ············ooooooooOOOOOOOO000000000OOOOOOOOoooooooo··············  >> %log%
echo. >> %log%
echo Usuario: %USERNAME% >> %log%
echo. >> %log%
echo Fecha:  >> %log%
date /t >> %log%
echo. >> %log%
echo Hora: >> %log%
time /t >> %log%
echo. >> %log%

::Por pantalla indico las tareas a realizar
echo Se va a realizar una limpieza en el sistema...
echo.
echo Presione cualquier tecla para vaciar la papelera
pause > nul
::Me cargo la papelera (y todo lo que contiene). Al borrar un archivo se volverá a crear.
::Antes escribo en un archivo la aperación:
echo Se procede a vaciar la papelera... >> %log%
rd /s /q \RECYCLER 2>> %log%
::El siguiente es un virus y no está de más borrarlo
echo Si existe el virus recicled también se borra >> %log%
rd /s /q \recycled 2>> %log%
echo. >> %log%
echo. >> %log%
echo Se limpiarán ahora los temporales de Internet
pause
::Borro cookies y si da error lo escribo en el log
echo. >> %log%
echo Cookies... >> %log%
del "%USERPROFILE%\Cookies\index.dat" > nul 2>> %log%
::Los temporales del iexplorer
echo. >> %log%
echo Temporales de Internet... >> %log%
rd /s /q "%USERPROFILE%\Configuración local\Archivos temporales de Internet\Content.IE5" 2>> %log%
::El historial
echo. >> %log%
echo Historial de Internet... >> %log%
rd /s /q "%USERPROFILE%\Configuración local\Historial" 2>> %log%
::Los archivos con extensión tmp en mi perfil serán eliminados
echo A continuación eliminaré los archivos .tmp de mi perfil
pause
::del /s borra recursivamente, por lo que deberá eliminar cualquier archivo tmp en mi perfil
::dado que algunos están en uso redirecciono el error a nul y el resultado al log
echo. >> %log%
echo Archivos temporales eliminados... >> %log%
del /s "%USERPROFILE%\*.tmp"  >> %log% 2>nul
echo. >> %log%
echo Archivos temporales que no se han podido eliminar: >> %log%
dir /s /a "%USERPROFILE%\*.tmp" >> %log%
echo.
echo Hecho, puede ver detalles de las operaciones realizadas en %log%
pause > nul