DATA perm;

	* Store CRP values in ARRAYs;
     ARRAY c{*} crp1-crp16;		*Mit c{*} legt man ein Arry mit unbekannter größe an, mit crp1-crp16 werden die variablen crp1,crp2... erstellt;

	 RETAIN crp1-crp16;  *Hier werden ein paar Variablen erstellt, welche bei jedem durchlauf durch RETAIN ihren Wert behalten und dann weiter genutzt werden können;
     RETAIN i 0;
     RETAIN eof 0;
     RETAIN totsum 0;
     RETAIN npermutationen 0; *Weiss nicht wofür das ist, Variable wird nie benutzt;

	 DO UNTIL(eof);
       SET CRP END=eof;	*Mit set wird die variable gesetzt durch welche iteriert werden soll, mit end bestimmt man den letzten wert;
	   i = i + 1;	*Eine Zahl die man einfach von 0 bis x hochzählt;
	   c{i} = CRP;	*Hier wird an die i-te Position im Array der CRP Wert des aktuellen schleifendurchlaufs geschrieben;
	   totsum = totsum + CRP; *Dadurch das totsum mit RETAIN definiert wurde wird hier immer wieder der crp des durchlaufes aufaddiert;
	 END; *Das ganze ist einfach dafür die totsum zu bestimmen;

	 * The indices i1-i8 determine the CRP values for the female group. The sum of the male group is determined as TotalSum-sumF;
	 DO i1 = 1 TO 9;
	   DO i2 = i1+1 TO 10;
 	     DO i3 = i2+1 TO 11;
	       DO i4 = i3+1 TO 12;
	         DO i5 = i4+1 TO 13;
	           DO i6 = i5+1 TO 14;
	             DO i7 = i6+1 TO 15;
	               DO i8 = i7+1 TO 16; *Ist bisschen komplex, wichtig ist das das hier im Inneren zunächst ausgeführt wird mit i8 = i7+1, und dann i8 = i7+2... +16 und die schleifen sich dann erst wieder nach außen arbeiten;
                     sumF = c{i1}+ c{i2}+c{i3}+c{i4}+c{i5}+c{i6}+c{i7}+c{i8}; *Hier wird für jeden DO-Schleife jeweils der Wert aus dem Array gelesen;
                     sumM = totsum - sumF; *Totale Summe - Frauen Summe = Männer Summe;
                     d = (sumF - sumM)/8;
					 if abs(d) >= abs(&samplediff.) then indi=1; else indi=0; *Wenn Absolute Wert von d >= der Wert vom Sample dann indi = 1, sonst indi=0;
                     KEEP i1 - i8 d indi;
                     OUTPUT;
                   END;
				 END;
			   END;
			 END;
		   END;
		 END;
	   END;
     END;
RUN;