[bitcoin] bitcoinica live ticker for mIRC

/*
bitcoinica live ticker for mIRC
by ageis @ #bitcoin-otc on freenode
http://ageispolis.net
modified: 12/05/2011
donations: 1AgeisUFv9NJ3AGGq7VPJWymGfFpCHDhCw

to load the script, type /load -rs btcticker.mrc
!! you must allow initialization commands
to set variables required by this script !!
to show the ticker, type /btcticker
to configure settings, type /btcsettings
or right-click for the menu

options:
- vertical or horizontal tickers    [default: horizontal]
- adjustable refresh rate       [default: 30 seconds]
- always on top         [default: on]
- show on desktop           [default: off]
- refresh while offline     [default: off]
*/

on *:LOAD:{
  unset btc*
  set %btcurl https://www.bitcoinica.com/api/quotes/BTCUSD.json
  set %btcrefresh 30
  set %btcoxaot 1
  set %btcoxoffline 0
  set %btcoxdesktop 0
  set %btcoxvert 0
}

menu * {
  bitcoinica
  ..ticker:btcticker
  ..config:btcsettings
}

dialog btcconfig {
  title "settings"
  size -1 -1 54 78
  option dbu
  check "always on top",1, 2 2 45 10,
  check "show on desktop",2, 2 12 50 10,
  check "refresh offline",3, 2 22 45 10,
  combo 9,2 33 50 9, drop
  text "refresh rate:",4, 2 45 50 8, center
  edit "",5, 2 52 30 11, limit 5
  text "secs",6, 34 54 10 10
  button "okay",99, 2 66 50 10, ok flat
}

dialog btcticker_vt {
  title "bitcoinica"
  size -1 -1 48 20
  option dbu
  text "BUY:" ,1, 2   0 14 8
  edit ""     ,2, 18  0 30 10,read
  text "SELL:" ,3, 2  10 14 8
  edit ""     ,4, 18 10 30 10,read
  ;button "refresh", 99, 0 60 48 10, flat
}

dialog btcticker_hz {
  title "bitcoinica live ticker"
  size -1 -1 94 10
  option dbu
  text "BUY:" ,1, 2   1 12 8
  edit ""     ,2, 16  0 30 10,read
  text "SELL:" ,3, 48  1 14 8
  edit ""     ,4, 64  0 30 10,read
  ;button "refresh", 99,278  0 32 10, flat
}

on *:dialog:btcticker_vt:init:0:{
  btcupdate btcticker_vt
  if (%btcoffline == 1) {
    .timerbtcvt -o 0 %btcrefresh btcupdate btcticker_vt
  }
  else { .timerbtcvt 0 %btcrefresh btcupdate btcticker_vt }
}
;on *:dialog:btcticker_vt:sclick:99:{ btcupdate btcticker_vt }
on *:dialog:btcticker_vt:close:0:{ .timerbtcvt off }

on *:dialog:btcticker_hz:init:0:{
  btcupdate btcticker_hz
  if (%btcoffline == 1) {
    .timerbtchz -o 0 %btcrefresh btcupdate btcticker_hz
  }
  else { .timerbtchz 0 %btcrefresh btcupdate btcticker_hz }
}

;on *:dialog:btcticker_hz:sclick:99:{ btcupdate btcticker_hz }
on *:dialog:btcticker_hz:close:0:{ .timerbtchz off }

on *:dialog:btcconfig:init:0:{
  did -arf btcconfig 5 %btcrefresh
  did -ai btcconfig 9 vertical
  did -ai btcconfig 9 horizontal

  if (%btcvert == 1) { did -c btcconfig 9 1 }
  else { did -c btcconfig 9 2 }
  if (%btcaot == 1) { did -c btcconfig 1 }
  if (%btcoffline == 1) { did -c btcconfig 3 }
  if (%btcdesktop == 1) { did -c btcconfig 2 }
}

on *:dialog:btcconfig:sclick:1:{
  if ($did(btcconfig,1).state == 1) { set %btcaot 1 }
  else { set %btcaot 0 }
}

on *:dialog:btcconfig:sclick:2:{
  if ($did(btcconfig,2).state == 1) { set %btcdesktop 1 }
  else { set %btcdesktop 0 }
}

on *:dialog:btcconfig:sclick:3:{
  if ($did(btcconfig,3).state == 1) { set %btcoffline 1 }
  else { set %btcoffline 0 }
}

on *:dialog:btcconfig:sclick:9:{
  if ($did(btcconfig,9) == vertical) { set %btcvert 1 }
  else { set %btcvert 0 }
}
on *:dialog:btcconfig:edit:5:{
  set %btcrefresh $did(btcconfig,5)
}

alias btcticker {
  var %params -mv
  if (%btcdesktop == 1) { %params = %params $+ d }
  if (%btcaot == 1) { %params = %params $+ o }

  if (%btcvert == 1) {
    dialog %params btcticker_vt btcticker_vt
  }
  else { dialog %params btcticker_hz btcticker_hz }
}

alias btcupdate {
  .jsonclearcache %btcurl
  var %btcbuy $json(%btcurl,buying)
  var %btcsell $json(%btcurl,selling)
  did -ar $1 2 %btcbuy
  did -ar $1 4 %btcsell
}

alias btcsettings {
  dialog -mov btcconfig btcconfig
}

;JSON implementation by Timi at http://timscripts.com/

alias json {
  if ($isid) {
    var %c = jsonidentifier,%x = 2,%str,%p,%v,%addr
    if ($isfile($1)) { %addr = $qt($replace($1,\,\\,;,\u003b,",\u0022)) }
    else { %addr = $qt($replace($1,;,\u003b,",\u0022)) }
    json.comcheck
    if (!$timer(jsonclearcache)) { .timerjsonclearcache -o 0 300 jsonclearcache }
    while (%x <= $0) {
      %p = $($+($,%x),2)
      if (%p == $null) { noop }
      elseif (%p isnum || $qt($noqt(%p)) == %p) { %str = $+(%str,[,%p,]) }
      else { %str = $+(%str,[",%p,"]) }
      inc %x
    }
    if ($prop == count) { %str = %str $+ .length }
    if ($isfile($1)) {
      if ($com(%c,eval,1,bstr,$+(str2json,$chr(40),filejson,$chr(40),%addr,$chr(41),$chr(41),%str))) { return $com(%c).result }
    }
    elseif (http://* iswm $1 || https://* iswm $1) {
      if ($com(%c,eval,1,bstr,$+(str2json,$chr(40),urlcache[,%addr,],$chr(41),%str))) { return $com(%c).result }
      elseif ($com(%c,eval,1,bstr,$+(urlcache[,%addr,]) = $+(httpjson,$chr(40),$qt($1),$chr(41)))) {
        if ($com(%c,eval,1,bstr,$+(str2json,$chr(40),urlcache[,%addr,],$chr(41),%str))) { return $com(%c).result }
      }
    }
    elseif ($com(%c,eval,1,bstr,$+(x=,%addr,;,x,%str,;))) { return $com(%c).result }
  }
}

alias jsonclearcache {
  if ($com(jsonidentifier)) {
    if (!$1) { noop $com(jsonidentifier,executestatement,1,bstr,urlcache = {}) }
    else { echo -qg $com(jsonidentifier,executestatement,1,bstr,urlcache[" $+ $1 $+ "] = "") }
  }
}

alias -l json.comcheck {
  var %c = jsonidentifier
  if (!$com(%c)) {
    .comopen %c MSScriptControl.ScriptControl
    noop $com(%c,language,4,bstr,jscript) $com(%c,addcode,1,bstr,function httpjson(url) $({,0) y=new ActiveXObject("Microsoft.XMLHTTP");y.open("GET",url,false);y.send();return y.responseText; $(},0))
    noop $com(%c,addcode,1,bstr,function filejson (file) $({,0) x = new ActiveXObject("Scripting.FileSystemObject"); txt1 = x.OpenTextFile(file,1); txt2 = txt1.ReadAll(); txt1.Close(); return txt2; $(},0))
    noop $com(%c,addcode,1,bstr,function str2json (json) $({,0) return !(/[^,:{}\[\]0-9.\-+Eaeflnr-u \n\r\t]/.test(json.replace(/"(\\.|[^"\\])*"/g, ''))) && eval('(' + json + ')'); $(},0))
    noop $com(%c,addcode,1,bstr,urlcache = {})
  }
}