//v1.1, 5/28/2011
//v1.1 uses getLineCount instead of isFile so if the file is empty it returns "not there."
//This is important because Torque can't delete files, so if someone deletes their account it will leave an empty file behind, and isFile would say the account was still in use.
//v1.1 also uses the username stored inside of the file instead of whatever string the user logs in with, so case won't be an issue.
//v1.1 saves the "guild" variable since I'm gonna start on that in about five minutes.

//I'm using messageClient commands so I can see them for now.
//They can be changed later.
//Or, better yet, you can keep those and have the GUIs use message hooks, so non-ennRP people can still get messages and stuff so they won't ragequit immediately.

function servercmdNewAccount(%client, %username, %password) {
if(%client.username !$= "") {
  messageClient(%client, 'MsgAccountCreationFailure', "You are already logged in.  Please log out before creating a new account.");
  return;
}
if(getLineCount("ennRP/server/accounts/"@ strLwr(%username) @".txt")) {
  messageClient(%client, 'MsgAccountCreationFailure', "Sorry, but that username has already been taken.  Please choose another username.");
  return;
}
if(getLineCount("ennRP/server/accounts/"@ strLwr(%username) @".txt")) {
  messageClient(%client, 'MsgAccountCreationFailure', "Sorry, but that username has already been taken.  Please choose another username.");
  return;
}
if(strLen(%userName) < 5) {
  messageClient(%client, 'MsgAccountCreationFailure', "Sorry, but your username must have at least 5 characters.  Please choose a longer username.");
  return;
}
if(strLen(%password) < 6) {
  messageClient(%client, 'MsgAccountCreationFailure', "Sorry, but your password must have at least 6 characters.  Please choose a longer password.");
  return;
}
%client.username = %username;
%client.password = %password;
%client.setStuds(100);
%client.level = 1;
%client.class = 1;
messageClient(%client, 'MsgAccountCreation',
  "Your new account has been created.  Your username is" SPC %username @ ".\n"@
  "Your password is" SPC %password @ ".  Don't forget your password.  It's important.");
}

function servercmdLogin(%client, %username, %password) {
//I'll just assume that the username and password are both adequately long, since the only reason that they wouldn't be is because somebody changed it on purpose.
if(!getLineCount("ennRP/server/accounts/"@ strLwr(%username) @".txt")) {
  messageClient(%client, 'MsgAccountLoginFailure', "Sorry, but that account does not exist.  Please verify that you have spelled your username correctly.");
  return;
}
if(!isObject(%f = EnnRP_FileObject))
  %f = new FileObject(EnnRp_FileObject);
%f.openForRead("ennRP/server/accounts/"@ strLwr(%username) @".txt");
%n = %f.readLine(); //The first line, I just realized, is the correct username.  This is case-sensitive and can handle funny characters that filenames can't.
if(%password !$= %f.readLine()) {
  messageClient(%client, 'MsgAccountLoginFailure', "Sorry, but your password is incorrect.  Please verify that you have typed your password in correctly.");
  %f.close();
  return;
}
//Success
messageClient(%client, 'MsgAccountLogin', "You have successfully logged in.");
%client.username = %n;
%client.password = %password; //Save this so we can use it later when we have to save
%client.setStuds(%f.readLine());
%client.level = %f.readLine();
%client.class = %f.readLine();
//Outfit information
%client.colorSkin	= %f.readLine();
%client.headCode	= %f.readLine();
%client.visorCode	= %f.readLine();
%client.backCode	= %f.readLine();
%client.leftHandCode    = %f.readLine();
%client.chestCode       = chestShowImage;
%client.faceCode        = faceplateShowImage;
%client.headCodeColor	= addTaggedString($legoColor[%f.readLine()]);
%client.visorCodeColor	= addTaggedString($legoColor[%f.readLine()]);
%client.backCodeColor	= addTaggedString($legoColor[%f.readLine()]);
%client.leftHandCodeColor = addTaggedString($legoColor[%f.readLine()]);
%client.chestdecalcode		= addTaggedString(%f.readLine());
%client.facedecalcode   	= addTaggedString(%f.readLine());
%client.bodytype = %f.readLine();
servercmdarmsncrotch(%client,%client.bodytype);
if(isObject(%player = %client.player)) {
	%player.unMountImage($headSlot);
	%player.unMountImage($visorSlot);
	%player.unMountImage($backSlot);
	%player.unMountImage($leftHandSlot);
	%player.unMountImage($chestSlot);
	%player.unMountImage($faceSlot);
	%player.unMountImage(7);
	if (%client.team $= "")
		%player.setSkinName(%client.colorSkin);
	%player.mountImage(%client.headCode, $headSlot, 1, %client.headCodeColor);
	%player.mountImage(%client.visorCode, $visorSlot, 1, %client.visorCodeColor);
	%player.mountImage(%client.backCode, $backSlot, 1, %client.backCodeColor);
	%player.mountImage(%client.leftHandCode, $leftHandSlot, 1, %client.leftHandCodeColor);
	%player.mountImage(%client.chestCode, $chestSlot, 1, %client.chestdecalcode);
	%player.mountImage(%client.faceCode, $faceSlot, 1, %client.facedecalcode);
}
//Inventory and such
%client.primaryWeapon = %f.readLine();
%client.secondaryWeapon = %f.readLine();
%client.Chest = %f.readLine();
%client.Helmet = %f.readLine();
%client.Ammo = %f.readLine();
if(isObject(%client.player)) {  //These should probably be saved to the player
  %client.player.primaryWeapon = %client.primaryWeapon;
  %client.player.secondaryWeapon = %client.secondaryWeapon;
  %client.player.Chest = %client.Chest;
  %client.player.Helmet = %client.Helmet;
  %client.player.Ammo = %client.Ammo;
}
for(%x = 1; %x <= 28; %x++)
  %client.inventory[%x] = %f.readLine();
%client.guild = %f.readLine();
%f.close();
}

function saveAccount(%client) {
echo("Saveaccount called.");
if(%client.username $= "") {
  echo("Error in saving account: client" SPC %client SPC "is not logged in.");
  return;
}
if(!isObject(%f = EnnRP_FileObject))
  %f = new FileObject(EnnRp_FileObject);
%f.openForWrite("ennRP/server/accounts/"@ strLwr(%client.username) @".txt");
%f.writeLine(%client.userName); //The first line is just the username, for no good reason.  Maybe later it will be the last person who logged into this account
%f.writeLine(%client.password);
%f.writeLine(%client.studMoney);
%f.writeLine(%client.level);
%f.writeLine(%client.class);
%f.writeLine(%client.colorSkin);
%f.writeLine(%client.headCode);
%f.writeLine(%client.visorCode);
%f.writeLine(%client.backCode);
%f.writeLine(%client.leftHandCode);
%f.writeLine(%client.headCodeColorCode);
%f.writeLine(%client.visorCodeColorCode);
%f.writeLine(%client.backCodeColorCode);
%f.writeLine(%client.leftHandCodeColorCode);
%f.writeLine(%client.chestDecalCodeCode);
%f.writeLine(%client.faceDecalCodeCode);
%f.writeLine(%client.bodyType);
%f.writeLine(%client.primaryWeapon);
%f.writeLine(%client.secondaryWeapon);
%f.writeLine(%client.chest);
%f.writeLine(%client.helmet);
%f.writeLine(%client.ammo);
for(%x = 1; %x <= 28; %x++)
  %f.writeLine(%client.inventory[%x]);
%f.writeLine(%client.guild);
%f.close();
}

package Wiggy_Stupid_ServercmdUpdatePrefs_Color_grabber {
function ServerCmdUpdatePrefs(%client, %name, %skin, %headCode, %visorCode, %backCode, %leftHandCode, %headCodeColor, %visorCodeColor, %backCodeColor, %leftHandCodeColor, %chestdecalcode, %facedecalcode, %bodytype) {
%client.headCodeColorCode = %headCodeColor;
%client.visorCodeColorCode = %visorCodeColor;
%client.backCodeColorCode = %backCodeColor;
%client.leftHandCodeColorCode = %leftHandCodeColor;
%client.chestdecalcodeCode = %chestdecalcode;
%client.facedecalcodeCode = %facedecalcode;
Parent::ServerCmdUpdatePrefs(%client, %name, %skin, %headCode, %visorCode, %backCode, %leftHandCode, %headCodeColor, %visorCodeColor, %backCodeColor, %leftHandCodeColor, %chestdecalcode, %facedecalcode, %bodytype);
}
};
activatepackage(Wiggy_Stupid_ServercmdUpdatePrefs_Color_grabber);

package Wiggy_Accounts {
function GameConnection::onDrop(%client, %reason) {
if(%client.username !$= "")
  saveAccount(%client);
Parent::onDrop(%client, %reason);
}
function saveBlocks(%a, %b) {
echo("saveBlocks");
for(%i = 0; %i < ClientGroup.getCount(); %i++ ) {
  if(ClientGroup.getObject(%i).username !$= "")
    saveAccount(ClientGroup.getObject(%i));
}
Parent::saveBlocks(%a, %b);
}
};
activatepackage(Wiggy_Accounts);