Nicklist DCX Based (Final)

;_________________________
;---= Custom Nicklist =---
;---=   DCX Based     =---
;_________________________
;Created By MakiMaki
;Images By seraphim
;Coded By MakiMaki & extremity
;Thank you to the Following:
;DCX dev team, err0r, Stealth, ness, MisterAwesome, Lucifer, and to any one I missed, Thank you.
;This snippet works only with the DCX dev build, and mIRC 7.*  (Copy of both encluded in Zip)
;Any bugs glitches or thoughts please email MakiMaki1.13@null.net
;Thankyou and enjoy:)

;Notes Icons path is icons\(filename) change this to what you wish (line 39 - 52 to edit icon file path)
;DCX Path is dlls\dcx.dll (line 104 to edit this file path)
;RCYF aka(Righ Click You Fucker) Path is dlls\rcyf.dll (line 97 to edit this file path)

;____________________
;(----= Dialog =----)
;____________________

dialog nlist {
  title "Nicklist"
  size -1 -1 1 $window(-2).h
  option pixel
}

on *:DIALOG:nlist:init:*:{
  dcx Mark nlist callback_nlist

  ;Nicklist
  xdialog -c $dname 2 listview 1 -1 175 $calc($window(-2).h - 90) report fullrow nolabelwrap noheader transparent tabstop showsel

  ;Sets background color and text color
  xdid -i $dname 2 +bk  $color($color(listbox))
  xdid -i $dname 2 +t  $color($color(listbox text))

  ;Icons to return user level
  xdid -t $dname 2 + 0 20 $null $chr(9) + 0 130
  xdid -w $dname 2 +n 0 icons\wings.ico
  xdid -w $dname 2 +n 0 icons\gold.ico
  xdid -w $dname 2 +n 0 icons\red.ico
  xdid -w $dname 2 +n 0 icons\silver.ico
  xdid -w $dname 2 +n 0 icons\brown.ico
  xdid -w $dname 2 +n 0 icons\voice.ico
  xdid -w $dname 2 +n 0 icons\users.ico
  xdid -w $dname 2 +n 0 icons\spec.ico
  xdid -w $dname 2 +n 0 icons\super.ico
  xdid -w $dname 2 +n 0 icons\meop.ico
  xdid -w $dname 2 +n 0 icons\mevoice.ico
  xdid -w $dname 2 +n 0 icons\meuser.ico
  xdid -w $dname 2 +n 0 icons\cup.ico

  nlist
}

;____________________
;(--= Main Alias =--)
;____________________

alias nicklist {
  if ($dialog(nlist)) { dialog -x nlist }
  dialog -m nlist nlist
  xdock -m $dialog(nlist).hwnd +r
  ;Fake Window to use for nicklist menu
  if ($window(@hidden)) { window -c @hidden }
  window --aihznhw0 @hidden 1 1 0 0
  xdock -m $window(@hidden).hwnd +b
}

alias nlist {
  if (!$dialog(nlist)) { nicklist }
  xdid -r nlist 2
  xdid -i nlist 2 +bk  $color($color(listbox)) | xdid -i nlist 2 +t  $color($color(listbox text))
  var %i 1
  while ($nick($active,%i)) {
    var %n $v1
    if ($left(%n,1) isin '^) var %l 1
    elseif ($ismode($active,%n,Q)) var %l $iif($me = %n,10,9)
    elseif ($ismode($active,%n,q)) var %l $iif($me = %n,10,2)
    elseif ($ismode($active,%n,a)) var %l $iif($me = %n,10,3)
    elseif ($ismode($active,%n,o)) var %l $iif($me = %n,10,4)
    elseif ($ismode($active,%n,h)) var %l $iif($me = %n,10,5)
    elseif ($ismode($active,%n,v)) var %l $iif($me = %n,11,6)
    else var %l $iif(m isin $chan($active).mode,8,$iif($me = %n,12,7))
    xdid -a nlist 2 0 0 + %l 0 0 0 -1 -1 $chr(9) + 0 0 -1 -1 %n
    inc %i
} }

alias callback_nlist {
  ;Nicklist clicks
  if ($2 == dclick && $3 == 2) { query $xnick }
  ;popup menu call- uses rcyf to popup fake nicklist
  if ($2 == rclick && $3 == 2) {
    ;y offset varies based upon menu size
    var %y $calc($mouse.cy - $window(-2).y + 40), %x $calc($mouse.cx - $window(-2).x)
    dll dlls\rcyf.dll popup $window(@hidden).hwnd %x %y
  }
  ;resize call- adjust size of nicklist
  elseif ($2 == sizing && $4 && $5) { var %p $xdid(nlist, 2).pos | xdid -p nlist 2 $gettok(%p,1-3,32) $5 }
  halt
}

alias dcx { if ($isid) returnex $dll($shortfn($mircdir) $+ dlls\dcx.dll,$1,$2-) | else dll " $+ $shortfn($mircdir) $+ dlls\dcx.dll" $1 $2- }

alias udcx { if ($dcx(IsUnloadSafe)) $iif($menu, .timer 1 0) dll -u dcx.dll | else echo 4 -qmlbfti2 [DCX] Unable to Unload Dll. }

alias xdid { if ( $isid ) returnex $dcx( _xdid, $1 $2 $prop $3- ) | dcx xdid $2 $3 $1 $4- }

alias xdialog { if ( $isid ) returnex $dcx( _xdialog, $1 $prop $2- ) | dcx xdialog $2 $1 $3- }

alias xdock { if ($isid) returnex $dcx( _xdock, $1 $prop $2- ) | dcx xdock $1- }

alias ismode return $iif($nick($1,$2,$mid($prefix,$poscs($nickmode,$3),1)),$true,$false)


;____________________
;(---= Triggers =---)
;____________________

on *:JOIN:#: { if ($active == #) { .timer -m 1 50 nlist } }

on *:PART:#: { if ($active == #) { .timer -m 1 50 nlist } }

on *:KICK:#: { if ($active == #) { .timer -m 1 50 nlist } }

on *:RAWMODE:#: { if ($active == #) { .timer -m 1 50 nlist } }

on *:QUIT: { if ($comchan($nick,0) == $active) { .timer -m 1 50 nlist } }

on *:NICK: { if ($comchan($newnick,0) == $active) { .timer -m 1 50 nlist } }

on *:ACTIVE:*: {
  if ($me ison $active) { xdock -r $dialog(nlist).hwnd + 207 1 | nlist }
  else { xdock -r $dialog(nlist).hwnd + 1 1 }
}

;____________________
;(-----= Menu =-----)
;____________________

;Nicklist Menu alias
alias xnick { return $xdid(nlist, 2, 2).seltext }

alias xnicks {
  var %i $xdid(nlist, 2).selnum, %r
  while (%i) { var %r $addtok(%r, $xdid(nlist, 2, $xdid(nlist, 2, %i).sel, 2).text , 44) | dec %i }
  return %r
}

menu @hidden {
  $xnick Info
  .Copy Nick $xnick : echo -a * Nickname copyed to clip board: $xnick | clipboard $xnick
  .Whois: whois $xnick
  .UserID $ial($xnick,1).user : echo 7 -a * $xnick User ID $ial($xnick,1).user | clipboard $ial($xnick,1).user
  .$address($xnick,1) : echo 7 -a * $xnick Full gate $address($xnick,1) | clipboard $address($xnick,1)
  -
  $iif($ismode($active,$xnick,q),$style(1)) · $chr(32) Owner: { mode $active $iif($ismode($active,$xnick,q),-q,+q) $xnick  }
  $iif($ismode($active,$xnick,a),$style(1)) · $chr(32) Admin: { mode $active $iif($ismode($active,$xnick,a),-a,+a) $xnick  }
  $iif($ismode($active,$xnick,o),$style(1)) · $chr(32) Host: { mode $active $iif($ismode($active,$xnick,o),-o,+o) $xnick }
  $iif($ismode($active,$xnick,h),$style(1)) · $chr(32) Halfop: { mode $active $iif($ismode($active,$xnick,h),-h,+h) $xnick  }
  $iif($ismode($active,$xnick,v),$style(1)) · $chr(32) Voice: { mode $active $iif($ismode($active,$xnick,v),-v,+v) $xnick }
  -
  CTCP
  .Time:.ctcp  $xnick TIME
  .Version:.ctcp  $xnick VERSION
  .Finger:.ctcp  $xnick FINGER
  -
  Kicks
  .Quick Kick: kick $active $xnick ByeBye
  .Custom Kick: kick $active $xnick $$?="Reason for kick:"
  -
}