Spawn a boss zombie in bo3 mod tools.

You will need a few things to get this boss zombie to spawn.
It can be an actor and you can even duplicate the zombie in ape and customize it to stand out from the rest.

first of all, we need the actor spawn name, this can be found by opening radiant and then selecting a zombie actor.
now hit "N" to open the entity editor and at the top, it says "Remap" click on the remap button and type what zombie you want to make a boss zombie.
whatever is in that box is the name we need.


First, open radiant and drop in at least 1 script struct.
Give it a target name of "boss_spawn"
That's all in radiant, you can duplicate the structs as many as you wish.

Now you will need to open your map name's GSC script file.
Usually, that's c:\SteamLibrary\steamapps\common\Call of Duty Black Ops III\usermaps\yourmapname\scripts\yourmapname.GSC.

paste the following under your last #using

#using scripts\shared\spawner_shared;


paste the following under "zm_usermap::main();"

Code:
//sg4y's boss boss zombie tutorial,
thread spawn_boss_zombie();

now paste the following to the bottom of the script.


function spawn_boss_zombie()
{

  while(1)
  {
    level waittill( "dog_round_starting" ); // this will spawn in the boss everytime the dog rounds are starting.
    //level flag::wait_till( "power_on" ); // this will spawn in the boss everytime the power goes on.
   //level waittill( "your custom notify" );    //this will spawn the boss everytime your level notify goes on.

    // you can only select 1, you can enable more flags/notifies, but i would only use 1 at a time.

    x_structs = struct::get_array( "boss_spawn", "targetname" );

    foreach( x_struct in x_structs )
     {
         x_struct thread xtra_zombie( );
         //x_struct PlaySound( "YOUR AUDIO!" );
     }
  wait .5;
  }

}


function xtra_zombie( )
{
    n_players = getplayers();//recommended by frost997
    n_players = n_players.size;
    boss_num = 0;
    health_func = 9000*level.round_number*n_players; // this is the health, it will increace by player size and round number the base health is set to 9000


    boss_zombie = SpawnActor("actor_spawner_zm_templar_boss_zombie", self.origin, self.angles, "", true, true); // change "actor_spawner_zm_templar_boss_zombie" to your actor spawner name.
    boss_zombie zm_spawner::zombie_spawn_init( undefined );
    boss_zombie._rise_spot = self;
    boss_zombie.is_boss = 1;
    boss_zombie.gibbed = 0; // change it to 1 if you don't want crawlers
    boss_zombie.health = health_func;
    boss_zombie.in_the_ground = 1;    // set it to 0 if you want him to just pop in like cod waw.
    boss_zombie.ignore_enemy_count = 1; // the round will end if you killed all regular zombies.
    boss_zombie.ignore_nuke = 1;    // the boss will be ignored to a nuke power drop.
    boss_zombie.no_powerups = 1;   // the boss zombie will drop no power drops.
    boss_zombie.no_damage_points = 1;  // players gets no damage points from the boss.
    boss_zombie.deathpoints_already_given = 1; // players will not get points for killing the boss zombie.
    boss_zombie.instakill_func = &lednors_boss_Damage;
    boss_zombie.script_string = "find_flesh"; // this means that the boss needs to be in playable area so not behind a window.
    boss_zombie zm_spawner::do_zombie_spawn();

}
function lednors_boss_Damage(player, mod, hit_location, damage)
{
  return true; //ignore insta kill
}
I added a few comments to know what it will affect and such. the code above was edited by Mr.Lednor and is working as of 17/11/22 any more issues plz let us know on discord

Keep in mind that you will need your zombie actor on your map so it will spawn the boss,
make sure to clear the script_noteworthy so it does not spawn in rounds like regular zombies.

I also made a detailed tutorial video, I definitely suggest watching the video while installing this script so
it's easier to understand what does what and where to do/change or add stuff.

https://youtu.be/xWID08-t4pM