# Maintainer:  txtsd <[email protected]>
# Contributor: Vitalii Kuzhdin <[email protected]>
# Contributor: Tun Win Naing <tunwn.mdy at gmail dot com>
# Contributor: Donald Webster <[email protected]>

_Name="Jackett"
_basename="${_Name,,}"
pkgname="${_basename}-mono"
pkgver=0.22.2360
pkgrel=2
pkgdesc="Use many torrent trackers with software that supports torznab/potato feeds"
arch=('any')
license=('GPL-2.0-only')
url="https://github.com/${_Name}/${_Name}"
depends=(
  'mono'
  'sh'
)
makedepends=(
  'mono-msbuild'
  'nuget'
)
optdepends=(
  'flaresolverr: proxy server to bypass Cloudflare protection'
)
provides=(
  "${_basename}"
)
conflicts=(
  "${_basename}"
)
_pkgsrc="${url##*/}-${pkgver}"
source=("${_pkgsrc}.tar.gz::${url}/archive/refs/tags/v${pkgver}.tar.gz"
        "${pkgname}.sh"
        "${_basename}.service"
        "${_basename}.sysusers"
        "${_basename}.tmpfiles")
sha256sums=('3a3865a0885eb88df93b28eb35841c5e5b49922e95e6ee84856d4d9371672824'
            '390f516cd042105881a8ca2913bc2ca55d497739faf8251fc379c698799f4dee'
            '2eac076a27789c79447b290ee904bdabe65af4617e97fd8fe4177db097e08e8e'
            'f865c06ffd21a12d37bf05953d9b483819c0f4e43d243a56db33986113fc40e4'
            '64022e15565a609f449090f02d53ee90ef95cffec52ae14f99e4e2132b6cffe1')

_srcenv() {
  export NUGET_PACKAGES="${srcdir}/.nuget"
}

prepare() {
  _srcenv

  cd "${srcdir}/${_pkgsrc}/src"
  nuget restore "DateTimeRoutines/DateTimeRoutines.csproj"
  nuget restore "${_Name}.Common/${_Name}.Common.csproj"
  nuget restore "${_Name}.Server/${_Name}.Server.csproj"
}

build() {
  _srcenv
  local msbuild_options=(
    "${_Name}.Server/${_Name}.Server.csproj"
    /p:Configuration=Release
    /p:Platform="Any CPU"
    /p:TargetFramework=net462
    /p:DebugType=None
    /p:DebugSymbols=false
    /nologo
    /verbosity:minimal
    -m
  )

  cd "${srcdir}/${_pkgsrc}/src"
  msbuild "${msbuild_options[@]}"
}

package() {
  cd "${srcdir}"
  install -vDm755 "${pkgname}.sh" "${pkgdir}/usr/bin/${_basename}"
  install -vDm644 "${_basename}.service"  "${pkgdir}/usr/lib/systemd/system/${_basename}.service"
  install -vDm644 "${_basename}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${_basename}.conf"
  install -vDm644 "${_basename}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${_basename}.conf"

  cd "${_pkgsrc}"
  install -vDm644 "README.md" "${pkgdir}/usr/share/doc/${_basename}/README.md"
  install -vDm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_basename}/LICENSE"

  cd "src/${_Name}.Server"
  install -vdm755 "${pkgdir}/usr/lib/${_basename}"
  cp -aT --no-preserve=ownership "bin/Any CPU/Release/net462" "${pkgdir}/usr/lib/${_basename}"

  rm -f "${pkgdir}/usr/lib/${_basename}"/{README.md,LICENSE}
}