Advertisement
Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- ; ====================================
- ; AUTO-EXECUTE ON LAUNCH
- ; ====================================
- ; ------------------------------------
- ; SETUP KEYBIND GROUPS
- ; #include F:\Documents\Documents\AHK-ViGEm-Bus\AHK-ViGEm-Bus.ahk
- SetTitleMatchMode, 3
- ; VN Standard Keybinds:
- ; Up Arrow: Scroll Wheel Up
- ; Down Arrow: Enter
- ; Left Arrow: Spacebar
- ; Right Arrow: Scroll Wheel Down
- ; Spacebar: Right Click
- ; Middle Click: Hide Mouse Cursor (Requires Borderless Gaming)
- GroupAdd, VNStandard, A Sky Full of Stars
- GroupAdd, VNStandard, Aokana
- GroupAdd, VNStandard, BALDR FORCE SE
- GroupAdd, VNStandard, BALDR SKY (18+ Patch)
- GroupAdd, VNStandard, 大番長 - System4.0 Ver.1.31 ; Big Bang Age
- GroupAdd, VNStandard, Bishoujo Mangekyou -Norowareshi Densetsu no Shoujo-
- GroupAdd, VNStandard, CHAOS;HEAD English RC2
- GroupAdd, VNStandard, Cartagra
- GroupAdd, VNStandard, ahk_exe cmvs64.exe ; Chrono Clock, Hapymaher
- GroupAdd, VNStandard, Da Capo 3 R
- GroupAdd, VNStandard, Daitoshokan no Hitsujikai
- GroupAdd, VNStandard, Dies irae ~Amantes amentes~
- GroupAdd, VNStandard, DRACU-RIOT!
- GroupAdd, VNStandard, euphoria
- GroupAdd, VNStandard, Evenicle
- GroupAdd, VNStandard, FATAL TWELVE
- GroupAdd, VNStandard, Funbag Fantasy
- GroupAdd, VNStandard, ahk_exe fureraba.exe ; Fureraba
- GroupAdd, VNStandard, ahk_exe SiglusEngine.exe ; Hatsukoi 1/1, HoshiOri
- GroupAdd, VNStandard, ahk_exe HGB.exe ; Hello, Goodbye
- GroupAdd, VNStandard, ISLAND
- GroupAdd, VNStandard, KARANOSHOJO
- GroupAdd, VNStandard, Kindred Spirits on the Roof
- GroupAdd, VNStandard, 恋色空模様 ; Koiiro Soramoyou
- GroupAdd, VNStandard, Magical Marriage Lunatics!!
- GroupAdd, VNStandard, Maitetsu
- GroupAdd, VNStandard, Momoiro Closet
- GroupAdd, VNStandard, ahk_exe mon_que.exe ; Monster Girl Quest! Final Chapter
- GroupAdd, VNStandard, Newton and the Apple Tree
- GroupAdd, VNStandard, レイジングループ ; Raging Loop
- GroupAdd, VNStandard, Re;Lord -The witch of Herfort and stuffed animals- Ver1.00
- GroupAdd, VNStandard, Sabbat of the Witch
- GroupAdd, VNStandard, Saku Saku: Love Blooms with the Cherry Blossoms (patch)
- GroupAdd, VNStandard, Sakura Sakura
- GroupAdd, VNStandard, Seinarukana
- GroupAdd, VNStandard, Sengoku Rance
- GroupAdd, VNStandard, Senren*Banka - A Thousand Colors Of Love -
- GroupAdd, VNStandard, Sorcery Jokers
- GroupAdd, VNStandard, Steins;Gate Linear Bounded Phenogram (English)
- GroupAdd, VNStandard, Tenioha! -Girls Can Be Pervy Too!-
- GroupAdd, VNStandard, The Ditzy Demons Are In Love With Me (18+ DLC)
- GroupAdd, VNStandard, The Fruit of Grisaia Unrated Version
- GroupAdd, VNStandard, Tokyo Babel
- GroupAdd, VNStandard, Tsujidou-san no Jun'ai Road
- GroupAdd, VNStandard, Ultimate Boob Wars!! ~Big Breasts vs Flat Chests~
- GroupAdd, VNStandard, Utawarerumono
- GroupAdd, VNStandard, VenusBlood FRONTIER International Eng Ver.
- GroupAdd, VNStandard, Wagamama High Spec
- GroupAdd, VNStandard, Wonderful Everyday
- ; Modified VN Keybinds:
- ; Use Page Up/Down as Up/Right Arrow
- GroupAdd, VNAltPgUpDown, FATAL TWELVE
- GroupAdd, VNAltPgUpDown, Sorcery Jokers
- GroupAdd, VNAltPgUpDown, Utawarerumono
- ; Use Right Click as Left Arrow
- GroupAdd, VNAltRightClick, Aokana
- GroupAdd, VNAltRightClick, BALDR SKY (18+ Patch)
- GroupAdd, VNAltRightClick, Bishoujo Mangekyou -Norowareshi Densetsu no Shoujo-
- GroupAdd, VNAltRightClick, ahk_exe cmvs64.exe ; Chrono Clock, Hapymaher
- GroupAdd, VNAltRightClick, Daitoshokan no Hitsujikai
- GroupAdd, VNAltRightClick, DRACU-RIOT!
- GroupAdd, VNAltRightClick, euphoria
- GroupAdd, VNAltRightClick, ahk_exe HGB.exe ; Hello, Goodbye
- GroupAdd, VNAltRightClick, KARANOSHOJO
- GroupAdd, VNAltRightClick, Maitetsu
- GroupAdd, VNAltRightClick, Momoiro Closet
- GroupAdd, VNAltRightClick, Sabbat of the Witch
- GroupAdd, VNAltRightClick, Saku Saku: Love Blooms with the Cherry Blossoms (patch)
- GroupAdd, VNAltRightClick, Sengoku Rance
- GroupAdd, VNAltRightClick, Senren*Banka - A Thousand Colors Of Love -
- GroupAdd, VNAltRightClick, The Ditzy Demons Are In Love With Me (18+ DLC)
- GroupAdd, VNAltRightClick, Tsujidou-san no Jun'ai Road
- GroupAdd, VNAltRightClick, Ultimate Boob Wars!! ~Big Breasts vs Flat Chests~
- GroupAdd, VNAltRightClick, Utawarerumono
- GroupAdd, VNAltRightClick, VenusBlood FRONTIER International Eng Ver.
- ; Use Shift as Left Arrow
- GroupAdd, VNAltShift, Kindred Spirits on the Roof
- GroupAdd, VNAltShift, Seinarukana
- ; Use Mid Click as Left Arrow
- GroupAdd, VNAltMidClick, Steins;Gate Linear Bounded Phenogram (English)
- ; Use Escape as Left Arrow
- GroupAdd, VNAltEscape, レイジングループ ; Raging Loop
- GroupAdd, VNAltEscape, Wonderful Everyday
- ; Use H as Left Arrow
- GroupAdd, VNAltH, FATAL TWELVE
- ; Alt-tab out and back into window before taking screenshot
- GroupAdd, VNTabOutSS, FATAL TWELVE
- ; ------------------------------------
- ; SETUP OTHER GROUPS
- GroupAdd, Desktop, ahk_class Progman
- GroupAdd, Desktop, ahk_class RDIconWnd
- GroupAdd, Desktop, ahk_class ROCKETDOCK
- GroupAdd, Desktop, ahk_class Shell_TrayWnd
- GroupAdd, Desktop, ahk_class WorkerW
- ; ------------------------------------
- ; SET GLOBAL VARIABLES
- ; Script execution variables
- EnableShellHook := false
- ; OS related variables
- OsVersion := ((r := DllCall("GetVersion") & 0xFFFF) & 0xFF) "." (r >> 8)
- OsWin7OrLower := (OsVersion <= 6.1)
- NativeResX := 2560
- NativeResY := 1440
- ; Path related variables
- PCSX2Folder = E:\Programs\Games\Emulators\PCSX2
- ScreenshotFolder = F:\Pictures\Screenshots
- ScriptsFolder = C:\Programs\Applications\Misc Scripts
- ShortcutsFolder = C:\Shortcuts
- ; Firefox related variables
- TabChangeDelay := 300
- ; ------------------------------------
- ; EXECUTE ON-LAUNCH SCRIPTS
- ; Setup hotkeys to pass alphabetic keys on desktop through to run dialog
- Alphabet = "abcdefghijklmnopqrstuvwxyz"
- Hotkey, IfWinActive, ahk_group Desktop
- Loop % StrLen(Alphabet)
- {
- c1 := SubStr(Alphabet, A_Index, 1)
- Hotkey, %c1%, RunPassthrough
- }
- ; Setup shell hook
- If (EnableShellHook) {
- Gui +LastFound
- DllCall("RegisterShellHookWindow", UInt, WinExist())
- MsgNum := DllCall("RegisterWindowMessage", Str, "SHELLHOOK")
- OnMessage(MsgNum, "ShellMessage")
- }
- ; ------------------------------------
- Return
- ; ====================================
- ; SUBROUTINE LABELS
- ; ====================================
- ; Close process on delay
- CloseOnDelay:
- WinClose ahk_exe %ToClose%
- CloseTimerActive = 0
- Return
- ; GTA V dance loop
- ; GTADance:
- ; IfWinExist, ahk_exe GTA5.exe
- ; {
- ; GTAController.SetButtonState(0,true)
- ; GTAController.SendReport()
- ; Sleep 60
- ; GTAController.SetButtonState(0,false)
- ; GTAController.SendReport()
- ; }
- ; else {
- ; MsgBox GTA 5 window not focused. Ending dance loop.
- ; GTADanceOn = 0
- ; SetTimer, GTADance, Delete
- ; }
- ; Return
- ; GTA V idle-avoiding loop
- GTAIdle:
- IfWinExist, ahk_exe GTA5.exe
- {
- SetKeyDelay, 60, 60
- IfWinExist, A
- {
- WinActivate, ahk_exe GTA5.exe
- Send, {w down}{s down}
- Sleep 100
- Send, {w up}{s up}
- WinActivate
- }
- }
- else {
- MsgBox GTA 5 window not detected. Ending anti-idle loop.
- GTAIdleOn = 0
- SetTimer, GTAIdle, Delete
- }
- Return
- ; Take screenshots with NirCMD
- NircmdSS:
- If (ScreenshotIndex < 1) {
- Loop, %ScreenshotFolder%\*
- {
- FileGetTime, Time, %A_LoopFileFullPath%, C
- If (Time > Time_Orig) {
- Time_Orig := Time
- NewIndexFile := A_LoopFileName
- }
- }
- Loop, Parse, NewIndexFile, (|)
- If (A_LoopField is integer)
- NewIndexNum := A_LoopField
- ScreenshotIndex := NewIndexNum
- MsgBox, Screenshot indexing complete. Repeat hotkey to take screenshot.
- }
- Else {
- Run nircmd savescreenshot "%ScreenshotFolder%\Screenshot (%ScreenshotIndex%).png"
- SoundPlay, *64
- }
- ScreenshotIndex++
- Return
- ; Pass alphabetic keys on desktop to run dialog (temporarily disable with Scroll Lock)
- RunPassthrough:
- If (!GetKeyState("ScrollLock", "T")) {
- SetKeyDelay, -1, 1
- Send #r
- Sleep 30
- Send %A_ThisHotkey%
- }
- Else
- Send %A_ThisHotkey%
- Return
- ; ------------------------------------
- ; ====================================
- ; FUNCTION DEFINITIONS
- ; ====================================
- ; Process messages from shell hook
- ; ShellMessage(wParam, lParam)
- ; {
- ; If (wParam = 32772 or wParam = 4) { ; HSHELL_RUDEAPPACTIVATED = 32772, HSHELL_WINDOWACTIVATED = 4
- ; WinGet, FocusedApp, ProcessName, "ahk_id %lParam%"
- ; Msgbox, Now focused: %FocusedApp%
- ; }
- ; }
- ; ------------------------------------
- ; ====================================
- ; GLOBAL HOTKEYS
- ; ====================================
- ; Volume Up/Down increment one step at a time
- ^Volume_Down::SoundSet, -1
- ^Volume_Up::SoundSet, +1
- ; Mute affects only focused window
- Volume_Mute::Run nircmd muteappvolume focused 2
- ; FeedDemon (Win+F10)
- #F10::Run "C:\Program Files (x86)\FeedDemon\FeedDemon.exe"
- ; Daemon Tools (Win+F9)
- #F9::Run "C:\Program Files\DAEMON Tools Lite\DTLite.exe"
- ; JDownloader (Win+F8)
- #F8::Run "C:\Programs\Applications\JDownloader v2.0\JDownloader2.exe"
- ; Open Window Spy (Win+F7)
- #F7::Run "C:\Program Files\AutoHotkey\AU3_Spy.exe"
- ; Edit This Script (Win+F6)
- #F6::Run "C:\Program Files (x86)\Notepad++\notepad++.exe" -openSession "F:\Documents\Documents\AutoHotkey.npp"
- ; Reload This Script (Win+F5)
- #F5::Reload
- ; Edit Firefox Start Page (Win+F4)
- #F4::Run "C:\Program Files (x86)\Notepad++\notepad++.exe" "E:\Dropbox\Program Data\Firefox Startpage\newtab.html"
- ; Run Borderless Gaming (Win+F3)
- #F3::
- DetectHiddenWindows, On
- IfWinNotExist ahk_exe BorderlessGaming.exe
- Run "C:\Program Files (x86)\Borderless Gaming\BorderlessGaming.exe"
- else
- WinActivate
- Return
- ; Show/Hide Taskbar (Win+A)
- #a::
- If (TaskbarHidden = 1) {
- WinShow, ahk_class Shell_TrayWnd
- TaskbarHidden = 0
- }
- else {
- WinHide, ahk_class Shell_TrayWnd
- TaskbarHidden = 1
- }
- Return
- ; Take screenshots in folder by app name with Win+PrtSc
- ; #PrintScreen::
- ; WinGet, TargetPath, ProcessPath, A
- ; SplitPath, TargetPath,,,, CurrentApp
- ; SSDest = %ScreenshotFolder%\%CurrentApp%
- ; If (!FileExist(SSDest))
- ; FileCreateDir %SSDest%
- ; Run nircmd savescreenshot "%SSDest%\%A_Now%.png"
- ; Return
- ; Open Shortcuts Folder (Ctrl+Win+S)
- ^#s::Run explore %ShortcutsFolder%
- ; Create Shortcut of Current Application (Win+S)
- #s::
- If (!WinActive("ahk_exe explorer.exe")) {
- WinGet, TargetPath, ProcessPath, A
- SplitPath, TargetPath,, TargetDir
- InputBox, ShortcutName, New Shortcut, A new shortcut will be created for the file:`r`r%TargetPath%`r`rwith the name:
- ShortcutName = %ShortcutName%
- If (!ErrorLevel && ShortcutName) {
- SetWorkingDir, %ShortcutsFolder%
- FileCreateShortcut, %TargetPath%, %ShortcutName%.lnk, %TargetDir%
- MsgBox Shortcut created for %ShortcutName%.
- }
- }
- else
- Send #s
- Return
- ; Reopen Logitech Gaming Software (Win+RMB)
- ; #RButton::
- ; Process, Close, LCore.exe
- ; Run "C:\Program Files\Logitech Gaming Software\LCore.exe"
- ; Return
- ; Hidden Files toggle (Win+H)
- #h::
- RegRead, HiddenFiles_Status, HKEY_CURRENT_USER, Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, Hidden
- If (HiddenFiles_Status = 2) {
- RegWrite, REG_DWORD, HKEY_CURRENT_USER, Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, Hidden, 1
- RegWrite, REG_DWORD, HKEY_CURRENT_USER, Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, ShowSuperHidden, 1
- }
- else {
- RegWrite, REG_DWORD, HKEY_CURRENT_USER, Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, Hidden, 2
- RegWrite, REG_DWORD, HKEY_CURRENT_USER, Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced, ShowSuperHidden, 0
- }
- Send {F5}
- Return
- ; Minimize Active Window (Win+N)
- #n::WinMinimize, A
- ; Copy Current Window Unique ID to Clipboard (Win+Del)
- #Del::
- WinGet, getId, ID, A
- Clipboard = %getId%
- Return
- ; Print Current Window Class and copy to Clipboard (Win+Z)
- #z::
- WinGetClass, CurrentClass, A
- MsgBox Current window is %CurrentClass%
- Clipboard = %CurrentClass%
- Return
- ; Put PC to sleep (Win+Pause)
- #Pause::DllCall("PowrProf\SetSuspendState", "int", 0, "int", 0, "int", 0)
- ; Temporarily Suspend All Hotkeys (Shift+Pause)
- +Pause::Suspend
- ; Exit AutoHotkey (Alt+Pause)
- !Pause::ExitApp
- ; Use RAlt+\ as Alt+Tab
- >!\::>!Tab
- ; Toggle screen resolution (Win+`)
- #`::
- If (A_ScreenWidth == NativeResX && A_ScreenHeight == NativeResY)
- Run "%ScriptsFolder%\LastUsedResolution.bat"
- Else
- Run nircmd setdisplay %NativeResX% %NativeResY% 32
- Return
- ; Switch monitors (Shift+Win+`)
- +#`::
- If (A_ScreenWidth == NativeResX && A_ScreenHeight == NativeResY)
- Run displayswitch.exe /external
- Else
- Run displayswitch.exe /internal
- Return
- ; Open apps from tray (Shift+Win+1-6)
- +#6::
- TrayApp++
- +#5::
- TrayApp++
- +#4::
- TrayApp++
- +#3::
- TrayApp++
- +#2::
- TrayApp++
- +#1::
- TrayApp++
- CoordMode, Mouse, Screen
- MouseGetPos, xOld, yOld
- Send #b{Right %TrayApp%}{Enter}
- MouseGetPos, xNew, yNew
- If (xOld == xNew and yOld == yNew)
- Send #b{Right %TrayApp%}{AppsKey}{Enter}{Enter}
- TrayApp := 0
- Return
- ; Refresh Focus (Win+-)
- #-::
- IfWinExist, A
- {
- WinActivate, ahk_class Shell_TrayWnd
- WinActivate
- }
- Return
- ; Close current app after delay (Ctrl+Alt+End)
- ^!End::
- If !CloseTimerActive {
- WinGet, ToClose, ProcessName, A
- InputBox, CloseDelay, Closing Program, %ToClose% will be closed after the specified delay in seconds. Repeat hotkey to cancel.
- CloseSeconds := CloseDelay * -1000
- If (!ErrorLevel && CloseSeconds) {
- SetTimer, CloseOnDelay, %CloseSeconds%
- CloseTimerActive = 1
- MsgBox Closing in %CloseDelay% seconds.
- }
- }
- Else {
- SetTimer, CloseOnDelay, Delete
- CloseTimerActive = 0
- MsgBox Cancelling close on delay for %ToClose%.
- }
- Return
- ; Remap Win+\ to Win+R (Workaround for mouse profiles)
- #\::Send #r
- ; Block Alt+Left Arrow (Workaround for UAC Macro)
- !Left::Return
- ; Launch KeePass if not already running (Ctrl+Alt+K)
- $^!k::
- DetectHiddenWindows, On
- IfWinNotExist ahk_exe KeePass.exe
- Run "C:\Program Files (x86)\KeePass Password Safe 2\KeePass.exe"
- else
- Send ^!k
- Return
- ; ------------------------------------
- ; ====================================
- ; PROGRAM-SPECIFIC HOTKEYS
- ; ====================================
- ; ------------------------------------
- ; TEMPORARY HOTKEYS
- ; Empty
- ; ------------------------------------
- ; INDIVIDUAL HOTKEYS
- ; Media Player Classic keybinds
- ; #IfWinActive ahk_class MediaPlayerClassicW
- ; RButton & Volume_Down::SoundSet, -1
- ; RButton & Volume_Up::SoundSet, +1
- ; RButton & XButton1::Send ^{PgUp}
- ; RButton & XButton2::Send ^{PgDn}
- ; RButton & WheelDown::Send {Left}
- ; RButton & WheelUp::Send {Right}
- ; RButton & MButton::Reload
- ; Firefox keybinds
- #IfWinActive ahk_exe firefox.exe
- ; Close tab with Alt+F4
- !F4::Send ^w
- ; Open tab with Win+Up
- #Up::Send ^t
- ; Reopen closed tab with Win+\ (For mouse macro)
- #\::Send +^t
- ; Refresh page with Win+- (On 4chan refresh thread/catalog)
- #-::
- SetTitleMatchMode, 2
- If (WinActive("4chan - Firefox Developer Edition"))
- Send z
- Else
- Send {F5}
- Return
- ; Open bookmarks with Win+` (or refresh watcher on 4chan)
- #`::
- SetTitleMatchMode, 2
- If (WinActive("4chan - Firefox Developer Edition"))
- Send +r
- Else
- Send ^b
- Return
- ; Left before enter on .exe dialogs
- !Left::
- SetTitleMatchMode, RegEx
- If (WinActive("Opening .*\.exe"))
- Send {Left}
- Return
- ; Fix for accidental tab change after closing/opening tab on mouse
- ^Tab::
- +^Tab::
- If (A_TimeSincePriorHotkey > TabChangeDelay or A_PriorHotkey == "^Tab" or A_PriorHotkey == "+^Tab" or A_TimeSincePriorHotkey == -1)
- If (A_ThisHotkey == "^Tab")
- Send ^{Tab}
- Else
- Send +^{Tab}
- Return
- ; File explorer keybinds
- #IfWinActive ahk_class CabinetWClass
- ; Open file location (Win+V)
- #v::Send {AppsKey}i
- ; Extract File/Folder to Temp folder (Win+E)
- #e::
- ClipBuffer := Clipboard
- Send ^c
- If (FileExist(Clipboard)) {
- SplitPath, Clipboard,,,, ArchName, ArchDrive
- ExtractPath = %ArchDrive%\Temp\%ArchName%\
- Run %ComSpec% /c "7z x "%Clipboard%" -o"%ExtractPath%" & pause & explorer "%ExtractPath%""
- }
- Clipboard := ClipBuffer
- Return
- ; Thunderbird keybinds
- #IfWinActive ahk_exe thunderbird.exe
- ; Navigate unread messages with mouse back/forward buttons
- XButton2::n
- XButton1::[
- ; Bluestacks keybinds
- #IfWinActive ahk_exe BlueStacks.exe
- ; Send security password
- :*:@s::
- If (!BSPassword) {
- InputBox, BSPassword, Enter Password, ROM Security Password not yet entered. Please enter password:
- }
- Else {
- SendInput %BSPassword%
- }
- Return
- ; PCSX2 keybinds
- #IfWinActive ahk_exe pcsx2.exe
- ; Toggle PCSX2 graphic settings then trigger GSdx refresh (Mouse back button)
- XButton1::
- SetWorkingDir, %PCSX2Folder%\inis
- If FileExist("GSdx_2.ini") {
- FileMove, GSdx.ini, GSdx_1.ini
- FileMove, GSdx_2.ini, GSdx.ini
- }
- Else If FileExist("GSdx_1.ini") {
- FileMove, GSdx.ini, GSdx_2.ini
- FileMove, GSdx_1.ini, GSdx.ini
- }
- SetKeyDelay, 200, 20
- Send {F9}{F9}
- Return
- ; Refresh GSdx on bottom right mouse button
- MButton::
- SetKeyDelay, 200, 20
- Send {F9}{F9}
- Return
- ; GTA V keybinds
- #IfWinActive ahk_exe GTA5.exe
- ; Connection switches
- ScrollLock::
- Run "%ScriptsFolder%\GTA V\Toggle GTAV Solo.lnk"
- SoundPlay *64
- Return
- End::
- Run "%ScriptsFolder%\GTA V\GTAV Emergency DC.lnk"
- SoundPlay *16
- Return
- ; Dance loop (ctrl+shift+D)
- ; +^d::
- ; If GTADanceOn {
- ; GTADanceOn = 0
- ; SetTimer, GTADance, Delete
- ; MsgBox Disabling dance loop.
- ; }
- ; else {
- ; MsgBox Enabling dance loop.
- ; If (!GTAController)
- ; GTAController := new ViGEmXb360()
- ; GTADanceOn = 1
- ; SetTimer, GTADance, 476
- ; }
- ;Return
- ; Idle avoiding loop (ctrl+shift+I)
- +^i::
- If GTAIdleOn {
- MsgBox Disabling anti-idle loop.
- GTAIdleOn = 0
- SetTimer, GTAIdle, Delete
- }
- else {
- MsgBox Enabling anti-idle loop.
- GTAIdleOn = 1
- SetTimer, GTAIdle, 420000
- }
- Return
- ; Toggle expanded radar (shift+Z)
- +z::
- SetKeyDelay, 100, 60
- Send {Esc}
- Sleep 100
- Send {Right 4}
- Sleep 300
- Send {Enter}
- Sleep 300
- Send {Down 5}{Enter}
- Sleep 100
- Send {Down 5}{Enter}
- Sleep 100
- Send {Backspace 3}
- Return
- ; Launch Chopper Tail (ctrl+shift+C)
- +^c::
- SetKeyDelay, 100, 60
- Send {Esc}
- Sleep 100
- Send {Right}
- Sleep 300
- Send {Enter}
- Sleep 300
- Send {Enter}
- Sleep 100
- Send {Down}{Enter}
- Sleep 100
- Send {Up 2}{Enter}
- Sleep 100
- Send {Up 5}{Enter}
- Sleep 200
- Send {Down 15}{Enter}{Enter}
- Return
- ; Disable Windows key (seems to get glitched when alt-tabbing in/out frequently)
- LWin::
- RWin::
- Return
- ; Bob up/down (Alt+C then hold C)
- !c::
- While (GetKeyState("c","P"))
- {
- Send {Ctrl Down}
- Sleep 600
- Send {Ctrl Up}
- Send {Shift Down}
- Sleep 550
- Send {Shift Up}
- }
- ; Tab advances to next word in inline autocomplete (Run dialog)
- #IfWinActive Run ahk_class #32770 ahk_exe explorer.exe
- Tab::
- ClipBuffer := Clipboard
- Send ^c
- NextWord := InStr(Clipboard, " ")
- Clipboard := SubStr(Clipboard, 1, NextWord ? NextWord - 1 : StrLen(Clipboard))
- Send ^v{Space}
- Clipboard := ClipBuffer
- Return
- ; qBittorrent keybinds
- #IfWinActive ahk_class Qt5QWindowIcon
- ; Save to last used location
- Home UP::Send {Tab 4}{Up 6}
- ; Allow Alt+Left to accept dialogs
- !Left::Send {Left}
- ; ------------------------------------
- ; HOTKEY GROUPS
- ; VN Alternate Keybinds
- #IfWinActive ahk_group VNAltPgUpDown
- Up::PgUp
- Right::PgDn
- #IfWinActive ahk_group VNAltRightClick
- Left::RButton
- Space::Space
- #IfWinActive ahk_group VNAltShift
- Left::Shift
- Space::Space
- #IfWinActive ahk_group VNAltMidClick
- Left::MButton
- Space::Space
- #IfWinActive ahk_group VNAltEscape
- Left::Esc
- Space::Space
- #IfWinActive ahk_group VNAltH
- Left::h
- Space::Space
- #IfWinActive ahk_group VNTabOutSS
- #PrintScreen::
- SetKeyDelay, 100, 60
- Send !{Tab}!{Tab}#{PrintScreen}
- Return
- ; VN Standard Keybinds
- #IfWinActive ahk_group VNStandard
- Up::Send {WheelUp}
- Down::Enter
- Left::Space
- Right::Send {WheelDown}
- Space::RButton
- MButton::
- Send #{ScrollLock}
- Send {ScrollLock}
- Return
- ; ------------------------------------
- ; ====================================
- ; OS-SPECIFIC HOTKEYS
- ; ====================================
- ; ------------------------------------
- ; WINDOWS 7 OR OLDER
- #If %OsWin7OrLower%
- ; Take screenshots with nircmd (Win+Print Screen)
- #PrintScreen::Gosub NircmdSS
- ; ------------------------------------
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement