prontera,155,171,5	script	Sample	757,{
mes "Select an headgear to trade to other colour ..";
set .@give,select( .menu$ ) - 1;

for( set .@i,0; .@i < .size[.@give]; set .@i,.@i + 1 ){
	set .@item,getd( ".headgear_"+.@give+"["+.@i+"]" );
	if( !countitem( .@item ) ){
		mes "You dont have "+getitemname( .@item );
		close;
	}
}
mes "Select exchange to which ?";
set .@gain,select( .menu$ ) - 1;
for( set .@i,0; .@i < .size[.@give]; set .@i,.@i + 1 )
	delitem getd( ".headgear_"+.@give+"["+.@i+"]" ),1;
for( set .@i,0; .@i < .size[.@gain]; set .@i,.@i + 1 )
	getitem getd( ".headgear_"+.@gain+"["+.@i+"]" ),1;
mes "Exchanged "+.headgear$[.@give]+" to "+.headgear$[.@gain];
close;

OnInit:
// headgear list
setarray .headgear$,"NAME 1","Name 2","Name 3";
setarray .headgear_0,5001,5002,5003;	// set 1
setarray .headgear_1,5004,5005,5006;	// set 2
setarray .headgear_2,5007,5008,5009;	// set 3

set .headgear_size,getarraysize( .headgear$ );
for( set .@i,0; .@i < .headgear_size; set .@i,.@i + 1 ){
	set .menu$,.menu$ + .headgear$[.@i] +":";
	set .size[.@i],getarraysize( getd( ".headgear_"+.@i ) );
}
end;
}