python-pysvn

pkgname=python-pysvn
_name=${pkgname#python-}
pkgver=1.9.16
pkgrel=1
pkgdesc="The Pythonic interface to Subversion"
arch=('x86_64')
url="https://pysvn.sourceforge.io"
license=('Apache')
depends=('apr' 'python' 'subversion')
makedepends=('python-pycxx' 'python-setuptools')
provides=("_${_name}.so")
source=("https://downloads.sourceforge.net/project/pysvn/pysvn/V$pkgver/$_name-$pkgver.tar.gz")
sha256sums=('20fbd5ab66d38997e691f088af2b8d74be1994206afb81026198fc5424a42e0e')

prepare() {
  cd "$_name-$pkgver"

  # Remove bundled libs
  rm -rf Import
}

build() {
  cd "$_name-$pkgver"

  pushd Source
  python setup.py configure --verbose --fixed-module-name --norpath

  sed -i "s/-Wall -fPIC -fexceptions -frtti/${CXXFLAGS} -fPIC -frtti/g" Makefile
  make
  popd
}

check() {
  cd "$_name-$pkgver"

  pushd Tests
  # the tests expect a valid answer from locale.getdefaultlocale()
  # C.UTF-8 does not work. Use en_US.utf-8.
  LC_ALL=en_US.UTF-8 make
  popd
}

package() {
  cd "$_name-$pkgver"
  python setup.py install --root="$pkgdir/" --optimize=1 --skip-build

  local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")

  # Fixed module name
  sed -i "s/_${_name}_3_9/_${_name}/g" \
    "$pkgdir$site_packages/$_name-$pkgver-py3.9.egg-info/top_level.txt"

  install -Dm644 "Source/$_name/__init__.py" -t "$pkgdir$site_packages/$_name/"
  install -Dm644 "Source/$_name/_${_name}.so" -t "$pkgdir$site_packages/$_name/"
}