admin-reinit.cmd

@REM admin-reinit.cmd -- perform misc clean up for new Insider builds
@REM MUST BE RUN AS ADMINISTRATOR!
@echo off
setlocal enableextensions

@REM set DEBUG=on
if "%DEBUG%" == "on" (
  echo on
  prompt $G$z
)

@echo.hide the Start menu's empty Maintenance directory
cd /d "C:\ProgramData\Microsoft\Windows\Start Menu\Programs"
attrib +h Maintenance /S /D
attrib -s "Immersive*.lnk"
attrib +s +h "Immersive*.lnk"
attrib +h "Microsoft Office Tools" /S /D
for %%f in (*) do @attrib +h "%%~f"
@REM following moves Charmap to Accessories
cd Accessories
for %%f in ("System Tools"\*) do @mklink "%%~nxf" "%%~f" /h
cd ..
attrib +h Accessories /D
attrib +h Accessibility /D

if "%DEBUG%" == "on" (pause) else (@echo.)

@echo.fix the registry
set rk=HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\UserSwitch
set aclcmd=e:\bin\setacl64.exe
set regcmd=c:\windows\system32\reg.exe
if "%DEBUG%" == "on" pause
%aclcmd% -on %rk% -ot reg -actn setowner -ownr "n:Administrators"
%aclcmd% -on %rk% -ot reg -actn ace -ace "n:SYSTEM;p:set_val;m:deny"
%regcmd%   add   %rk% /v Enabled /t REG_DWORD /d 1 /f

@REM fixing shell icons to hide compressed folder overlays which Insider builds revert
set rk=HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Shell Icons
%regcmd% add "%rk%" /v 179 /t REG_SZ /d "%Public%\Pictures\empty.ico" /f

if "%DEBUG%" == "on" (pause) else (@echo.)

@echo.disk cleanup (sadly, must be interactive)
start cleanmgr /d c

if "%DEBUG%" == "on" (pause) else (@echo.)

@echo.Final Tweaks
start "" "E:\opt\UWT4-Win10\Ultimate Windows Tweaker 4.8.exe"

@REM ALWAYS pause at end
pause