ffmpeg_reduce_4k_video_file_size.bat

@ECHO OFF
SETLOCAL ENABLEEXTENSIONS
COLOR 0A
TITLE SHRINK 4K VIDEO SIZE

:-----------------------------------------------------------------------------

REM CREATED BY: SLYFOX1186
REM WEB: https://pastebin.com/u/slyfox1186

REM SHRINK THE SIZE OF 4K VIDEOS USING GEFORCE HARDWARE ACCELERATION
REM PLACE THE SCRIPT IN THE SAME FOLDER AS YOUR MP4 VIDEO

REM CHANGE SETTINGS AS NEEDED

:-----------------------------------------------------------------------------

REM CHANGE WORKING DIRECTORY TO THE SCRIPT'S DIRECTORY
PUSHD "%~dp0"
IF NOT "%1"=="MAX" START /MAX CMD /D /C %0 MAX & GOTO :EOF

:-----------------------------------------------------------------------------

REM POINT THE FF VARIABLE BELOW TO THE FULL PATH OF FFMPEG.EXE
SET "FF=E:\MAB-E\local64\bin-video\ffmpeg.exe"
SET "LIB=hevc_nvenc"
SET "PRESET=p7"

REM SET [ BITRATE ] TO HALF THE ORIGINAL VIDEO'S DATA RATE
REM [ EXAMPLE ] IF DATARATE = 30 Mbps AKA 30M, MAKE BITRATE = 15M
SET "BITRATE=15M"

REM SET [ MAX RATE ] EQUAL TO ORIGINAL VIDEO'S DATA RATE
SET "MAXRATE=30M"

REM COPY AUDIO INSTEAD OF RE-ENCODING TO SPEED UP FFMPEG
SET "AUDIO=copy"

:-----------------------------------------------------------------------------

REM DELETE ANY FOUND LEFTOVERS
FOR %%G IN (*.mp4) DO (
    IF NOT ERRORLEVEL 1 IF EXIST "%%~nG (x265).mp4" (
        DEL /Q "%%~nG (x265).mp4"
    )
)

:-----------------------------------------------------------------------------

REM RUN FFMPEG
FOR %%H IN (*.mp4) DO (
    IF NOT ERRORLEVEL 1 IF EXIST "%%H" (
        "%FF%" ^
        -y ^
        -hide_banner ^
        -hwaccel cuda ^
        -i "%%H" ^
        -c:v %LIB% ^
        -preset %PRESET% ^
        -rc cbr ^
        -b:v %BITRATE% ^
        -bufsize %BITRATE% ^
        -maxrate %MAXRATE% ^
        -qmin 0 ^
        -g 250 ^
        -rc-lookahead 20 ^
        -i_qfactor 0.75 ^
        -b_qfactor 1.1 ^
        -c:a %AUDIO% ^
        "%%~nH (x265).mp4"
    )
)

:-----------------------------------------------------------------------------

REM CHANGE CMD COLOR SCHEME TO INDICATE SCRIPT HAS FINISHED
COLOR 0E
ECHO=
PAUSE