Advanced First Writes v3 By xDrugz ( Fixed )

#include < amxmodx >
#include < hamsandwich >
#include < cstrike >

new const g_CmdStart[][] = {
    "say /fw",
    "say /first",
    "say_team /fw",
    "say_team /first"
};
new const g_CmdStop[][] = {
    "say /stop",
    "say /stopfw",
    "say_team /stop",
    "say_team /stopfw"
};
new g_FWCount, g_fwActive = false, g_fwAllowMove = false, g_CountVoice[ 21 ], szWinner[ 32 ], g_MixChars[ 6 ], g_LastChars[ 6 ]
const TASKID = 2502502

public plugin_init() {
    register_plugin("Advanced FirstWrites (Fixed)", "v3", "xDrugz")

    for( new i; i < sizeof g_CmdStart; i++ )
        register_clcmd( g_CmdStart[ i ], "fnFwStart" )
    for( new i; i < sizeof g_CmdStop; i++ )
        register_clcmd( g_CmdStop[ i ], "fnFwStop" )
    register_clcmd( "say", "HandleSay" )
}

public fnFwStart( player ) {
    if ( !(get_user_flags( player ) & ADMIN_RCON) ) {
        ColorChat( player, "Only^4 Admins^1 May Use This Command !" )
        return PLUGIN_HANDLED
    }
    if( !g_fwActive ) {
        g_FWCount = 5
        ActionTimer( )
        g_fwActive = true
    }
    else {
        ColorChat(player, "^"^4First Writes^1^" Activity Already Started !" )
    }
    return PLUGIN_CONTINUE
}

public fnFwStop( player ) {
    if ( !(get_user_flags( player ) & ADMIN_RCON) ) {
        ColorChat( player, "Only^4 Admins^1 May Use This Command !" )
        return PLUGIN_HANDLED
    }
    if( g_fwActive ) {
        remove_task( TASKID )
        g_fwActive = false
        g_fwAllowMove = false
        ColorChat(0, "^"^4First Writes^1^" Activity Stopped !" )
    }
    return PLUGIN_CONTINUE
}

public HandleSay( player ) {
    new szMessage[ 32 ]
    read_args( szMessage, charsmax( szMessage ) )
    remove_quotes( szMessage )

    if ( g_fwAllowMove && get_user_team( player ) != 1 ) {
        ColorChat( player, "Only^4 Prisoners^1 May Participate !" )
        return PLUGIN_HANDLED
    }
    if( equali( szMessage, g_LastChars ) ) {
        if ( g_fwAllowMove ) {
            if ( !is_user_connected(player) || !is_user_alive(player) ) {
                ColorChat( player, "You Must Be^4 Alive^1 !" )
                return PLUGIN_HANDLED
            }
            get_user_name( player, szWinner, 31 )
            cs_set_user_team( player, CS_TEAM_CT )
            ExecuteHamB(Ham_CS_RoundRespawn, player );
            set_hudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.30, 0, 4.0, 4.0)
            show_hudmessage( 0, "%s, is the Winner !", szWinner )
            ColorChat(0, "^1%s^4 Won^1 And Moved To^4 CT Team^1 !", szWinner )
            client_cmd( player, "spk holo/tr_holo_nicejob" )
            g_fwAllowMove = false
            g_fwActive = false
        }
    }
    else {
        if ( g_fwAllowMove ) {
            client_cmd( 0, "spk scientist/completelywrong" )
        }
    }
    return PLUGIN_CONTINUE
}

public ActionTimer( ) {
    switch( g_FWCount ) {
        case 0: {
            g_fwAllowMove = true
            formatex(g_MixChars, 5, "%i", random_num(0, 99999))
            g_LastChars = g_MixChars
            set_hudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.30, 0, 4.0, 4.0)
            show_hudmessage( 0, "[ %s ]", g_LastChars )
            ColorChat(0, "Agreed Number is^4 %s^1 Hurry up !", g_LastChars)
            remove_task( TASKID )
            set_task( 15.0, "ActionFailed", TASKID )
        }
        case 1..5: {
            set_task( 1.0, "ActionTimer", TASKID )
        }
    }
    if(g_FWCount != 0) {
        num_to_word(g_FWCount, g_CountVoice, 20)
        client_cmd(0, "spk ^"vox/%s seconds^"", g_CountVoice)
        set_hudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.30, 0, 0.5, 0.5)
        show_hudmessage( 0, "Start in %d Seconds !", g_FWCount )
        --g_FWCount
    }
}

public ActionFailed( ) {
    if( g_fwAllowMove ) {
        set_hudmessage(random_num(1, 255), random_num(1, 255), random_num(1, 255), -1.0, 0.30, 0, 4.0, 4.0)
        show_hudmessage( 0, "First Writes Activity Failed !" )
        ColorChat(0, "^"^4First Writes^1^" Activity Failed !" )
        client_cmd( 0, "spk holo/tr_holo_tryagain" )
        g_fwAllowMove = false
        g_fwActive = false
    }
    else {
        remove_task( TASKID )
    }
}


stock ColorChat(index, const Msg[], {Float, Sql, Result,_}:...) {
    new Buffer[190], Buffer2[192]
    formatex(Buffer2, sizeof(Buffer2)-1, "^3[^1 JailBreak ^3]^1 %s", Msg)
    vformat(Buffer, sizeof(Buffer)-1, Buffer2, 3)
    if(!index) {
        for (new i = 1; i <= get_maxplayers(); i++) {
            if(!is_user_connected(i))   continue
            message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"),_, i)
            write_byte(i)
            write_string(Buffer)
            message_end()
        }
        } else {
        if(!is_user_connected(index))   return
        message_begin(MSG_ONE_UNRELIABLE, get_user_msgid("SayText"),_, index)
        write_byte(index)
        write_string(Buffer)
        message_end()
    }
}