pkgname=cp2k
pkgver=6.1
pkgrel=6
_arch=Linux-x86-64-arch
_version=psmp
pkgdesc="A quantum chemistry and solid state physics software package"
arch=('x86_64')
url="www.cp2k.org"
license=('GPL2')
depends=('blas' 'lapack')
makedepends=('gcc-fortran' 'python' 'git')
optdepends=('libint>=1.1.4' 'fftw' 'scalapack'  'openmpi' 'libxc>=4.0.4' 'libxsmm' 'spglib' 'libgrid' 'cuda' 'elpa<=2017.05.003')
conflicts=("$pkgname-bin" "$pkgname-git")
source=("git+https://github.com/cp2k/cp2k.git#branch=support/v$pkgver"
        $_arch.$_version)
sha256sums=('SKIP'
            'SKIP')

prepare() {
  #module load cuda
  cd $srcdir/$pkgname
  sed -i 's/$(CP2KHOME)\/data/\/usr\/share\/cp2k\/data/g' makefiles/Makefile
  mv ../$_arch.$_version arch
  sed -i 's/P100/K20X/g' src/dbcsr/libsmm_acc/libcusmm/generate.py
  sed -i 's/largeDB(/largeDB1(/g' src/dbcsr/libsmm_acc/libcusmm/parameters_K20X.txt
  sed -i 's/triples += combinations(6,7,8)/#triples += combinations(6,7,8)/g' src/dbcsr/libsmm_acc/libcusmm/generate.py
  sed -i 's/triples += combinations(13,14,25,26,32)/#triples += combinations(13,14,25,26,32)/g' src/dbcsr/libsmm_acc/libcusmm/generate.py
}

build() {
  cd $srcdir/$pkgname/makefiles
  make ARCH=$_arch VERSION=$_version
}

check() {
  cd $srcdir/$pkgname/tools/regtesting
  ./do_regtest -cp2kdir ../.. -nosvn -version $_version -arch $_arch -nobuild
}

package() {
  install -dm755 $pkgdir/usr/{bin,share/$pkgname}
  install -m755 $srcdir/$pkgname/exe/$_arch/cp2k.$_version $pkgdir/usr/bin/cp2k
  install -m755 $srcdir/$pkgname/exe/$_arch/cp2k_shell.$_version $pkgdir/usr/bin/cp2k_shell
  install -m755 $srcdir/$pkgname/exe/$_arch/graph.$_version $pkgdir/usr/bin/cp2k_graph
  rsync -r $srcdir/$pkgname/data $pkgdir/usr/share/$pkgname
}