BDFD | Орел и решка | v2

Орел и Решка | v2

・ Создатель: mlad_ | 773538519775445052

-------------------------------------------------------

Слеш:

・ Название: user, Тип: User, Не обязательно
・ Название: number, Тип: Number, Не обязательно

-------------------------------------------------------

Переменная:

・ Название: eagle
・ Значение: {}

-------------------------------------------------------

・ Язык: BDScript 2
・ Триггер: (префикс)eagle

$onlyIf[$guildID!=;]
$nomention

$var[color;ffffff]
$c[Цвет рамки]

$var[var;money]
$c[Переменная денежных средств (По умолчанию)]

$c[Тип переменной должен быть getUserVar, если хотите изменить тип, перейдите в $onInteraction, потом опустится в самый низ, и поменять функцию с setUserVar на setVar]

$if[$isSlash]
$var[user;$message[user]]
$var[number;$message[number]]
$else
$var[user;$findUser[$message[1];no]]
$var[number;$message[>]]
$endif

$color[$var[color]]
$if[$message[1]==info]
$title[Информация]
$description[📚 Вы можете сыграть в орла и решку, с кем-то, или прописав одну команду, вы сможете сыграть с ботом!]
$addField[Использование:;
⠀**.eagle** user number
⠀**.eagle** user
⠀**.eagle** number
⠀**.eagle**]
$addField[Аргументы:;
⠀**user** - пользователь / бот (не обязательно)
⠀**number** - сумма (Победитель забирает все деньги)]
$stop $endif

$if[$isNumber[$var[number]]]
$if[$var[number]>100000000]
$var[number;false]
$endif
$if[$var[number]<1]
$var[number;false]
$endif
$else
$var[number;false]
$endif

$if[$userExists[$var[user]]]
$if[$authorID==$var[user]]
$var[user;$botID]
$endif
$if[$isBot[$var[user]]]
$var[user;$botID]
$endif
$else
$var[user;$botID]
$endif

$jsonParse[$getUserVar[eagle]]
$if[$json[user]!=]
$description[Вы уже играете с пользователем **$username[$json[user]]**]
$stop $endif

$if[$botID!=$var[user]]
$jsonParse[$getUserVar[eagle;$var[user]]]
$if[$json[user]!=]
$description[Этот пользователь играет с пользователем **$username[$json[user]]**]
$stop $endif $endif

$if[$varExists[$var[var]]]
$if[$isNumber[$getVar[$var[var]]]==false]
$var[number;false]
$endif
$if[$isNumber[$getUserVar[$var[var]]]==false]
$var[number;false]
$endif
$if[$botID!=$var[user]]
$if[$isNumber[$getUserVar[$var[var];$var[user]]]==false]
$var[number;false]
$endif
$endif
$else
$var[number;false]
$endif

$if[$isNumber[$var[number]]]
$var[mong;За $var[number]$ (Победитель забирает все деньги)]

$if[$getUserVar[money]<$var[number]]
$description[У вас недостаточно средств! (Ваш баланс: $getUserVar[money])]
$stop $endif

$if[$botID!=$var[user]]
$if[$getUserVar[money;$var[user]]<$var[number]]
$description[У пользователя недостаточно средств! (Его баланс: $getUserVar[money;$var[user]])]
$stop $endif $endif $endif

$jsonSetString[user;$var[user]]
$setUserVar[eagle;$jsonStringify]

$if[$var[user]!=$botID]
$jsonSetString[user;$authorID]
$setUserVar[eagle;$jsonStringify;$var[user]]
$endif

$if[$var[user]==$botID]
$var[description;**$username**, вы начали играть с ботом! $var[mong]

Выберите орёл или решка]
$else
$var[description;**$username**, вы начали играть с пользователем **$username[$var[user]]**! $var[mong]

Выберите орёл или решка]
$endif

$var[msg;$sendEmbedMessage[$channelID;;$username[$var[user]] vs $username;;$var[description];$var[color];;;;;;;no;yes]]

$addButton[no;&|404|&_&|404|&;$username />;success;yes;;$var[msg]]

$addButton[no;eagle_and_tails-true_$var[var]_$var[number]_$authorID_$var[user];Орёл;secondary;no;;$var[msg]]

$addButton[no;eagle_and_tails-false_$var[var]_$var[number]_$authorID_$var[user];Решка;secondary;no;;$var[msg]]

$async[delete] $replyIn[40s] $try
$removeButtons[$var[msg]]
$catch $stop $endtry
$setUserVar[eagle;]
$setUserVar[eagle;;$var[user]]
$deleteMessage[$channelID;$var[msg]]
$endasync

-------------------------------------------------------

・ Язык: BDScript 2
・ Триггер: $onInteraction

$if[$checkContains[$customID;eagle_and_tails]==false] $stop $endif
$nomention $removeButtons

$var[color;ffffff]
$c[Цвет рамки]

$var[gif;https://media.discordapp.net/attachments/1082736047747764295/1085635552876961992/coin-flip-18.gif]
$c[GIF подброса монетки]

$textSplit[$customID;-]
$textSplit[$splitText[2];_]
$var[eagle;$splitText[1]]
$var[var;$splitText[2]]
$var[number;$splitText[3]]

$var[user1;$splitText[4]]
$var[user2;$splitText[5]]
$var[eagle1;$splitText[6]]

$if[$var[eagle1]==]
$var[user;$var[user1]]
$else $var[user;$var[user2]]
$endif

$if[$var[user]!=$authorID]
$description[Это не ваша кнопка!]
$color[$var[color]]
$ephemeral $stop $endif

$optOff[
$var[ranA;$randomText[true;false]]
$var[ranB;$randomText[true;false]]
]

$if[$var[user2]==$botID]
$color[$var[color]]
$title[Момент истины!]
$description[**$username[$botID]** подбросил монетку (🪙)]
$image[$var[gif]]

$if[$var[eagle]==$var[ranA]]
$var[nn1;true] $else
$var[nn1;false] $endif

$if[$var[ranB]==$var[ranA]]
$var[nn2;true] $else
$var[nn2;false] $endif

$editEmbedIn[3s;$username vs $username[$botID];
**$username[$botID]** подбросил монетку (🪙) и выпал$if[$var[ranA]] **Орёл**$elseа **Решка**$endif

⠀**$username** выбрал **$if[$var[eagle]]Орла$elseРешку$endif**, и **$if[$var[nn1]]Угадал!$elseНе угадал...$endif**
⠀**$username[$botID]** выбрал **$if[$var[ranB]]Орла$elseРешку$endif**, и **$if[$var[nn2]]Угадал!$elseНе угадал...$endif**

$if[$isNumber[$var[number]]]**$username**, $if[$var[nn1]]вам было добавлено$elseс вас было списано$endif **$var[number]**$$endif;;$var[color]]
$else

$if[$var[eagle1]!=]
$color[$var[color]]
$title[Момент истины!]
$description[**$username[$botID]** подбросил монетку (🪙)]
$image[$var[gif]]

$if[$var[eagle1]==$var[ranA]]
$var[nn1;true] $else
$var[nn1;false] $endif

$if[$var[eagle]==$var[ranA]]
$var[nn2;true] $else
$var[nn2;false] $endif

$editEmbedIn[3s;$username[$var[user2]] vs $username[$var[user1]];
**$username[$botID]** подбросил монетку (🪙) и выпал$if[$var[ranA]] **Орёл**$elseа **Решка**$endif

⠀**$username[$var[user1]]** выбрал **$if[$var[eagle1]]Орла$elseРешку$endif**, и **$if[$var[nn1]]Угадал!$elseНе угадал...$endif**
⠀**$username[$var[user2]]** выбрал **$if[$var[eagle]]Орла$elseРешку$endif**, и **$if[$var[nn2]]Угадал!$elseНе угадал...$endif**

$if[$isNumber[$var[number]]]$if[$var[nn1]==$var[nn2]]Ничья$else**$username[$var[user1]]**, $if[$var[nn1]]вам было добавлено$elseс вас было списано$endif **$var[number]**$
**$username[$var[user2]]**, $if[$var[nn2]]вам было добавлено$elseс вас было списано$endif **$var[number]**$$endif $endif;;$var[color]]
$else

$if[$isNumber[$var[number]]]
$var[mong;За $var[number]$ (Победитель забирает все деньги)]
$endif

$color[$var[color]]
$title[$username[$var[user2]] vs $username[$var[user1]]]

$description[**$username[$var[user1]]**, начал играть с вами **$username[$var[user2]]**! $var[mong]

Выберите орёл или решка]

$addButton[no;&$botID_$botID&;$username[$var[user2]] />;success;yes;]

$addButton[no;eagle_and_tails-true_$var[var]_$var[number]_$var[user1]_$var[user2]_$var[eagle];Орёл;secondary;no;]

$addButton[no;eagle_and_tails-false_$var[var]_$var[number]_$var[user1]_$var[user2]_$var[eagle];Решка;secondary;no;]
$stop $endif $endif

$setUserVar[eagle;;$var[user1]]
$if[$var[user2]!=$botID]
$setUserVar[eagle;;$var[user2]]
$endif

$if[$isNumber[$var[number]]]
$if[$var[nn1]!=$var[nn2]]
$if[$var[nn1]]
$setUserVar[$var[var];$sum[$getUserVar[$var[var];$var[user1]];$var[number]];$var[user1]]
$else
$setUserVar[$var[var];$sub[$getUserVar[$var[var];$var[user1]];$var[number]];$var[user1]]
$endif
$if[$var[user2]!=$botID]
$if[$var[nn2]]
$setUserVar[$var[var];$sum[$getUserVar[$var[var];$var[user2]];$var[number]];$var[user2]]
$else
$setUserVar[$var[var];$sub[$getUserVar[$var[var];$var[user2]];$var[number]];$var[user2]]
$endif $endif $endif $endif