;=======================================================================
;skaner_itemow (c) by evantis
;version 1.02
;makro skanujace itemy noszone przez osobe bedaca ostatnim celem
;wyswietla nazwy zalozonych przedmiotow (np. umow) widoczne w paperdollu
;wymaga wskazania osoby przez TargetNext lub jakims targetterem
;(wazne zeby pod spodem postaci byl pasek z hp)
;rzeczy przed kreska mozna ustawic samemu, pod spodem lepiej nie ruszac
;=======================================================================

set %klawisz 4 ;tutaj wpisac klawisz pod ktory przypisuje sie makro
set %drugiKlawisz ctrl ;drugi klawisz, mozna zostawic puste
;tzn. samo set %drugiKlawisz albo set %drugiKlawisz CTRL/ALT/SHIFT
set %coSzukac umiejetn  ;tutaj wpisac slowo ktore ma zawierac przedmiot
;--------------------------------------------

set %n 0
set %null

while ( #true )
{
 onHotkey %klawisz %drugiKlawisz
 gosub sprawdz
}

sub sprawdz
  if ( #ltargetid = #charid )
  {
   event sysmessage Lepiej nie, zamkniesz swoj paperdoll!
   wait 1s
   return
  }
  gosub otworzPaperdoll
  finditem * C_ , #ltargetid
  ;gosub zamknijPaperdoll
  if ( #findcnt > 0 )
  {
    for #findindex 1 #findcnt
    {
     event property #findid
     repeat
     until ( #property <> %null )
     if ( %coSzukac in #property )
     {
      set %finditem . %n #property
      set %n %n + 1
      str len #property
      set %wytnijKoniec #strres - 1
	    str left #property %wytnijKoniec
	    set %staryKolorTekstu #sysmsgcol
	    set #sysmsgcol 4000
      event sysmessage %n , : , #spc , #strres
	    set #sysmsgcol %staryKolorTekstu
      wait 10
     }
    }
    if %n = 0
     event sysmessage Brak przedmiotow zawierajacych ' , %coSzukac , '.
  }
  else
   event sysmessage Brak przedmiotow zawierajacych ' , %coSzukac , '.
  set %n 0
return

sub otworzPaperdoll
  set #lobjectid #ltargetid
  event macro 17
  wait 10
return

sub zamknijPaperdoll
  if ( #contname = paperdoll_gump )
  {
   set %clickX #contposx + 100
   set %clickY #contposy + 100
   click %clickX %clickY dmc r
  }
return