smooth-and-polished.zs

import crafttweaker.item.IItemStack;


var twoByTwo as IItemStack [IItemStack] =
{
  <quark:limestone:1> : <quark:limestone>,
  <quark:slate:1> : <quark:slate>,
  <quark:basalt:1> : <quark:basalt>,
  <quark:polished_netherrack> : <minecraft:netherrack>,
  <quark:marble:1> : <quark:marble>,
  <minecraft:stone:4> : <minecraft:stone:3>,
  <quark:soul_sandstone:2> : <quark:sandstone_new:4>,
  <minecraft:sandstone:2> : <quark:sandstone_new>,
  /* <additionalenderblocks:smooth_end_stone> : <minecraft:end_stone>, */
  <minecraft:stone:6> : <minecraft:stone:5>,
  <minecraft:red_sandstone:2> : <quark:sandstone_new:2>,
  <minecraft:stone:2> : <minecraft:stone:1>,
  <twilightforest:maze_stone:2> : <twilightforest:maze_stone>,
  <quark:jasper:1> : <quark:jasper>,
};

var twoByTwoRemove as IItemStack [IItemStack] =
{
  <quark:soul_sandstone:2> : <quark:soul_sandstone>,
  <minecraft:sandstone:2> : <minecraft:sandstone>,
  <minecraft:red_sandstone:2> : <minecraft:red_sandstone>,
  <twilightforest:maze_stone:2> : <twilightforest:maze_stone>
};

var oShape as IItemStack [IItemStack] =
{
  <quark:sandstone_new:4> : <quark:soul_sandstone>,
  <quark:sandstone_new> : <minecraft:sandstone>,
  <quark:sandstone_new:2> : <minecraft:red_sandstone>
};

for output, input in twoByTwo
{
  recipes.removeShaped(output * 4, [[input, input], [input, input]]);
  furnace.addRecipe(output, input, 0.5);
}

for output, input in twoByTwoRemove
{
  recipes.removeShaped(output * 4, [[input, input], [input, input]]);
}

for output, input in oShape
{
  recipes.removeShaped(output * 8, [[input, input, input], [input, null, input], [input, input, input]]);
  furnace.addRecipe(output, input, 0.5);
}

furnace.remove(<minecraft:netherbrick>);
furnace.addRecipe(<minecraft:netherbrick>, <vbe:slabnetherrack>, 0.5);