Rolling a Globe

map = Graphics[{RGBColor[0, 0.8, 0.2],
   ({ColorData["ArmyColors"][Random[]],
       CountryData[#, "SchematicPolygon"]} &) /@ CountryData[],
   Darker@Red,
   Table[Line[{{-180, i}, {180, i}}], {i, -90, 90, 10}],
   Table[Line[{{i, -90}, {i, 90}}], {i, -180, 180, 20}]

   }, Background -> RGBColor[0.2, 0.5, 0.8], ImageSize -> 500,
  PlotRange -> {{-180, 180}, {-70, 90}}];
rollmap =
  ImageTransformation[
   map, {ArcTan[-#[[2]], #[[1]]], Mod[-Norm[#], Pi]} &,
   DataRange -> {{-Pi, Pi}, {0, Pi}},
   PlotRange -> 2 Pi {{-1, 1}, {-1, 1}}];
globe = ParametricPlot3D[{Cos[ \[Phi]] Sin[\[Theta]],
    Sin[\[Phi]] Sin[\[Theta]], Cos[\[Theta]]}/(2 Pi), {\[Phi], 0,
   2 \[Pi]}, {\[Theta], 0, \[Pi]}, Mesh -> None,
  PlotStyle -> Texture[map],
  TextureCoordinateFunction -> ({#4 + 3 Pi/2, #3 } &),
  Lighting -> "Neutral", Axes -> False, RotationAction -> "Clip"];
Show[Graphics3D[{Texture[rollmap],
   Polygon[{{-1, -1, 1/(2 Pi)}, {1, -1, 1/(2 Pi)}, {1, 1,
      1/(2 Pi)}, {-1, 1, 1/(2 Pi)}
     }, VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}, {0,
       1}}]}, Lighting -> "Neutral", Boxed -> False,
  ViewPoint -> {-10, -10, -5},
  PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}/(2 Pi)}, ImageSize -> 1000],
 globe]