backupper_savekey

@echo off

if "%PROCESSOR_ARCHITECTURE%" neq "AMD64" (
  echo Dieses Script funktioniert z.Zt. nur auf einem 64-bit Betriebssystem.
  echo Anpassung der Pfade notwendig!
  echo.
  pause
  exit /b
)

reg query "HKU\S-1-5-19" >nul 2>&1 || (
  echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
  echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
  "%temp%\getadmin.vbs"
  del "%temp%\getadmin.vbs" >nul 2>&1
  exit /b
)

set regkey=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion
set regvalue=ProgramData
set regfile=backupper_reg.reg
set regfile2=backupper_regfile.bin
set restore=backupper_restore.bat

reg query %regkey% /v %regvalue% | findstr /i "%regvalue%" >"%~dp0%regfile%"
set /p tmp=<"%~dp0%regfile%"
set tmp=%tmp:~33%
set reghex=

:loop
set reghex=%reghex%%tmp:~0,2%,
set tmp=%tmp:~2%
if "%tmp%" neq "" goto loop

echo Windows Registry Editor Version 5.00>"%~dp0%regfile%"
echo.>>"%~dp0%regfile%"
echo [%regkey%]>>"%~dp0%regfile%"
echo "%regvalue%"=hex:%reghex:~0,-1%>>"%~dp0%regfile%"

copy C:\Windows\SysWOW64\winsevr.dat "%~dp0%regfile2%" /y >nul 2>&1

echo @echo off>"%~dp0%restore%"
echo.>>"%~dp0%restore%"
echo reg query "HKU\S-1-5-19" ^>nul 2^>^&1 ^|^| ( >>"%~dp0%restore%"
echo   echo Set UAC = CreateObject^^("Shell.Application"^^) ^> "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   echo UAC.ShellExecute "%%~s0", "", "", "runas", 1 ^>^> "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   "%%temp%%\getadmin.vbs" >>"%~dp0%restore%"
echo   del "%%temp%%\getadmin.vbs" ^>nul 2^>^&1 >>"%~dp0%restore%"
echo   exit /b >>"%~dp0%restore%"
echo ) >>"%~dp0%restore%"
echo. >>"%~dp0%restore%"
echo reg import "%%~dp0%regfile%" >>"%~dp0%restore%"
echo copy "%%~dp0%regfile2%" "C:\Windows\SysWOW64\winsevr.dat" >>"%~dp0%restore%"
echo copy "%%~dp0%regfile2%" "C:\Program Files (x86)\AOMEI Backupper\AmCore.dll" >>"%~dp0%restore%"