-	script	KoE	-1,{

OnInit:
	// min gm level to control koe
	.gm_level = 90;
	// map used for koe
	.map_name$ = "guild_vs1";
	// koe max duration in minutes
	.koe_duration = 1;

	setarray .@mapflag_list,mf_nomemo,mf_noteleport,mf_nosave,mf_nobranch,mf_gvg,mf_nowarp,mf_noicewall,mf_nogo,mf_nowarpto;
	.@mapflag_list_size = getarraysize( .@mapflag_list );
	for( .@i = 0; .@i < .@mapflag_list_size; .@i++ )
		setmapflag .map_name$,.@mapflag_list[.@i];
	disablenpc "KoE#entrance";
	donpcevent "::OnRevKoE";
	end;

OnWhisperGlobal:
	if( getgmlevel() < .gm_level ) end;
	else if( compare( @whispervar0$,"on" ) ) goto L_start;
	else if( compare( @whispervar0$,"off" ) ) goto L_end;
	else if( compare( @whispervar0$,"reset" ) ) goto OnGuildBreak;
	else end;

L_start:
	if( !.koe_start ){
		announce "The King of Emperium Hill - "+.map_name$+" has begun for next "+.koe_duration+" minutes..!", 0;
		.koe_start = 1;
		$koe_guild = 0;
		enablenpc "KoE#entrance";
		donpcevent "::OnRevKoE";
		maprespawnguildid .map_name$,$koe_guild,6;
		monster .map_name$,49,49,"KOE Emperium",1001,1,strnpcinfo(0)+"::OnEmpDead";

		sleep ( .koe_duration * 60000 );

		announce "The King of Emperium Hill is over!", 0;
		.koe_start = 0;
		killmonsterall .map_name$;
		maprespawnguildid .map_name$,$koe_guild,7;

		if( $koe_guild ){
			.@size = query_sql( "SELECT `account_id`,`char_id` FROM `guild_member` WHERE `guild_id` = '"+$koe_guild+"'",.@aid,.@cid );
			for( .@i = 0; .@i < .@size; .@i++ )
				if( isloggedin( .@aid[.@i],.@cid[.@i] ) ){
					// all online member get rewards.
					getitem 512,1,.@aid[.@i];
					getitem 512,2,.@aid[.@i];
					getitem 512,3,.@aid[.@i];
				}
		}
		disablenpc "KoE#entrance";
	}
	end;

OnEmpDead:
	.@gid = getcharid(2);
	if( .@gid != $koe_guild ){
		$koe_guild = getcharid(2);
		donpcevent "::OnRevKoE";
		announce "The current King of Emperium Hill is the [ "+strcharinfo(2)+" ] guild.", 0;
		maprespawnguildid .map_name$,$koe_guild,6;
	}
	if( .koe_start ){
		sleep 2000;
		monster .map_name$,49,49,"KOE Emperium",1001,1,strnpcinfo(0)+"::OnEmpDead";
	}
	end;

L_end:
	if( .koe_start )
		awake strnpcinfo(0);
	end;

OnGuildBreak:
	$koe_guild = 0;
	donpcevent "::OnRevKoE";
	announce "KOE Ownership removed.",0;
	end;

OnWarp:
	if( !.koe_start ){
		mes "No KOE now.";
	}else if( !getcharid(2) ){
		mes "You need a aguild.";
	}else{
		setarray .@x[0],50,88,50,11;
		setarray .@y[0],88,50,11,50;
		set .@random,getarraysize(.@x);
		warp .map_name$,.@x[.@random],.@y[.@random];
		end;
	}
	close;
}


// KOE Entrance
prontera,155,181,5	script	KoE#entrance	757,{
	doevent "KoE::OnWarp";
}


// KOE Flags
-	script	koe_flag	-1,{
	if( $koe_guild ){
		mes "[King of Emperium Hill]";
		mes "The Current King of Emperium Hill is the [ ^0055FF"+ getguildname( $koe_guild ) +"^000000 ] guild.";
	}
	close;

OnRevKoE:
	if( $koe_guild )
		flagemblem $koe_guild;
	end;
}


// Duplicated Flags
guild_vs1,49,38,4	duplicate(koe_flag)	King of Emperium Hill#1	722
guild_vs1,61,49,6	duplicate(koe_flag)	King of Emperium Hill#2	722
guild_vs1,38,49,2	duplicate(koe_flag)	King of Emperium Hill#3	722
guild_vs1,49,61,0	duplicate(koe_flag)	King of Emperium Hill#4	722