config_texportable_mini

:: ------SCRIPT DE CONFIG AUTO (MINI) TEX PORTABLE --------
:: v1.1     ajout des options par défaut sur les 1eres questions
:: v1.0     version initiale
:: utilisation avec miktex/texstudio/unzip/thonny/gnuplot
:: utilisation du logiciel inifile, disponible sur https://www.horstmuc.de/div.htm#inifile
:: l'executable inifile.exe est dans le repertoire logiciels ;-)
:: -------------------------------------------------

@echo off
:: on recupere la lettre du lecteur ;-)
set id=%CD:~0,1%

:: on verifie que la lettre est bonne :-)
echo La lettre du lecteur est %id%
set lettreok=o
set /p lettreok="C'est bien cela [o/n] ? "

:: si c'est pas bon, on redemande !
IF "%lettreok%"=="n" (
    set /p id="Alors quelle est la bonne lettre ? "
)

:: variables des chemins pour raccourcir un peu !!
set texstudioini=logiciels/texstudio/config/texstudio.ini
set miktexini=logiciels/miktex-portable/texmfs/config/miktex/config/miktex.ini
set miktexexe=logiciels\miktex-portable\texmfs\install\miktex\bin\x64\miktex-console.exe
set initmiktexexe=logiciels\miktex-portable\texmfs\install\miktex\bin\x64\initexmf.exe
set mpmexe=logiciels\miktex-portable\texmfs\install\miktex\bin\x64\mpm.exe

:: variables pour les fichiers ini
set diction=%id%:\\logiciels\\texstudio\\dictionaries
set pythonexe=%id%:\\logiciels\\thonny\\python.exe
set pythontex=%id%:\\logiciels\\miktex-portable\\texmfs\\install\\scripts\\pythontex\\pythontex.py
set pathgnuplot=%id%:\\logiciels\\gnuplot\\bin
set paththonny=%id%:\\logiciels\\thonny
set paththonnyscripts=%id%:\\logiciels\\thonny\\Scripts
set pathmiktex=%id%:\\logiciels\\miktex-portable\\texmfs\\install\\miktex\\bin\\x64


:: on injecte la lettre dans le PATH dans texstudio
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] "Tools\Search%%20Paths"="%pathgnuplot%;%paththonny%;%pathmiktex%;%paththonnyscripts%"
:: on modifie les exe (si jamais texstudio les change...)
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\latex="latex.exe -src synctex=0 -interaction=nonstopmode %%.tex"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\pdflatex="pdflatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\xelatex="xelatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\lualatex="lualatex.exe -synctex=0 -interaction=nonstopmode %%.tex"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\view-dvi=yap.exe %%.dvi
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\view-pdf-external=sumatra.exe %%.pdf
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\dvips=dvips.exe -o %%.ps %%.dvi
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\dvipng=dvipng.exe -T tight -D 120 %%.dvi
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\ps2pdf=ps2pdf.exe %%.ps
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\dvipdf=dvipdfmx.exe %%.dvi
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\bibtex=bibtex.exe %%
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\bibtex8=bibtex8.exe %%
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\biber=biber.exe %%
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\makeindex=makeindex.exe %%.idx
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\texindy=texindy.exe %%.idx
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\makeglossaries=makeglossaries.exe %%
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\metapost="mpost.exe -interaction=nonstopmode ?me)"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\asy=asy.exe ?m*.asy
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\gs=mgs.exe \"?am.ps\"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\latexmk="latexmk.exe -pdf -silent -synctex=1 %%"
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\texdoc="texdoc.exe "
:: on injecte la compilation pythonpdflatex
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\pythonpdflatex="txs:///pdflatex/[-draftmode] | %pythonexe% %pythontex% --rerun=always %%.tex | txs:///pdflatex | txs:///view-pdf"
:: on injecte la compilation pythonlualatex
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\pythonlualatex="txs:///lualatex/[-draftmode] | %pythonexe% %pythontex% --rerun=always %%.tex | txs:///lualatex | txs:///view-pdf"
:: on injecte la lettre pour les dictionnaires
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Spell\DictionaryDir=%diction%
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Spell\Language=fr_FR
:: on injecte sumatra
%~d0%~p0logiciels\inifile.exe %~d0%~p0%texstudioini% [texmaker] Tools\Commands\view-pdf-external=sumatra.exe %%.pdf

:: on demande si on est au boulot ou pas
set varproxy=n
set /p varproxy="Utilisation du proxy au boulot [o/n] ? "
set proxylycee=192.168.224.254
set portproxylycee=3128

:: en fonction on parametre la section du proxy :
IF "%varproxy%"=="n" (
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] ProxyHost=127.0.0.1
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] ProxyPort=8080
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] UseProxy=false
)
IF "%varproxy%"=="o" (
    set /p proxylycee="IP du proxy (%proxylycee%) ? "
    set /p portproxylycee="Port du proxy (%portproxylycee%) ? "
)
IF "%varproxy%"=="o" (
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] ProxyHost=%proxylycee%
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] ProxyPort=%portproxylycee%
    %~d0%~p0logiciels\inifile.exe %~d0%~p0%miktexini% [MPM] UseProxy=true
)

:: on lance miktex-console si besoin
set miktexlaunch=o
set /p miktexlaunch="Lancer la console MiKTeX [o/n] ? "
IF "%miktexlaunch%"=="o" (
    start "" "%~d0%~p0%miktexexe%" --mkmaps
)