cleo speed limiter (60-90-130)

{$VERSION 4.3.16}
{$CLEO .cs}

//-------------MAIN---------------

thread 'SPEED_LIMITER'

0006: 0@ = -1 //not active
0006: 20@ = -1 //incar

0007: 18@ = 45.0 //max speed
0007: 19@ = 7.0 //extra speed for setspeed

//--------------------------------------------------

:SPEED_LIMITER_00
wait 0
if and
    00DF: actor $PLAYER_ACTOR driving
    84C8: not actor $PLAYER_ACTOR driving_flying_vehicle
    84A9: not actor $PLAYER_ACTOR driving_heli
    84A7: not actor $PLAYER_ACTOR driving_boat
else_jump @SPEED_LIMITER_09 //loop da loop

if
    0039: 20@ == -1 //not incar
then
    0006: 20@ = 1 //incar
    if
        0039: 0@ == 1 //iz enabled
    then
        00BA: show_text_styled GXT 'SPEED_1' time 1000 style 6  // ~g~enabled
    else
        00BA: show_text_styled GXT 'SPEED_0' time 1000 style 6  // ~r~disabled
    end
end

gosub @SPEED_LIMITER_40 //check da keys

if
    0039: 0@ == 1 //enabled
else_jump @SPEED_LIMITER_50 //check key

gosub @SPEED_LIMITER_10 //limit it

jump @SPEED_LIMITER_50 //check key

:SPEED_LIMITER_09
0006: 20@ = -1 //not incar
jump @SPEED_LIMITER_00

//--------------------------------------------------

//check key
:SPEED_LIMITER_50
if or
    0AB0: key_pressed 48 //0
    0AB0: key_pressed 96 //numpad 0
else_jump @SPEED_LIMITER_00 //loop da loop
gosub @SPEED_LIMITER_20 //toggle
jump @SPEED_LIMITER_00 //loop da loop

//--------------------------------------------------

//limit it
:SPEED_LIMITER_10
03C0: 2@ = actor $PLAYER_ACTOR car
02E3: 3@ = car 2@ speed
if
    0025: 3@ > 18@ // (float)
else_jump @SPEED_LIMITER_11
0087: 14@ = 18@ // (float)
005B: 14@ += 19@ // (float)
04BA: set_car 2@ speed_to 14@
:SPEED_LIMITER_11
return

//--------------------------------------------------

//toggle
:SPEED_LIMITER_20
0012: 0@ *= -1 //toggledashizzle
if
    0039: 0@ == 1 //iz enabled
then
    00BA: show_text_styled GXT 'SPEED_1' time 1000 style 6  // ~g~enabled
else
    00BA: show_text_styled GXT 'SPEED_0' time 1000 style 6  // ~r~disabled
end
wait 500
return

//--------------------------------------------------

//check da keys
:SPEED_LIMITER_40
if
    0AB0:   key_pressed 49 // 1
else_jump @SPEED_LIMITER_41
gosub @SPEED_LIMITER_60 //enable
0007: 18@ = 18.3 //max speed
0007: 19@ = 2.0 //extra
00BA: show_text_styled GXT 'SPEED_15' time 1000 style 6  // ~g~15

:SPEED_LIMITER_41
if
    0AB0:   key_pressed 50 // 2
else_jump @SPEED_LIMITER_42
gosub @SPEED_LIMITER_60 //enable
0007: 18@ = 28.5 //max speed
0007: 19@ = 5.2 //extra
00BA: show_text_styled GXT 'SPEED_25' time 1000 style 6  // ~g~25

:SPEED_LIMITER_42
if
    0AB0:   key_pressed 51 // 3
else_jump @SPEED_LIMITER_49
gosub @SPEED_LIMITER_60 //enable
0007: 18@ = 40.0 //max speed
0007: 19@ = 7.5 //extra
00BA: show_text_styled GXT 'SPEED_33' time 1000 style 6  // ~g~33

:SPEED_LIMITER_49
return

//--------------------------------------------------

//enable
:SPEED_LIMITER_60
if
    0039: 0@ == -1 //not enabled
then
    0006: 0@ = 1 //enable
    00BA: show_text_styled GXT 'SPEED_1' time 1000 style 6  // ~g~enabled
end
return