# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
# Maintainer: Caleb Maclennan <[email protected]>
# Contributor: schuay <[email protected]>
# Contributor: Roman Zimbelmann <[email protected]>

pkgname=ranger-git
pkgver=1.9.3.730.gbd9b37fa
pkgrel=2
pkgdesc='Simple, vim-like file manager'
arch=('any')
url='https://ranger.github.io'
license=('GPL')
depends=('python')
optdepends=(
    'atool: for previews of archives'
    'elinks: for previews of html pages'
    'ffmpegthumbnailer: for video previews'
    'highlight: for syntax highlighting of code'
    'imagemagick: auto-rotate image previews based on EXIF data'
    'libcaca: for ASCII-art image previews'
    'lynx: for previews of html pages'
    'mediainfo: for viewing information about media files'
    'odt2txt: for OpenDocument texts'
    'perl-image-exiftool: for viewing information about media files'
    'poppler: for pdf previews'
    'python-chardet: in case of encoding detection problems'
    'python-pillow: for in-terminal preview of images in Kitty'
    'sudo: to use the "run as root"-feature'
    'transmission-cli: for viewing bittorrent information'
    'ueberzug: for previews of images'
    'w3m: for previews of images and html pages')
checkdepends=('python-pytest')
makedepends=(python-{build,installer,wheel}
             python-setuptools
             python-pylint
             git)
conflicts=('ranger')
#source=(https://ranger.github.io/${pkgname}-${pkgver}.tar.gz{,.sig})
source=("$pkgname::git+https://github.com/ranger/ranger")
#sha512sums=('18cd1d66838a5f85176e6b7502521a7e449aaa0b12e97d62142d39f980c529c5b97a50f6fb8a65adb64612fa80450b1e13047327f7bcc005a494af4ab321e4d4'
#            'SKIP')
#validpgpkeys=('1E9B36EC051FF6F7FFC969A7F08CE1E200FB5CDF' # Roman Zimbelmann <[email protected]> (@hut)
#              '30193C49CB39CD27008246ADE5902A52B247B8DE' # Wojciech Siewierski <[email protected]>
#              '66FA95C0F1619BDA520A41F60D63346A5D15D055') # Toon Nolten <[email protected]> (@huterich)
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --always | sed -e 's|-|.|g' -e '1s|^.||'
}

prepare() {
#  cd "${pkgname}-${pkgver}"
  cd "$srcdir/$pkgname"
  # fixes https://github.com/ranger/ranger/issues/1853
  # upsteam fix was never released:
  # https://github.com/ranger/ranger/commit/2241cac899536a94c032a58bb7f1bf921980687e
  sed -i 's/xdg-open -- /xdg-open /' "ranger/config/rifle.conf"
}

build() {
#  cd ${pkgname}-${pkgver}
  cd "$srcdir/$pkgname"
  python -m build -wn
}

check() {
#  cd ${pkgname}-${pkgver}
  cd "$srcdir/$pkgname"
  local _pyver=$(python -c 'import sys; print("".join(map(str, sys.version_info[:2])))')
  export PYTHONPATH="$PWD/lib.linux-$CARCH-cpython-$_pyver"
  export TERM=linux
  pytest
}

package() {
#  cd ${pkgname}-${pkgver}
  cd "$srcdir/$pkgname"
  python -m installer -d "$pkgdir" dist/*.whl
}

# vim: ts=2 sw=2 et: