Combobind - 29/9/2018

///////////////////////////////////////////////////////////////////////////////
//  Combobind / Master Scroll Controller                                     //
///////////////////////////////////////////////////////////////////////////////

msc_multiplier = 8

msc_delta = [
    cond $editing [
        if $.followplayer [ follownext $arg1 ] [
            cond [&& $enthavesel [||iskeyheld "1" "2" "3" "4" "5"]] [
                loop i 5 [ if (iskeyheld (+ $i 1)) [ entattrdelta $i $arg1 ] ]
            ] [iskeyheld "G"] [                                                       // Change grid power
                gridpower (max 0 (min 12 (+ $arg1 $gridpower) (- $mapscale 1)))
            ] [iskeyheld "R"] [                                                       // Selection rotate / blend brush rotate
                if $blendpaintmode [ rotateblendbrush $arg1 ] [ editrotate $arg1 ]
            ] [iskeyheld "Q"] [                                                       // Push corner closest to the cursor
                editfacewsel $arg1 2
            ] [iskeyheld "F"] [                                                       // Push selected face/corners
                editfacewsel $arg1 0
            ] [iskeyheld "Y"] [                                                       // Change MRU textures
                edittex $arg1
            ] [iskeyheld "Z"] [                                                       // Change floatspeed
                floatspeed (clamp (+ $floatspeed (* 50 $arg1)) 50 5000)
            ] [&& $hmapedit [iskeyheld "H"]] [                                        // Change heightmap brush
                selecthbrush $arg1
            ] $blendpaintmode [                                                       // Change blendmap mode / blend brush
                if (iskeyheld "B") [
                    arg1 = (+ $blendpaintmode $arg1)
                    cond [< $arg1 1] [ blendpaintmode = 5 ] [> $arg1 5] [ blendpaintmode = 1 ] [ blendpaintmode $arg1 ]
                ] [ nextblendbrush $arg1 ]
            ] [ editfacewsel $arg1 1 ]
        ]
    ] $mainmenu [
        // NOTHING HERE YET
    ] [isspectator $getclientnum] [
        if $thirdperson [
            loop i 10 [ sleep (* $i 10) [
                thirdpersondistance (clampf (+f $thirdpersondistance (*f $arg1 0.25)) 10 50)
            ] ]
        ] [ nextfollow $arg1 ]
    ] [ nextweapon $arg1 ]
]



defnormkey = [
    [:def.norm:@arg1] = $arg2
    [:cus.norm:@arg1] = []
    bind $arg1 [ keyswitch @arg1 [:def.norm:@@arg1] [:cus.norm:@@arg1] ]
    defsvarp [:desc.def.norm:@arg1] $arg3
]

defeditkey = [
    [:def.edit:@arg1] = $arg2
    [:cus.edit:@arg1] = []
    editbind $arg1 [ keyswitch @arg1 [:def.edit:@@arg1] [:cus.edit:@@arg1] ]
    defsvarp [:desc.def.edit:@arg1] $arg3
]

defspeckey = [
    [:def.spec:@arg1] = $arg2
    [:cus.spec:@arg1] = []
    specbind $arg1 [ keyswitch @arg1 [:def.spec:@@arg1] [:cus.spec:@@arg1] ]
    defsvarp [:desc.def.spec:@arg1] $arg3
]

normkey = [ [:cus.norm:@arg1] = $arg2 ; [:desc.cus.norm:@arg1] = $arg3 ]
editkey = [ [:cus.edit:@arg1] = $arg2 ; [:desc.cus.edit:@arg1] = $arg3 ]
speckey = [ [:cus.spec:@arg1] = $arg2 ; [:desc.cus.spec:@arg1] = $arg3 ]

keyswitch = [
    [:switch:@arg1] = 1
    onrelease [ [:switch:@@arg1] = 0 ]
    nodebug [ if (=s $$arg3 "") $$arg2 $$arg3 ]
]

iskeyheld = [ = 1 $[:switch:@arg1] ]

&&iskeyheld = [
    local k ; k = 0
    nodebug [ loop+ i 1 $numargs [
        k = (+ $k $[:switch:@[arg@i]])
    ] ]
    = $k $numargs
]

||iskeyheld = [
    local k ; k = 0
    nodebug [ loop+ i 1 $numargs [
        k = (+ $k $[:switch:@[arg@i]])
    ] ]
    > $k 0
]

// example binds:

    defnormkey "MOUSEWHEELUP"   [ msc_delta  1 ]
    defnormkey "MOUSEWHEELDOWN" [ msc_delta -1 ]
    defnormkey "F5"  [                                 // Savemap
        if (! $mapname) [ toggleui "dialog_savemap" ] [
            if (iskeyheld "LCTRL") [ toggleui "dialog_savemap" ] savemap
        ]
    ]
    defeditkey "PAGEUP"    [
        if $fullconsole [ conskip 5 ] [
            if $enthavesel [ entautoview 1 ] [
                vdelta [ vscale 2 ]
            ]
        ]
    ]
    defeditkey "PAGEDOWN"  [
        if $fullconsole [ conskip -5 ] [
            if $enthavesel [ entautoview -1 ] [
                vdelta [ vscale 0.5 ]
            ]
        ]
    ]