@echo OFF

:FULLPATH
set /P "FOLDER=type the full folder address: "

REM auto remove all quotes
set FOLDER=%FOLDER:"=%
set FOLDER=%FOLDER:'=%
set FOLDER=%FOLDER:`=%

if NOT EXIST "%FOLDER%" (
    echo. && echo ["%FOLDER%"] was not found!
    echo. && echo pls, type again!
    TIMEOUT /NOBREAK /T 4
    cls
    goto :FULLPATH
) ELSE (
    echo. && echo folder found: ["%FOLDER%"] && echo.
)

REM it will rename all files: *.*
echo generating the renaming script: "02-check-first-renamer.cmd" [pls, wait]
echo @echo ON > 02-check-first-renamer.cmd
for /R "%FOLDER%" %%F IN (*.*) DO (
    call :OUTOFTHELOOP "%%F"
)
echo timeout /NOBREAK /T 8 >> 02-check-first-renamer.cmd
echo exit /B >> 02-check-first-renamer.cmd
echo.
echo done! && echo. && echo read the file "02-check-first-renamer.cmd" _o/
echo.

goto END

:OUTOFTHELOOP
echo file found: %1
REM you can try to change the "hasher-engine" file
for /F "usebackq delims==" %%C IN (`01-hasher-engine.cmd %1`) DO (
    echo move /Y %1 "%~d1%~p1%~n1 [%%C]%~x1" >> 02-check-first-renamer.cmd
)
goto :EOF

:END
timeout /NOBREAK /T 32
exit /B

REM file: 00-rename-hasher.cmd