ivtc_helpers.avs

Function ivtc_txt60mc (clip src, int frame_ref, bool "srcbob", bool "draft")
{
    srcbob    = Default (srcbob, false)
    draft     = Default (draft,  false)

    field_ref = (srcbob) ? frame_ref : frame_ref * 2
    field_ref =      field_ref  % 5
    invpos    = (5 - field_ref) % 5
    pel       = (draft) ? 1 : 2

    src
      (srcbob) ? last
\   : (draft ) ? Bob ()
\   :            QTGMC ("fast")

    clean  = SelectEvery (5, 1 - invpos)
    jitter = SelectEvery (5, 3 - invpos, 4 - invpos)
    jsup   = jitter.MSuper (pel=pel)
    vect_f = jsup.MAnalyse (isb=false, delta=1, overlap=4)
    vect_b = jsup.MAnalyse (isb=true,  delta=1, overlap=4)
    comp   = jitter.MFlowInter (jsup, vect_b, vect_f, time=50, thSCD1=400)
    fixed  = comp.SelectEvery (2, 0)
    Interleave (clean, fixed)
    Trim (invpos / 2, 0)
}


function norm_ivtc(clip c, bool "dec_out", int "y0", int "y1") {
    dec_out = Default(dec_out, true)
    y0i = Default(y0, 58)
    y1i = Default(y1, 140)
    c
    dt = TDeint(order=1,field=1,type=1,edeint=nnedi3(field=1,threads=1))
    tfm(pp=5,mode=2,order=1,slow=1,y0=y0i,y1=y1i,clip2=dt)
    vinverse()
    return (dec_out) ? last.tdecimate() : last.assumefps("ntsc_film")
}

function fast_ivtc(clip c, bool "dec_out", int "y0", int "y1") {
    dec_out = Default(dec_out, true)
    c
    tfm(slow=0, pp=0)
    return (dec_out) ? last.tdecimate() : last.assumefps("ntsc_film")
}