Auto Set Attributes

scn AutoSetAttributesSCRIPT

short myStrength
short myEndurance
short mySpeed
short myAgility
short myPersonality
short myIntelligence
short myWillpower
short myLuck

short averageStrength
short averageEndurance
short averageSpeed
short averageAgility
short averagePersonality
short averageIntelligence
short averageWillpower
short averageLuck

short myBlade
short myBlunt
short myHandtoHand
short myArmorer
short myBlock
short myHeavyArmor
short myAthletics
short myAcrobatics
short myLightArmor
short mySecurity
short mySneak
short myMarksman
short myMercantile
short mySpeechcraft
short myIllusion
short myAlchemy
short myConjuration
short myMysticism
short myAlteration
short myDestruction
short myRestoration

short myLevel
short myHealth
short baseHealth
short plusHealth
short minimumHealth

short runOnce

short starLady
short starSteed
short starThief
short starWarrior


BEGIN MenuMode 1
    ; Wait sewer "Tutorial Quest" to finish
    if ( GetStageDone MQ01 90 != 1 )
        return
    endif

    ; Initialize variables
    set myStrength to PlayerREF.getBaseAV Strength
    set myIntelligence to PlayerREF.getBaseAV Intelligence
    set myWillpower to PlayerREF.getBaseAV Willpower
    set myAgility to PlayerREF.getBaseAV Agility
    set mySpeed to PlayerREF.getBaseAV Speed
    set myEndurance to PlayerREF.getBaseAV Endurance
    set myPersonality to PlayerREF.getBaseAV Personality
    set myLuck to PlayerREF.getBaseAV Luck
    set myLevel to PlayerREF.getLevel

    set myBlade to PlayerREF.getBaseAV Blade
    set myBlunt to PlayerREF.getBaseAV Blunt
    set myHandtoHand to PlayerREF.getBaseAV HandtoHand
    set myArmorer to PlayerREF.getBaseAV Armorer
    set myBlock to PlayerREF.getBaseAV Block
    set myHeavyArmor to PlayerREF.getBaseAV HeavyArmor
    set myAthletics to PlayerREF.getBaseAV Athletics
    set myAcrobatics to PlayerREF.getBaseAV Acrobatics
    set myLightArmor to PlayerREF.getBaseAV LightArmor
    set mySecurity to PlayerREF.getBaseAV Security
    set mySneak to PlayerREF.getBaseAV Sneak
    set myMarksman to PlayerREF.getBaseAV Marksman
    set myMercantile to PlayerREF.getBaseAV Mercantile
    set mySpeechcraft to PlayerREF.getBaseAV Speechcraft
    set myIllusion to PlayerREF.getBaseAV Illusion
    set myAlchemy to PlayerREF.getBaseAV Alchemy
    set myConjuration to PlayerREF.getBaseAV Conjuration
    set myMysticism to PlayerREF.getBaseAV Mysticism
    set myAlteration to PlayerREF.getBaseAV Alteration
    set myDestruction to PlayerREF.getBaseAV Destruction
    set myRestoration to PlayerREF.getBaseAV Restoration

    ; Consider all values limited to 100
    ; skills
    if ( myBlade > 100 )
        set myBlade to 100
    endif
    if ( myBlunt > 100 )
        set myBlunt to 100
    endif
    if ( myHandtoHand > 100 )
        set myHandtoHand to 100
    endif
    if ( myArmorer > 100 )
        set myArmorer to 100
    endif
    if ( myBlock > 100 )
        set myBlock to 100
    endif
    if ( myHeavyArmor > 100 )
        set myHeavyArmor to 100
    endif
    if ( myAthletics > 100 )
        set myAthletics to 100
    endif
    if ( myAcrobatics > 100 )
        set myAcrobatics to 100
    endif
    if ( myLightArmor > 100 )
        set myLightArmor to 100
    endif
    if ( mySecurity > 100 )
        set mySecurity to 100
    endif
    if ( mySneak > 100 )
        set mySneak to 100
    endif
    if ( myMarksman > 100 )
        set myMarksman to 100
    endif
    if ( myMercantile > 100 )
        set myMercantile to 100
    endif
    if ( mySpeechcraft > 100 )
        set mySpeechcraft to 100
    endif
    if ( myIllusion > 100 )
        set myIllusion to 100
    endif
    if ( myAlchemy > 100 )
        set myAlchemy to 100
    endif
    if ( myConjuration > 100 )
        set myConjuration to 100
    endif
    if ( myMysticism > 100 )
        set myMysticism to 100
    endif
    if ( myAlteration > 100 )
        set myAlteration to 100
    endif
    if ( myDestruction > 100 )
        set myDestruction to 100
    endif
    if ( myRestoration > 100 )
        set myRestoration to 100
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Birth Signs
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Keep track of Birth Signs

    ; Lady: Willpower +10, Endurance +10
    if ( GetIsPlayerBirthsign BirthsignLady == 1 )
        set starLady to 1
    else
        set starLady to 0
    endif

    ; Steed: Speed +20
    if ( GetIsPlayerBirthsign BirthsignSteed == 1 )
        set starSteed to 1
    else
        set starSteed to 0
    endif
    ; Thief: Agility +10, Speed +10, Luck +10
    if ( GetIsPlayerBirthsign BirthsignThief == 1 )
        set starThief to 1
    else
        set starThief to 0
    endif
    ; Warrior: Strength +10, Endurance +10
    if ( GetIsPlayerBirthsign BirthsignWarrior == 1 )
        set starWarrior to 1
    else
        set starWarrior to 0
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Strength
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageStrength to ( ( myBlade + myBlunt + myHandtoHand ) / 3 )

    ; BirthSign
    if ( starWarrior == 1 )
        set averageStrength to ( averageStrength + 10 )
    endif

    if ( averageStrength > 100 )
        set averageStrength to 100
    endif

    ; Never reduces
    if ( averageStrength > myStrength )
        PlayerREF.SetActorValue Strength averageStrength
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Intelligence
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageIntelligence to ( ( myAlchemy + myConjuration + myMysticism ) / 3 )

    if ( averageIntelligence > 100 )
        set averageIntelligence to 100
    endif

    ; Never reduces
    if ( averageIntelligence > myIntelligence )
        PlayerREF.SetActorValue Intelligence averageIntelligence
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Willpower
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageWillpower to ( ( myAlteration + myDestruction + myRestoration ) / 3 )

    ; BirthSign
    if ( starLady == 1 )
        set averageWillpower to ( averageWillpower + 10 )
    endif

    if ( averageWillpower > 100 )
        set averageWillpower to 100
    endif

    ; Never reduces
    if ( averageWillpower > myWillpower )
        PlayerREF.SetActorValue Willpower averageWillpower
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Agility
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageAgility to ( ( mySecurity + mySneak + myMarksman ) / 3 )

    ; BirthSign
    if ( starThief == 1 )
        set averageAgility to ( averageAgility + 10 )
    endif

    if ( averageAgility > 100 )
        set averageAgility to 100
    endif

    ; Never reduces
    if ( averageAgility > myAgility )
        PlayerREF.SetActorValue Agility averageAgility
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Speed
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageSpeed to ( ( myAthletics + myAcrobatics + myLightArmor ) / 3 )

    ; BirthSign
    if ( starSteed == 1 )
        set averageSpeed to ( averageSpeed + 20 )
    endif
    if ( starThief == 1 )
        set averageSpeed to ( averageSpeed + 10 )
    endif

    if ( averageSpeed > 100 )
        set averageSpeed to 100
    endif

    ; Never reduces
    if ( averageSpeed > mySpeed )
        PlayerREF.SetActorValue Speed averageSpeed
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Endurance
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averageEndurance to ( ( myArmorer + myBlock + myHeavyArmor ) / 3 )

    ; BirthSign
    if ( starWarrior == 1 )
        set averageEndurance to ( averageEndurance + 10 )
    endif
    if ( starLady == 1 )
        set averageEndurance to ( averageEndurance + 10 )
    endif

    if ( averageEndurance > 100 )
        set averageEndurance to 100
    endif

    ; Never reduces
    if ( averageEndurance > myEndurance )
        PlayerREF.SetActorValue Endurance averageEndurance
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Personality
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; arithmetic average
    set averagePersonality to ( ( myMercantile + mySpeechcraft + myIllusion ) / 3 )

    if ( averagePersonality > 100 )
        set averagePersonality to 100
    endif

    ; Never reduces
    if ( averagePersonality > myPersonality )
        PlayerREF.SetActorValue Personality averagePersonality
    endif

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Luck
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Luck is based on Level
    set averageLuck to ( myLevel + 50 )

    ; BirthSign
    if ( starThief == 1 )
        set averageLuck to ( averageLuck + 10 )
    endif

    if ( averageLuck > 100 )
        set averageLuck to 100
    endif

    ; Never reduces
    if ( averageLuck > myLuck )
        PlayerREF.SetActorValue Luck averageLuck
    endif


    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Base Health
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; Health is based on Endurance
    set myHealth to PlayerREF.getBaseAV Health
    set baseHealth to ( myEndurance * 2 )
    set plusHealth to ( 10 * myLevel )
    set minimumHealth to ( baseHealth + plusHealth )

    ; Never reduces
    if ( minimumHealth > myHealth )
        PlayerREF.SetActorValue Health plusHealth
    endif


END