@echo off
setlocal


::Change length of password and toggle use of special characters
set pw_length=13
set complex=0
set complexchars=!#$'+-;=?@

::Change possible combinations
set pre0=mc
set pre1=mr
set pre2=sir
set pre3=the
set pre4=great
set pre5=a
set pre6=something
set pre7=mister
set pre8=ms
set pre9=dr

set middle0=flurry
set middle1=whirly
set middle2=whirl
set middle3=windy
set middle4=squall
set middle5=gust
set middle6=red
set middle7=green
set middle8=blue
set middle9=random

set end0=spoon
set end1=fork
set end2=spork
set end3=knife
set end4=name
set end5=end
set end6=dude
set end7=bro
set end8=chap
set end9=person




set "seed=%~1"
set "host=%~2"
if "%~3"=="1" set complex=1
if not defined host (
    set /p seed="seed: "
    set /p host="hostname: "
)
echo.%seed%%host%>templogingen
for /f "skip=1 delims=" %%# in ('certutil -hashfile templogingen SHA512') do set hash=%%#&goto b
:b
del templogingen
set hash=%hash: =%
set #=%hash:a=%
for %%c in (b c d e f) do call set #=%%#:%%c=%%
call set name=%%pre%#:~,1%%%%%middle%#:~1,1%%%%%end%#:~2,1%%%
call set pw=%%hash:~,%pw_length%%%
if "%complex%"=="1" call :complex
echo username: %name%@%host%
echo password: %pw%
exit /b

:complex
set #c=%#:~,1%
call set pwc=%pwc%%%complexchars:~%#c%,1%%
set #=%#:~1%
if defined # goto complex
set pw=
:p
set pw=%pw%%hash:~,2%%pwc:~,1%
set hash=%hash:~2%
set pwc=%pwc:~1%
if defined pwc if defined hash goto p
call set pw=%%pw:~,%pw_length%%%