Algoritmo Calculo Salário

/*
 * Escreva um algoritmo que receba o valor do salário mínimo, o número de horas
trabalhadas, o número de dependentes do funcionário e a quantidade de horas extras
trabalhadas. Calcule e mostre o salário do funcionário de acordo com as regras a seguir:

- o valor da hora trabalhada é igual a 1/5 do salário mínimo;

- o salário do mês é igual ao número de horas trabalhadas multiplicado pelo valor da
hora trabalhada;

- para cada dependente acrescentar R$ 32,00;

- para cada hora extra trabalhada, calcular o valor da hora trabalhada acrescida de 50%;

- o salário bruto é igual ao salário do mês mais o valor dos dependentes mais o valor
das horas extras;

- calcular o valor do imposto de renda retido na fonte de acordo com a tabela a seguir:

IRRF   Salário bruto

Isento   Inferior a R$ 200,00

10%   De R$ 200,00 até R$ 500,00

20%   Superior a R$ 500,00

- o salário líquido é igual ao salário bruto menos IRRF;

- a gratificação segue a tabela a seguir:

Salário Líquido   Gratificação

Até R$ 350,00   R$ 100,00

Superior a R$ 350,00  R$ 50,00

- o salário do funcionário é igual ao salário líquido mais gratificação.
*/
programa
{

	funcao inicio()
	{
		real valorSalarioMinimo, numeroHorasTrabalhadas, numeroHorasExtras, valorHora, salarioMes, valorDependentes, valorHorasExtras, salarioBruto, impostoRenda, salarioLiquido, gratificacao, salarioFinal
		inteiro dependentes
	// leitura das informações
		escreva ("Informe o valor do salário mínimo: ")
		leia (valorSalarioMinimo)
		escreva ("Informe o número de horas trabalhadas: ")
		leia (numeroHorasTrabalhadas)
		escreva ("Informe a quantidade de horas extras trabalhadas: ")
		leia (numeroHorasExtras)
		escreva ("Informe o número de dependentes: ")
		leia (dependentes)

	// - o valor da hora trabalhada é igual a 1/5 do salário mínimo;
		valorHora = valorSalarioMinimo/5
		escreva ("Valor hora: " + valorHora + "\n")
	//- o salário do mês é igual ao número de horas trabalhadas multiplicado pelo valor da hora trabalhada;
		salarioMes = numeroHorasTrabalhadas*valorHora
		escreva ("Salario mês: " + salarioMes+ "\n")
	// - para cada dependente acrescentar R$ 32,00;
		valorDependentes = dependentes * 32.00
		escreva ("Valor dependentes: " + valorDependentes+ "\n")
	// - para cada hora extra trabalhada, calcular o valor da hora trabalhada acrescida de 50%;
		valorHorasExtras = numeroHorasExtras * (valorHora + (valorHora*50/100))
		escreva ("Valor horas extras: " + valorHorasExtras+ "\n")
	// o salário bruto é igual ao salário do mês mais o valor dos dependentes mais o valor das horas extras;
		salarioBruto = salarioMes + valorDependentes + valorHorasExtras
		escreva ("Salario Bruto: " + salarioBruto+ "\n")
	// - calcular o valor do imposto de renda retido na fonte
	impostoRenda=0.0
	se (salarioBruto < 200.00) {
		impostoRenda = 0.0

	}
	se (salarioBruto >= 200.00 e salarioBruto <= 500.00) {
		impostoRenda = (salarioBruto * (10.00/100))

	}
	se (salarioBruto > 500.00) {
		impostoRenda = (salarioBruto * (20.00/100))

	}
	escreva ("Imposto de renda: " + impostoRenda+ "\n")
	// - o salário líquido é igual ao salário bruto menos IRRF;
		salarioLiquido = salarioBruto - impostoRenda
	escreva ("Salário Liquido: " + salarioLiquido+ "\n")
	// a gratificação segue a tabela a seguir:
	se (salarioLiquido <= 350.00 ){
		gratificacao = 100.00
	}
	senao {
		gratificacao = 50.00
	}
	escreva ("Gratificação: " + gratificacao+ "\n")
	// - o salário do funcionário é igual ao salário líquido mais gratificação.
	salarioFinal = salarioLiquido + gratificacao
	//informar o salario final
	escreva ("Salário final é de: "+ salarioFinal)


	}
}